1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
|
#lang typed/racket/base
(require typed/racket/draw typed/racket/class
"../common/type-doc.rkt"
"../common/types.rkt"
"../common/draw.rkt"
"../common/parameters.rkt"
"../common/parameter-groups.rkt"
"../common/parameter-group.rkt"
"../common/plot-element.rkt"
"../common/nonrenderer.rkt"
"../common/file-type.rkt"
"../common/utils.rkt"
"../plot2d/plot-area.rkt"
"../plot2d/renderer.rkt"
"plot2d-utils.rkt"
"evil.rkt"
typed/racket/unsafe)
(unsafe-provide plot/dc
plot-bitmap
plot-pict
plot-file)
;; ===================================================================================================
;; Plot to a given device context
(:: plot/dc
(->* [(Treeof (U renderer2d nonrenderer))
(Instance DC<%>)
Real Real Nonnegative-Real Nonnegative-Real]
[#:x-min (U Real #f) #:x-max (U Real #f)
#:y-min (U Real #f) #:y-max (U Real #f)
#:title (U String #f)
#:x-label (U String #f)
#:y-label (U String #f)
#:legend-anchor Anchor]
Void))
(define (plot/dc renderer-tree dc x y width height
#:x-min [x-min #f] #:x-max [x-max #f]
#:y-min [y-min #f] #:y-max [y-max #f]
#:title [title (plot-title)]
#:x-label [x-label (plot-x-label)]
#:y-label [y-label (plot-y-label)]
#:legend-anchor [legend-anchor (plot-legend-anchor)])
(define fail/pos (make-raise-argument-error 'plot/dc renderer-tree dc x y width height))
(define fail/kw (make-raise-keyword-error 'plot/dc))
(cond
[(not (rational? x)) (fail/pos "rational?" 2)]
[(not (rational? y)) (fail/pos "rational?" 3)]
[(not (rational? width)) (fail/pos "rational?" 4)]
[(not (rational? height)) (fail/pos "rational?" 5)]
[(and x-min (not (rational? x-min))) (fail/kw "#f or rational" '#:x-min x-min)]
[(and x-max (not (rational? x-max))) (fail/kw "#f or rational" '#:x-max x-max)]
[(and y-min (not (rational? y-min))) (fail/kw "#f or rational" '#:y-min y-min)]
[(and y-max (not (rational? y-max))) (fail/kw "#f or rational" '#:y-max y-max)]
[else
(define renderer-list (get-renderer-list renderer-tree))
(define bounds-rect (get-bounds-rect renderer-list x-min x-max y-min y-max))
(define-values (x-ticks x-far-ticks y-ticks y-far-ticks)
(get-ticks renderer-list bounds-rect))
(parameterize ([plot-title title]
[plot-x-label x-label]
[plot-y-label y-label]
[plot-legend-anchor legend-anchor])
(define area (make-object 2d-plot-area%
bounds-rect x-ticks x-far-ticks y-ticks y-far-ticks dc x y width height))
(plot-area area renderer-list))]))
;; ===================================================================================================
;; Plot to a bitmap
(:: plot-bitmap
(->* [(Treeof (U renderer2d nonrenderer))]
[#:x-min (U Real #f) #:x-max (U Real #f)
#:y-min (U Real #f) #:y-max (U Real #f)
#:width Positive-Integer
#:height Positive-Integer
#:title (U String #f)
#:x-label (U String #f)
#:y-label (U String #f)
#:legend-anchor Anchor]
(Instance Bitmap%)))
(define (plot-bitmap renderer-tree
#:x-min [x-min #f] #:x-max [x-max #f]
#:y-min [y-min #f] #:y-max [y-max #f]
#:width [width (plot-width)]
#:height [height (plot-height)]
#:title [title (plot-title)]
#:x-label [x-label (plot-x-label)]
#:y-label [y-label (plot-y-label)]
#:legend-anchor [legend-anchor (plot-legend-anchor)])
((if (plot-animating?) draw-bitmap draw-bitmap/supersampling)
(λ (dc)
(plot/dc renderer-tree dc 0 0 width height
#:x-min x-min #:x-max x-max #:y-min y-min #:y-max y-max
#:title title #:x-label x-label #:y-label y-label #:legend-anchor legend-anchor))
width height))
;; ===================================================================================================
;; Plot to a pict
(:: plot-pict
(->* [(Treeof (U renderer2d nonrenderer))]
[#:x-min (U Real #f) #:x-max (U Real #f)
#:y-min (U Real #f) #:y-max (U Real #f)
#:width Positive-Integer
#:height Positive-Integer
#:title (U String #f)
#:x-label (U String #f)
#:y-label (U String #f)
#:legend-anchor Anchor]
Pict))
(define (plot-pict renderer-tree
#:x-min [x-min #f] #:x-max [x-max #f]
#:y-min [y-min #f] #:y-max [y-max #f]
#:width [width (plot-width)]
#:height [height (plot-height)]
#:title [title (plot-title)]
#:x-label [x-label (plot-x-label)]
#:y-label [y-label (plot-y-label)]
#:legend-anchor [legend-anchor (plot-legend-anchor)])
(define saved-values (plot-parameters))
(dc (λ (dc x y)
(parameterize/group ([plot-parameters saved-values])
(plot/dc renderer-tree dc x y width height
#:x-min x-min #:x-max x-max #:y-min y-min #:y-max y-max
#:title title #:x-label x-label #:y-label y-label #:legend-anchor legend-anchor)))
width height))
;; ===================================================================================================
;; Plot to a file
(:: plot-file
(->* [(Treeof (U renderer2d nonrenderer))
(U Path-String Output-Port)]
[(U 'auto Image-File-Format)
#:x-min (U Real #f) #:x-max (U Real #f)
#:y-min (U Real #f) #:y-max (U Real #f)
#:width Positive-Integer
#:height Positive-Integer
#:title (U String #f)
#:x-label (U String #f)
#:y-label (U String #f)
#:legend-anchor Anchor]
Void))
(define (plot-file renderer-tree output [kind 'auto]
#:x-min [x-min #f] #:x-max [x-max #f]
#:y-min [y-min #f] #:y-max [y-max #f]
#:width [width (plot-width)]
#:height [height (plot-height)]
#:title [title (plot-title)]
#:x-label [x-label (plot-x-label)]
#:y-label [y-label (plot-y-label)]
#:legend-anchor [legend-anchor (plot-legend-anchor)])
(define real-kind
(cond [(eq? kind 'auto)
(cond [(port? output) (error 'plot-file "can't detect file type from output stream")]
[else (detect-image-file-type output)])]
[else kind]))
(case real-kind
[(png jpeg xbm xpm bmp)
(define bm
(plot-bitmap
renderer-tree
#:x-min x-min #:x-max x-max #:y-min y-min #:y-max y-max #:width width #:height height
#:title title #:x-label x-label #:y-label y-label #:legend-anchor legend-anchor))
(send bm save-file output real-kind (plot-jpeg-quality))]
[(ps pdf svg)
(define dc
(case real-kind
[(ps) (new-post-script-dc% width height output)]
[(pdf) (new-pdf-dc% width height output)]
[(svg) (new-svg-dc% width height output)]))
(define-values (x-scale y-scale) (send dc get-device-scale))
(send dc start-doc "Rendering plot")
(send dc start-page)
(plot/dc renderer-tree dc 0 0
(/ width (inexact->exact x-scale)) (/ height (inexact->exact y-scale))
#:x-min x-min #:x-max x-max #:y-min y-min #:y-max y-max
#:title title #:x-label x-label #:y-label y-label #:legend-anchor legend-anchor)
(send dc end-page)
(send dc end-doc)])
(void))
|
