defaultmodifier = 0
modifier = $defaultmodifier
domodifier = [ modifier = $arg1; onrelease [ modifier = $defaultmodifier ] ]

deltastates = ["game" "dead" "edit" "spec" "wait"]
universaldelta = [
    delta = (format "delta_%1_%2" (at $deltastates (getplayerstate)) $modifier)
    if (stringcmp (getalias $delta) "") [
        delta = (format "delta_%1_%2" (at $deltastates (getplayerstate)) $defaultmodifier)
        if (stringcmp (getalias $delta) "") [
            delta = (format "delta_%1_%2" (at $deltastates 0) $modifier)
            if (stringcmp (getalias $delta) "") [
                delta = (format "delta_%1_%2" (at $deltastates 0) $defaultmodifier)
            ]
        ]
    ]
    if (getalias $delta) [ do [@delta @arg1] ]
]; setcomplete universaldelta 1

listcomplete editmat "air water clip glass noclip lava death aiclip ladder alpha hurt"
air = [ editmat air $arg1 ]; setcomplete air 1
loop i 4 [
    [water@(? $i (+ $i 1))] = [ editmat water@(? $i (+ $i 1)) $arg1 ]; setcomplete [water@(? $i (+ $i 1))] 1
    [lava@(? $i (+ $i 1))] = [ editmat lava@(? $i (+ $i 1)) $arg1 ]; setcomplete [lava@(? $i (+ $i 1))] 1
    [glass@(? $i (+ $i 1))] = [ editmat glass@(? $i (+ $i 1)) $arg1 ]; setcomplete [glass@(? $i (+ $i 1))] 1
]
clip = [ editmat clip $arg1 ]; setcomplete clip 1
noclip = [ editmat noclip $arg1 ]; setcomplete noclip 1
death = [ editmat death $arg1 ]; setcomplete death 1
aiclip = [ editmat aiclip $arg1 ]; setcomplete aiclip 1
ladder = [ editmat ladder $arg1 ]; setcomplete ladder 1
alpha = [ editmat alpha $arg1 ]; setcomplete alpha 1
hurt = [ editmat hurt $arg1 ]; setcomplete hurt 1

//////// Entity Editing ///////////////

=enttype = [
    || [stringcmp * $arg1] [stringcmp (enttype) $arg1]
]

=entattr = [
    || [stringcmp * $arg2] [= (entattr $arg1) $arg2]
]

// clear ents of given type
clearents = [
    if $editing [
        entcancel
        entselect [ =enttype $arg1 ];
        echo Deleted (enthavesel) $arg1 entities;
        delent
    ]
]; setcomplete clearents 1

// replace all ents that match current selection
// with the values given
replaceents = [
    if $editing [
        do [
            entfind @(entget)
            entset @(loopconcat i $numargs [result $[arg@(+ $i 1)]])
        ]
        echo Replaced (enthavesel) entities
    ]
]; setcomplete replaceents 1

selentedit      = [ saycommand ( concatword "/entset " (entget) ) ]; setcomplete selentedit 1
selreplaceents  = [ saycommand ( concatword "/replaceents " (entget) ) ]; setcomplete selreplaceents 1
selentfindall   = [ do [ entfind @(entget) ] ]; setcomplete selentfindall 1

// modify given attribute of ent by a given amount
// arg1 attribute
// arg2 value
entmodify = [
    entattr $arg1 (+ (entattr $arg1) $arg2)
]; setcomplete entmodify 1

entproperty = [
    entprop $arg1 $arg2
]; setcomplete entproperty 1

//////// Copy and Paste //////////////

// 3 types of copying and pasting
// 1. select only cubes      -> paste only cubes
// 2. select cubes and ents  -> paste cubes and ents. same relative positions
// 3. select only ents       -> paste last selected ent. if ents are selected, replace attrs as paste

opaquepaste = 1
entcopybuf = ""

entreplace   = [
    do [
        if (enthavesel) [] [ newent @entcopybuf ]
        entset @entcopybuf
    ]
]; setcomplete entreplace 1

editcopy   = [
    if (|| [havesel] [! (enthavesel)]) [
        entcopybuf = ""
        entcopy
        copy
    ] [
        entcopybuf = (entget)
    ]
]; setcomplete editcopy 1

editpaste  = [
    cancelpaste = (! (|| [enthavesel] [havesel]));
    if (stringcmp "" $entcopybuf) [
        pastehilight
        onrelease [
            if $opaquepaste delcube
            paste
            entpaste
            if $cancelpaste [ cancelsel ]
        ]
    ] [
        entreplace
        if $cancelpaste [ cancelsel ]
    ]
]; setcomplete editpaste 1

/////// Selection ///////////////

// select ents with given properties
// '*' is wildcard
entfind    = [
    if (= $numargs 0) [
        entselect 1
    ] [
        entselect (concat [ && [=enttype @@arg1] ] (loopconcat i (- $numargs 1) [
            result [ [=entattr @@i @@[arg@(+ $i 2)]] ]
        ]))
    ]
]; setcomplete entfind 1

entfindinsel = [
    if (= $numargs 0) [
        entselect [ insel ]
    ] [
        entselect (concat [ && [insel] [=enttype @@arg1] ] (loopconcat i (- $numargs 1) [
            result [ [=entattr @@i @@[arg@(+ $i 2)]] ]
        ]))
    ]
]; setcomplete entfindinsel 1

lse        = [
    line = ""
    count = 0
    entloop [
        line  = ( concatword $line (entget) "       " )
        count = ( + $count 1 )
        if (> $count 4) [
            echo $line
            line = ""
            count = 0
        ]
    ]
    if (> $count 0 ) [ echo $line ]
    echo (enthavesel) entities selected
]; setcomplete lse 1

grabbing = 0

drag       = [ dragging 1; onrelease [ dragging 0 ] ]
corners    = [ selectcorners 1; dragging 1; onrelease [ selectcorners 0; dragging 0 ] ]
editmove   = [ moving 1; onrelease [ moving 0 ]; result $moving ]
entdrag    = [ entmoving 1; onrelease [entmoving 0]; result $entmoving ]

editdrag   = [ cancelsel; || [entdrag] [ drag ] ]; setcomplete editdrag 1
selcorners = [ if $hmapedit [ hmapselect ] [ cancelsel; || [entdrag] [ corners ] ] ]; setcomplete selcorners 1
editextend = [ || [entdrag] [ selextend; reorient; editmove ] ]; setcomplete editextend 1

editmovewith    = [
    if (havesel) [
        || [editmove] [ @arg1 ]
        onrelease [ moving 0; dragging 0 ]
    ] [
        @arg1
    ]
]

editmovecorner = [ editmovewith selcorners ]; setcomplete editmovecorner 1
editmovedrag   = [ editmovewith editdrag ]; setcomplete editmovedrag 1

////// Other Editing commands /////////

editfacewentpush = [
    if (|| [havesel] [! (enthavesel)] ) [
        if $moving [
            pushsel $arg1
        ] [
            entcancel
            editface $arg1 $arg2
        ]
    ] [
        if $entmoving [ entpush $arg1 ]
    ]
]; setcomplete editfacewentpush 1

entswithdirection = ["playerstart 0" "mapmodel 1" "teledest 0" "camera 0"]

editdel    = [ if (= (enthavesel) 0) [ delcube ] [ delent ] ]; setcomplete editdel 1
editflip   = [ if (= (enthavesel) 0) [ flip ] [ entflip ] ]; setcomplete editflip 1

editrotate = [
    rotate $arg1
    entrotate $arg1
]; setcomplete editrotate 1

editcut    = [  
  if (moving 1) [
    if (= $moving 1) [selsave]
    onrelease [ 
      moving 0 
      if (selmoved) [
        selswap
        copy; entcopy
        delcube; delent
        selrestore
        paste; entpaste
      ]
    ] 
  ] 
]; setcomplete editcut 1

selectents = [ entselect [&& [insel] [=enttype @@arg1]] ]; setcomplete selectents 1

noautosave = 0
autosaveinterval = 10; setpersist autosaveinterval 1; setcomplete autosaveinterval 1
autosave = [
    if (= $noautosave 0) [
        savemap
        sleep (* $autosaveinterval 60000) [ autosave ]
    ] [ noautosave = 0 ]
]; setcomplete autosave 1
stopautosave = [ noautosave = 1 ]; setcomplete stopautosave 1

togglesound = [ if (> $mastervol 0) [ mastervol 0; echo "sound off" ] [ mastervol 255; echo "sound on" ] ]; setcomplete togglesound 1

changeoutline = [
    outlinestatus = (mod (+ $arg1 $outlinestatus) (listlen $outlinecolours))
    if (< $outlinestatus 0) [
        outlinestatus = (+ (listlen $outlinecolours) $outlinestatus ) //just making sure it'll fit
    ]

    if (=s (at $outlinecolours $outlinestatus) "OFF") [
        echo "Outline OFF"
        outline 0
    ] [
        echo (concat "Outline" (at $outlinecolours $outlinestatus))
        outline 1
        outlinecolour @(at $outlinecolours $outlinestatus)
    ]
]; setcomplete changeoutline 1
outlinecolours = ["255 255 255" "0 0 0" "80 80 255" "0 127 255" "255 80 80" "255 0 255" "80 255 80" "255 255 80" "OFF"]
outlinestatus = 0

enttypelist = ""
do [
    en = (getentinfo)
    loop q $en [
        es = (getentinfo $q)
        enttypelist = (? $q (concat $enttypelist $es) $es)
    ]
]
entcomplete = [ listcomplete $arg1 $enttypelist ]

// entcomplete gets defined by game
entcomplete newent
entcomplete entfind

enttypeselect = [
    enttypelength = (listlen $enttypelist)
    next = (mod (+ (indexof $enttypelist (enttype)) $arg1) $enttypelength)
    if (< $next 0) [ next = (+ $next $enttypelength) ]
    do [entset @(listsplice (entget) (at $enttypelist $next) 0 1)]
]

slime = [
    editmat water
    editmat death
    obitwater "sucked on slime"
    watercolour 0x182200
    waterfallcolour 0x002200
    waterfog 0
    waterspec 10
]

quicklight = [ calclight (? (> $numargs 0) $arg1 -1) 1 ]; setcomplete quicklight 1
quickpatchlight = [ patchlight (? (> $numargs 0) $arg1 -1) 1 ]; setcomplete quickpatchlight 1