1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
conf = configuration_data()
conf.set('app_id', app_id)
conf.set('app_name', app_name)
conf.set('developer_id', developer_id)
conf.set('exec', get_option('exec_name_as_base_id') ? base_id : meson.project_name())
desktop_file = i18n.merge_file(
input: configure_file(
input: base_id + '.' + 'desktop.in.in',
output: base_id + '.' + 'desktop.in',
configuration: conf
),
output: app_id + '.desktop',
type: 'desktop',
po_dir: '../po',
install: true,
install_dir: join_paths(get_option('datadir'), 'applications')
)
desktop_utils = find_program('desktop-file-validate', required: false)
if desktop_utils.found()
test('Validate desktop file', desktop_utils, args: [desktop_file])
endif
pkgdatadir = get_option('prefix') / get_option('datadir') / meson.project_name()
appstream_file = i18n.merge_file(
input: configure_file(
input: base_id + '.' + 'metainfo.xml.in.in',
output: base_id + '.' + 'metainfo.xml.in',
configuration: conf
),
output: app_id + '.' + 'metainfo.xml',
po_dir: '../po',
install: true,
install_dir: get_option('datadir') / 'metainfo'
)
gnome.compile_resources('data',
configure_file(
input: 'data.gresource.xml.in',
output: 'data.gresource.xml',
configuration: conf
),
gresource_bundle: true,
install: true,
install_dir: pkgdatadir,
dependencies: [appstream_file]
)
appstreamcli = find_program('appstreamcli', required: false, disabler: true)
test('Validate appstream file', appstreamcli,
args: ['validate', '--no-net', '--explain', appstream_file])
install_data('page.tesk.Refine.gschema.xml',
install_dir: get_option('datadir') / 'glib-2.0' / 'schemas'
)
compile_schemas = find_program('glib-compile-schemas', required: false, disabler: true)
test('Validate schema file',
compile_schemas,
args: ['--strict', '--dry-run', meson.current_source_dir()])
service_conf = configuration_data()
service_conf.set('bindir', get_option('prefix') / get_option('bindir'))
service_conf.set('exec', get_option('exec_name_as_base_id') ? base_id : meson.project_name())
configure_file(
input: 'page.tesk.Refine.service.in',
output: 'page.tesk.Refine.service',
configuration: service_conf,
install_dir: get_option('datadir') / 'dbus-1' / 'services'
)
subdir('icons')
|
