1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
|
# BEGIN BPS TAGGED BLOCK {{{
#
# COPYRIGHT:
#
# This software is Copyright (c) 1996-2025 Best Practical Solutions, LLC
# <sales@bestpractical.com>
#
# (Except where explicitly superseded by other copyright notices)
#
#
# LICENSE:
#
# This work is made available to you under the terms of Version 2 of
# the GNU General Public License. A copy of that license should have
# been provided with this software, but in any event can be snarfed
# from www.gnu.org.
#
# This work is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
# 02110-1301 or visit their web page on the internet at
# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
#
#
# CONTRIBUTION SUBMISSION POLICY:
#
# (The following paragraph is not intended to limit the rights granted
# to you to modify and distribute this software under the terms of
# the GNU General Public License and is only of importance to you if
# you choose to contribute your changes and enhancements to the
# community by submitting them to Best Practical Solutions, LLC.)
#
# By intentionally submitting any modifications, corrections or
# derivatives to this work, or any other work intended for use with
# Request Tracker, to Best Practical Solutions, LLC, you confirm that
# you are the copyright holder for those contributions and you grant
# Best Practical Solutions, LLC a nonexclusive, worldwide, irrevocable,
# royalty-free, perpetual, license to use, copy, create derivative
# works based on those contributions, and sublicense and distribute
# those contributions and any derivatives thereof.
#
# END BPS TAGGED BLOCK }}}
=head1 NAME
RT::Action::NotifyGroup - Send email notifications to groups or users
=head1 DESCRIPTION
NotifyGroup sends email notifications to the groups or users defined. The
recipients are set via the parameter passed in, either in the RT Action
Parameters to Pass configuration or C<--action-arg> from L<rt-crontool>.
Valid values are RT group names or ids, usernames or ids, or RT user email
addresses. You can also pass an arbitrary valid email address that is not
associated with an RT user.
The RT utility L<rt-email-group-admin> provides a way to create RT actions
that use NotifyGroup via the command line. You can also create actions
via the web UI at Admin > Global > Actions > Create.
=cut
package RT::Action::NotifyGroup;
use strict;
use warnings;
use base qw(RT::Action::Notify);
require RT::User;
require RT::Group;
=head1 METHODS
=head2 SetRecipients
Sets the recipients of this message to Groups, Users, or a provided email
address. It respects RT's NotifyActor configuration.
To send email to the selected recipients regardless of RT's NotifyActor
configuration, include AlwaysNotifyActor in the list of arguments. Or to
always suppress email to the selected recipients regardless of RT's
NotifyActor configuration, include NeverNotifyActor in the list of arguments.
=cut
sub SetRecipients {
my $self = shift;
my $arg = $self->Argument;
foreach( $self->__SplitArg( $arg ) ) {
$self->_HandleArgument( $_ );
}
$self->{'seen_ueas'} = {};
return 1;
}
sub _HandleArgument {
my $self = shift;
my $instance = shift;
return if $instance eq 'AlwaysNotifyActor'
|| $instance eq 'NeverNotifyActor';
if ( $instance !~ /\D/ ) {
my $obj = RT::Principal->new( $self->CurrentUser );
my ($ok, $msg) = $obj->Load( $instance );
if ( $ok ) {
return $self->_HandlePrincipal( $obj );
}
else {
RT->Logger->error( "Unable to load principal from $instance: $msg" );
return;
}
}
my $group = RT::Group->new( $self->CurrentUser );
$group->LoadUserDefinedGroup( $instance );
# to check disabled and so on
return $self->_HandlePrincipal( $group->PrincipalObj )
if $group->id;
require Email::Address;
my $user = RT::User->new( $self->CurrentUser );
if ( $instance =~ /^$Email::Address::addr_spec$/ ) {
$user->LoadByEmail( $instance );
return $self->__PushUserAddress( $instance )
unless $user->id;
} else {
$user->Load( $instance );
}
return $self->_HandlePrincipal( $user->PrincipalObj )
if $user->id;
RT->Logger->error(
"'$instance' is not a principal id, group name, user name,"
." user email address or a valid email address"
);
return;
}
sub _HandlePrincipal {
my $self = shift;
my $obj = shift;
unless( $obj->id ) {
RT->Logger->error( "Principal object not loaded" );
return;
}
if( $obj->Disabled ) {
RT->Logger->info( "Principal id " . $obj->Id . " is disabled, skipping" );
return;
}
if( !$obj->PrincipalType ) {
RT->Logger->crit( "Principal id " . $obj->Id . " has empty type" );
} elsif( lc $obj->PrincipalType eq 'user' ) {
$self->__HandleUserArgument( $obj->Object );
} elsif( lc $obj->PrincipalType eq 'group' ) {
$self->__HandleGroupArgument( $obj->Object );
} else {
RT->Logger->info( "Principal id " . $obj->Id . " has an unsupported type" );
}
return;
}
sub __HandleUserArgument {
my $self = shift;
my $obj = shift;
my $uea = $obj->EmailAddress;
unless( $uea ) {
$RT::Logger->warning( "User #". $obj->id ." has no email address" );
return;
}
$self->__PushUserAddress( $uea );
}
sub __HandleGroupArgument {
my $self = shift;
my $obj = shift;
my $members = $obj->UserMembersObj;
while( my $m = $members->Next ) {
$self->__HandleUserArgument( $m );
}
}
sub __SplitArg {
return grep length, map {s/^\s+//; s/\s+$//; $_} split /,/, $_[1];
}
sub __PushUserAddress {
my $self = shift;
my $uea = shift;
push @{ $self->{'To'} }, $uea unless $self->{'seen_ueas'}{ $uea }++;
return;
}
RT::Base->_ImportOverlays();
1;
|
