1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
set terminal cairolatex pdf color standalone
set output "transport_dg-cv-linf-2d-t-grid.tex"
set size square 0.9
set colors classic
set log
set xrange [2e-3:0.2]
set yrange [1e-15:1]
set xtics (\
"[r]{$10^{-3}$}" 1e-3, \
"[r]{$10^{-2}$}" 1e-2, \
"[r]{$10^{-1}$}" 1e-1, \
"[r]{$1$}" 1 )
set ytics (\
"[r]{$10^{-15}$}" 1e-15, \
"[r]{$10^{-10}$}" 1e-10, \
"[r]{$10^{-5}$}" 1e-5, \
"[r]{$1$}" 1 )
set xlabel '[c]{\large $h$}'
set label '[l]{$\left\|\phi - \phi_h\right\|_{L^\infty}$}' at graph 0.03,0.95
set key bottom
graph_ratio = 2.0/15.0
# triangle a droite, pente +1
slope_A = graph_ratio*1.0
xA = 0.25
yA = 0.88
dxA = 0.10
dyA = dxA*slope_A
set label "[l]{\\scriptsize $1=k+1$}" at graph xA+dxA+0.02, yA+0.5*dyA right
set arrow from graph xA, yA to graph xA+dxA, yA nohead
set arrow from graph xA+dxA, yA to graph xA+dxA, yA+dyA nohead
set arrow from graph xA+dxA, yA+dyA to graph xA, yA nohead
# placian-fixed-point-p=1,5-err-linf.plot:#triangle a droite, pente +5
slope_B = graph_ratio*5.0
xB = 0.23
yB = 0.14
dxB = 0.10
dyB = dxB*slope_B
set label "[l]{\\scriptsize $5=k+1$}" at graph xB+dxB+0.02, yB+0.5*dyB right
set arrow from graph xB, yB to graph xB+dxB, yB nohead
set arrow from graph xB+dxB, yB to graph xB+dxB, yB+dyB nohead
set arrow from graph xB+dxB, yB+dyB to graph xB, yB nohead
plot \
"transport_dg-cv-2d-t-grid.gdat" \
i 0 u (1./$1):3 \
t '[r]{$k=0$}' \
w lp, \
"transport_dg-cv-2d-t-grid.gdat" \
i 1 u (1./$1):3 \
t '[r]{$k=1$}' \
w lp lc rgb '#008800', \
"transport_dg-cv-2d-t-grid.gdat" \
i 2 u (1./$1):3 \
t '[r]{$k=2$}' \
w lp, \
"transport_dg-cv-2d-t-grid.gdat" \
i 3 u (1./$1):3\
t '[r]{$k=3$}' \
w lp, \
"transport_dg-cv-2d-t-grid.gdat" \
i 4 u (1./$1):3\
t '[r]{$k=4$}' \
w lp
#pause -1 "<retour>"
|
