1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
# Copyright (c) 2018-2020 Ribose Inc.
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
# notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
# notice, this list of conditions and the following disclaimer in the
# documentation and/or other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
# POSSIBILITY OF SUCH DAMAGE.
#.rst:
# FindBotan
# -----------
#
# Find the botan-2 or botan-3 library.
#
# IMPORTED Targets
# ^^^^^^^^^^^^^^^^
#
# This module defines :prop_tgt:`IMPORTED` targets:
#
# ``Botan::Botan``
# The botan-2 or botan-3 library, if found.
#
# Result variables
# ^^^^^^^^^^^^^^^^
#
# This module defines the following variables:
#
# ::
#
# BOTAN_FOUND - true if the headers and library were found
# BOTAN_INCLUDE_DIRS - where to find headers
# BOTAN_LIBRARIES - list of libraries to link
# Botan_VERSION - library version that was found, if any
#
# Hints
# ^^^^^
#
# These variables may be set to control search behaviour:
#
# ``BOTAN_ROOT_DIR``
# Set to the root directory of the Botan installation.
#
# use pkg-config to get the directories and then use these values
# in the find_path() and find_library() calls
find_package(PkgConfig QUIET)
# Search for the version 2 first unless version 3 requested
if(NOT "${Botan_FIND_VERSION_MAJOR}" EQUAL "3")
pkg_check_modules(PC_BOTAN QUIET botan-2)
set(_suffixes "botan-2" "botan-3")
set(_names "botan-2" "libbotan-2" "botan-3" "libbotan-3")
else()
set(_suffixes "botan-3")
set(_names "botan-3" "libbotan-3")
endif()
if(NOT PC_BOTAN_FOUND)
pkg_check_modules(PC_BOTAN QUIET botan-3)
endif()
if(DEFINED BOTAN_ROOT_DIR)
set(_hints_include "${BOTAN_ROOT_DIR}/include")
set(_hints_lib "${BOTAN_ROOT_DIR}/lib")
endif()
if(DEFINED ENV{BOTAN_ROOT_DIR})
list(APPEND _hints_include "$ENV{BOTAN_ROOT_DIR}/include")
list(APPEND _hints_lib "$ENV{BOTAN_ROOT_DIR}/lib")
endif()
# Append PC_* stuff only if BOTAN_ROOT_DIR is not specified
if(NOT _hints_include)
list(APPEND _hints_include ${PC_BOTAN_INCLUDEDIR} ${PC_BOTAN_INCLUDE_DIRS})
list(APPEND _hints_lib ${PC_BOTAN_LIBDIR} ${PC_BOTAN_LIBRARY_DIRS})
else()
set(_no_def_path "NO_DEFAULT_PATH")
endif()
# find the headers
find_path(BOTAN_INCLUDE_DIR
NAMES botan/version.h
HINTS
${_hints_include}
PATH_SUFFIXES ${_suffixes}
${_no_def_path}
)
# find the library
if(MSVC)
find_library(BOTAN_LIBRARY
NAMES botan ${_names}
HINTS
${_hints_lib}
${_no_def_path}
)
else()
find_library(BOTAN_LIBRARY
NAMES
${_names}
HINTS
${_hints_lib}
${_no_def_path}
)
endif()
# determine the version
if(BOTAN_INCLUDE_DIR AND EXISTS "${BOTAN_INCLUDE_DIR}/botan/build.h")
file(STRINGS "${BOTAN_INCLUDE_DIR}/botan/build.h" botan_version_str
REGEX "^#define[\t ]+(BOTAN_VERSION_[A-Z]+)[\t ]+[0-9]+")
string(REGEX REPLACE ".*#define[\t ]+BOTAN_VERSION_MAJOR[\t ]+([0-9]+).*"
"\\1" _botan_version_major "${botan_version_str}")
string(REGEX REPLACE ".*#define[\t ]+BOTAN_VERSION_MINOR[\t ]+([0-9]+).*"
"\\1" _botan_version_minor "${botan_version_str}")
string(REGEX REPLACE ".*#define[\t ]+BOTAN_VERSION_PATCH[\t ]+([0-9]+).*"
"\\1" _botan_version_patch "${botan_version_str}")
set(Botan_VERSION "${_botan_version_major}.${_botan_version_minor}.${_botan_version_patch}"
CACHE INTERNAL "The version of Botan which was detected")
endif()
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(Botan
REQUIRED_VARS BOTAN_LIBRARY BOTAN_INCLUDE_DIR
VERSION_VAR Botan_VERSION
)
if (BOTAN_FOUND)
set(BOTAN_INCLUDE_DIRS ${BOTAN_INCLUDE_DIR} ${PC_BOTAN_INCLUDE_DIRS})
set(BOTAN_LIBRARIES ${BOTAN_LIBRARY})
endif()
if (BOTAN_FOUND AND NOT TARGET Botan::Botan)
# create the new library target
add_library(Botan::Botan UNKNOWN IMPORTED)
# set the required include dirs for the target
if (BOTAN_INCLUDE_DIRS)
set_target_properties(Botan::Botan
PROPERTIES
INTERFACE_INCLUDE_DIRECTORIES "${BOTAN_INCLUDE_DIRS}"
)
endif()
# set the required libraries for the target
if (EXISTS "${BOTAN_LIBRARY}")
set_target_properties(Botan::Botan
PROPERTIES
IMPORTED_LINK_INTERFACE_LANGUAGES "C"
IMPORTED_LOCATION "${BOTAN_LIBRARY}"
)
endif()
endif()
mark_as_advanced(BOTAN_INCLUDE_DIR BOTAN_LIBRARY)
|
