1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
|
.386
.MODEL flat
SCREENWIDTH = 96
.data
loopcount dd 0
pixelcount dd 0
EXTRN _centery:DWORD
EXTRN _centeryclipped:DWORD
EXTRN _dc_yl:DWORD
EXTRN _dc_yh:DWORD
EXTRN _dc_iscale:DWORD
EXTRN _dc_texturemid:DWORD
EXTRN _ylookup:DWORD
;EXTRN _dc_firstsource:DWORD
EXTRN _dc_source:DWORD
EXTRN _shadingtable:DWORD
.code
SEGMENT text USE32
ALIGN 16
;================
;
; R_DrawColumn
;
;================
PROC R_DrawColumn_
PUBLIC R_DrawColumn_
push ebp
mov ebp,[_dc_yl]
mov ebx,ebp
add edi,[_ylookup+ebx*4]
mov eax,[_dc_yh]
inc eax
sub eax,ebp ; pixel count
mov [pixelcount],eax ; save for final pixel
js done ; nothing to scale
shr eax,1 ; double pixel count
mov [loopcount],eax
mov ecx,[_dc_iscale]
mov eax,[_centery]
sub eax,ebp
imul ecx
mov ebp,[_dc_texturemid]
sub ebp,eax
mov esi,[_dc_source]
mov ebx,[_dc_iscale]
mov eax,OFFSET patch1+2 ; convice tasm to modify code...
mov [eax],ebx
mov eax,OFFSET patch2+2 ; convice tasm to modify code...
mov [eax],ebx
; eax aligned colormap
; ebx aligned colormap
; ecx,edx scratch
; esi virtual source
; edi moving destination pointer
; ebp frac
mov ecx,ebp ; begin calculating first pixel
add ebp,ebx ; advance frac pointer
shr ecx,16 ; finish calculation for first pixel
mov edx,ebp ; begin calculating second pixel
add ebp,ebx ; advance frac pointer
shr edx,16 ; finish calculation for second pixel
mov eax,[_shadingtable]
mov ebx,eax
;mov [_dc_firstsource],esi
;add [_dc_firstsource],ecx
mov al,[esi+ecx] ; get first pixel
mov bl,[esi+edx] ; get second pixel
mov al,[eax] ; color translate first pixel
mov bl,[ebx] ; color translate second pixel
test [pixelcount],0fffffffeh
jnz doubleloop ; at least two pixels to map
jmp checklast
ALIGN 16
doubleloop:
mov ecx,ebp ; begin calculating third pixel
patch1:
add ebp,12345678h ; advance frac pointer
mov [edi],al ; write first pixel
shr ecx,16 ; finish calculation for third pixel
mov edx,ebp ; begin calculating fourth pixel
patch2:
add ebp,12345678h ; advance frac pointer
mov [edi+SCREENWIDTH],bl ; write second pixel
shr edx,16 ; finish calculation for fourth pixel
mov al,[esi+ecx] ; get third pixel
add edi,SCREENWIDTH*2 ; advance to third pixel destination
mov bl,[esi+edx] ; get fourth pixel
dec [loopcount] ; done with loop?
mov al,[eax] ; color translate third pixel
mov bl,[ebx] ; color translate fourth pixel
jnz doubleloop
; check for final pixel
checklast:
test [pixelcount],1
jz done
mov [edi],al ; write final pixel
done:
pop ebp
ret
ENDP
;================
;
; R_DrawSolidColumn
;
;================
PROC R_DrawSolidColumn_
PUBLIC R_DrawSolidColumn_
mov ecx,[_dc_yl]
mov eax,ecx
add edi,[_ylookup+eax*4]
mov eax,[_dc_yh]
inc eax
sub eax,ecx ; pixel count
mov [pixelcount],eax ; save for final pixel
js soliddone ; nothing to scale
shr eax,1 ; double pixel count
mov [loopcount],eax
test [pixelcount],0fffffffeh
jnz soliddoubleloop ; at least two pixels to map
jmp solidchecklast
ALIGN 16
soliddoubleloop:
mov [edi],bl ; write first pixel
add edi,SCREENWIDTH ; advance to third pixel destination
mov [edi],bl ; write second pixel
add edi,SCREENWIDTH ; advance to fourth pixel destination
dec [loopcount] ; done with loop?
jnz soliddoubleloop
; check for final pixel
solidchecklast:
test [pixelcount],1
jz soliddone
mov [edi],bl ; write final pixel
soliddone:
ret
ENDP
;================
;
; R_TransColumn
;
;================
PROC R_TransColumn_
PUBLIC R_TransColumn_
mov ebx,[_dc_yl]
mov eax,[_dc_yh]
add edi,[_ylookup+ebx*4]
inc eax
sub eax,ebx ; pixel count
mov [pixelcount],eax ; save for final pixel
js tdone ; nothing to scale
shr eax,1 ; double pixel count
mov [loopcount],eax
; eax aligned colormap
; ebx aligned colormap
; esi moving destination pointer
; edi moving destination pointer
mov eax,[_shadingtable]
mov esi,edi
mov ebx,eax
add esi,SCREENWIDTH
mov al,[BYTE PTR edi] ; get first pixel
mov bl,[BYTE PTR esi] ; get second pixel
mov al,[BYTE PTR eax] ; color translate first pixel
mov bl,[BYTE PTR ebx] ; color translate second pixel
test [pixelcount],0fffffffeh
jnz tdoubleloop ; at least two pixels to map
jmp tchecklast
ALIGN 16
tdoubleloop:
mov [edi],al ; write first pixel
mov [esi],bl ; write second pixel
add edi,SCREENWIDTH*2 ; advance to third pixel destination
add esi,SCREENWIDTH*2 ; advance to third pixel destination
mov al,[edi] ; get third pixel
mov bl,[esi] ; get fourth pixel
mov al,[eax] ; color translate third pixel
dec [loopcount] ; done with loop?
mov bl,[ebx] ; color translate fourth pixel
jnz tdoubleloop
; check for final pixel
tchecklast:
test [pixelcount],1
jz tdone
mov [edi],al ; write final pixel
tdone:
ret
ENDP
;================
;
; R_DrawClippedColumn
;
;================
PROC R_DrawClippedColumn_
PUBLIC R_DrawClippedColumn_
push ebp
mov ebp,[_dc_yl]
mov ebx,ebp
add edi,[_ylookup+ebx*4]
mov eax,[_dc_yh]
inc eax
sub eax,ebp ; pixel count
mov [pixelcount],eax ; save for final pixel
js adone ; nothing to scale
shr eax,1 ; double pixel count
mov [loopcount],eax
mov ecx,[_dc_iscale]
mov eax,[_centeryclipped]
sub eax,ebp
imul ecx
mov ebp,[_dc_texturemid]
sub ebp,eax
mov esi,[_dc_source]
mov ebx,[_dc_iscale]
mov eax,OFFSET apatch1+2 ; convice tasm to modify code...
mov [eax],ebx
mov eax,OFFSET apatch2+2 ; convice tasm to modify code...
mov [eax],ebx
; eax aligned colormap
; ebx aligned colormap
; ecx,edx scratch
; esi virtual source
; edi moving destination pointer
; ebp frac
mov ecx,ebp ; begin calculating first pixel
add ebp,ebx ; advance frac pointer
shr ecx,16 ; finish calculation for first pixel
mov edx,ebp ; begin calculating second pixel
add ebp,ebx ; advance frac pointer
shr edx,16 ; finish calculation for second pixel
mov eax,[_shadingtable]
mov ebx,eax
mov al,[esi+ecx] ; get first pixel
mov bl,[esi+edx] ; get second pixel
mov al,[eax] ; color translate first pixel
mov bl,[ebx] ; color translate second pixel
test [pixelcount],0fffffffeh
jnz adoubleloop ; at least two pixels to map
jmp achecklast
ALIGN 16
adoubleloop:
mov ecx,ebp ; begin calculating third pixel
apatch1:
add ebp,12345678h ; advance frac pointer
mov [edi],al ; write first pixel
shr ecx,16 ; finish calculation for third pixel
mov edx,ebp ; begin calculating fourth pixel
apatch2:
add ebp,12345678h ; advance frac pointer
mov [edi+SCREENWIDTH],bl ; write second pixel
shr edx,16 ; finish calculation for fourth pixel
mov al,[esi+ecx] ; get third pixel
add edi,SCREENWIDTH*2 ; advance to third pixel destination
mov bl,[esi+edx] ; get fourth pixel
dec [loopcount] ; done with loop?
mov al,[eax] ; color translate third pixel
mov bl,[ebx] ; color translate fourth pixel
jnz adoubleloop
; check for final pixel
achecklast:
test [pixelcount],1
jz adone
mov [edi],al ; write final pixel
adone:
pop ebp
ret
ENDP
;================
;
; R_DrawWallColumn
;
;================
PROC R_DrawWallColumn_
PUBLIC R_DrawWallColumn_
push ebp
mov ebp,[_dc_yl]
mov ebx,ebp
add edi,[_ylookup+ebx*4]
mov eax,[_dc_yh]
; inc eax
sub eax,ebp ; pixel count
mov [pixelcount],eax ; save for final pixel
js wcdone ; nothing to scale
shr eax,1 ; double pixel count
mov [loopcount],eax
mov ecx,[_dc_iscale]
mov eax,[_centery]
sub eax,ebp
imul ecx
mov ebp,[_dc_texturemid]
sub ebp,eax
shl ebp,10
mov esi,[_dc_source]
mov ebx,[_dc_iscale]
shl ebx,10
mov eax,OFFSET wcpatch1+2 ; convice tasm to modify code...
mov [eax],ebx
mov eax,OFFSET wcpatch2+2 ; convice tasm to modify code...
mov [eax],ebx
; eax aligned colormap
; ebx aligned colormap
; ecx,edx scratch
; esi virtual source
; edi moving destination pointer
; ebp frac
mov ecx,ebp ; begin calculating first pixel
add ebp,ebx ; advance frac pointer
shr ecx,26 ; finish calculation for first pixel
mov edx,ebp ; begin calculating second pixel
; and ecx,63
add ebp,ebx ; advance frac pointer
shr edx,26 ; finish calculation for second pixel
mov eax,[_shadingtable]
; and edx,63
mov ebx,eax
mov al,[esi+ecx] ; get first pixel
mov bl,[esi+edx] ; get second pixel
mov al,[eax] ; color translate first pixel
mov bl,[ebx] ; color translate second pixel
test [pixelcount],0fffffffeh
jnz wcdoubleloop ; at least two pixels to map
jmp wcchecklast
ALIGN 16
wcdoubleloop:
mov ecx,ebp ; begin calculating third pixel
wcpatch1:
add ebp,12345678h ; advance frac pointer
mov [edi],al ; write first pixel
shr ecx,26 ; finish calculation for third pixel
mov edx,ebp ; begin calculating fourth pixel
; and ecx,63
wcpatch2:
add ebp,12345678h ; advance frac pointer
mov [edi+SCREENWIDTH],bl ; write second pixel
shr edx,26 ; finish calculation for fourth pixel
mov al,[esi+ecx] ; get third pixel
; and edx,63
add edi,SCREENWIDTH*2 ; advance to third pixel destination
mov bl,[esi+edx] ; get fourth pixel
dec [loopcount] ; done with loop?
mov al,[eax] ; color translate third pixel
mov bl,[ebx] ; color translate fourth pixel
jnz wcdoubleloop
; check for final pixel
wcchecklast:
test [pixelcount],1
jz wcdone
mov [edi],al ; write final pixel
wcdone:
pop ebp
ret
ENDP
ENDS
END
|
