1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
|
SUBROUTINE PBCGERC( ICONTXT, XDIST, YDIST, M, N, MB, NB, MZ, NZ,
$ ALPHA, X, INCX, Y, INCY, A, LDA, IXROW, IXCOL,
$ IYROW, IYCOL, IAROW, IACOL, BR1ST, XCOMM,
$ XWORK, YCOMM, YWORK, WORK )
*
* -- PB-BLAS routine (version 2.1) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory.
* April 28, 1996
*
* Jaeyoung Choi, Oak Ridge National Laboratory
* Jack Dongarra, University of Tennessee and Oak Ridge National Lab.
* David Walker, Oak Ridge National Laboratory
*
* .. Scalar Arguments ..
CHARACTER*1 BR1ST, XCOMM, XDIST, XWORK, YCOMM, YDIST,
$ YWORK
INTEGER IACOL, IAROW, ICONTXT, INCX, INCY, IXCOL,
$ IXROW, IYCOL, IYROW, LDA, M, MB, MZ, N, NB, NZ
COMPLEX ALPHA
* ..
* .. Array Arguments ..
COMPLEX A( LDA, * ), X( * ), Y( * ), WORK( * )
* ..
*
* Purpose
* =======
*
* PBCGERC is a parallel blocked version of CGERC.
* PBCGERC performs one of the matrix-vector operations based on
* block cyclic distribution.
*
* PBCGERC performs the rank 1 operation
*
* A := alpha*x*conjg( y' ) + A,
*
* where alpha is a scalar, X is an m element vector, Y is an n element
* vector and A is an m-by-n matrix.
*
* Parameters
* ==========
*
* ICONTXT (input) INTEGER
* ICONTXT is the BLACS mechanism for partitioning communication
* space. A defining property of a context is that a message in
* a context cannot be sent or received in another context. The
* BLACS context includes the definition of a grid, and each
* process' coordinates in it.
*
* XDIST (input) CHARACTER*1
* XDIST specifies the distribution of vector X as follows:
*
* XDIST = 'C', X is distributed columnwise
* or on a column of processes
* XDIST = 'R', X is distributed rowwise
* or on a row of processes
*
* YDIST (input) CHARACTER*1
* YDIST specifies the distribution of vector Y as follows:
*
* YDIST = 'C', Y is distributed columnwise
* or on a column of processes
* YDIST = 'R', Y is distributed rowwise
* or on a row of processes
*
* M (input) INTEGER
* M specifies the number of rows of the matrix A. M >= 0.
*
* N (input) INTEGER
* N specifies the number of columns of the matrix A. N >= 0.
*
* MB (input) INTEGER
* MB specifies the column block size of the matrix A and the
* block size of the vector X. MB >= 1.
*
* NB (input) INTEGER
* MB specifies the row block size of the matrix A and the
* block size of the vector Y. NB >= 1.
*
* MZ (input) INTEGER
* MZ is the column offset to specify the column distance from
* the beginning of the block to the the first element of A.
* 0 <= MZ < MB.
*
* NZ (input) INTEGER
* NZ is the row offset to specify the row distance from the
* beginning of the block to the the first element of A.
* 0 <= NZ < NB.
*
* ALPHA (input) COMPLEX
* ALPHA specifies the scalar alpha.
*
* X (input) COMPLEX array of DIMENSION at least
* ( 1 + ( Mp - 1 )*abs( INCX ) ) if XDIST = 'C', or
* ( 1 + ( Mq - 1 )*abs( INCX ) ) if XDIST = 'R'.
* The incremented array X must contain the (local) vector X.
*
* INCX (input) INTEGER
* INCX specifies the increment for the elements of X.
* INCX <> 0.
*
* Y (input/output) COMPLEX array of DIMENSION at least
* ( 1 + ( Np - 1 )*abs( INCY ) ) if YDIST = 'C', or.
* ( 1 + ( Nq - 1 )*abs( INCY ) ) if YDIST = 'R'.
* The incremented array Y must contain the (local) vector Y.
*
* INCY (input) INTEGER
* INCY specifies the increment for the elements of Y.
* INCY <> 0.
*
* A (input/output) COMPLEX array of DIMENSION ( LDA, Nq ),
* On entry, the leading Mp-by-Nq part of the array must
* contain the (local) matrix A.
* On exit, A is overwritten by the updated matrix.
*
* LDA (input) INTEGER
* The leading dimension of the (local) array A.
* LDA >= max( 1, Mp ).
*
* IXROW (input) INTEGER
* IXROW specifies a row of the process template which has
* the first element of X. 0 <= IXROW < NPROW. If all rows
* of the process template have their own copies of X when
* XDIST = 'R', then set IXROW = -1.
*
* IXCOL (input) INTEGER
* IXCOL specifies a column of the process template which has
* the first element of X. 0 <= IXCOL < NPCOL. If all columns
* of the process template have their own copies of X when
* XDIST = 'C', then set IXCOL = -1.
*
* IYROW (input) INTEGER
* IYROW specifies a row of the process template which has
* the first element of Y. 0 <= IYROW < NPROW. If all rows
* of the process template have their own copies of Y when
* YDIST = 'R', then set IYROW = -1.
*
* IYCOL (input) INTEGER
* IYCOL specifies a column of the process template which has
* the first element of Y. 0 <= IYCOL < NPCOL. If all columns
* of the process template have their own copies of Y when
* YDIST = 'C', then set IYCOL = -1.
*
* IAROW (input) INTEGER
* The process row that has the first block of A.
* 0 <= IAROW < NPROW.
*
* IACOL (input) INTEGER
* The process column that has the first block of A.
* 0 <= IACOL < NPCOL.
*
* BR1ST (input) CHARACTER*1
* BR1ST determines which vector needs to be broadcast first,
* X or Y, when IXCOL >= 0, and IYROW >= 0.
*
* BR1ST = 'X': X is broadcast first,
* BR1ST = 'Y': Y is broadcast first.
*
* XCOMM (input) CHARACTER*1
* XCOMM specifies the communication scheme of X if XDIST = 'C'.
* It follows topology definition of BLACS.
*
* XWORK (input) CHARACTER*1
* XWORK determines whether X is a workspace or not.
*
* XWORK = 'Y': X is workspace in other processes.
* X is sent to X position in other processes.
* It is assumed that processes have
* sufficient space to store (local) X.
* XWORK = 'N': Data of X in other processes will be
* untouched (unchanged).
*
* YCOMM (input) CHARACTER*1
* YCOMM specifies the columnwise communication scheme of Y.
* It follows topology definition of BLACS.
*
* YWORK (input) CHARACTER*1
* YWORK determines whether Y is a workspace or not.
*
* YWORK = 'Y': Y is workspace in other processes.
* Y is sent to Y position in other processes.
* It is assumed that processes have
* sufficient space to store (local) Y.
* YWORK = 'N': Data of Y in other processes will be
* untouched (unchanged).
*
* WORK (workspace) COMPLEX array of DIMENSION Size(WORK)
* It will store copy of X and/or copy of Y. (see requirements)
*
* Memory Requirement of WORK
* ==========================
*
* MM = M + MZ
* NN = N + NZ
* Mpb = CEIL( MM, MB*NPROW )
* Nqb = CEIL( NN, NB*NPCOL )
* Mp0 = NUMROC( MM, MB, 0, 0, NPROW ) ~= Mpb * MB
* Nq0 = NUMROC( NN, NB, 0, 0, NPCOL ) ~= Nqb * NB
* LCMQ = LCM / NPCOL
* LCMP = LCM / NPROW
*
* (1) XDIST='C' & YDIST = 'C'
* Size(WORK) = Nq0
* + Mp0 (if IXCOL <> -1 & XWORK <> 'Y')
* + MAX[ CEIL(Nqb,LCMQ)*NB (if IYCOL <> -1),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB))
* (if IYCOL = -1) ]
*
* (2) XDIST='C' & YDIST = 'R'
* Size(WORK) = Mp0 (if IXCOL <> -1 & XWORK <> 'Y')
* + Nq0 (if IYROW <> -1 & YWORK <> 'Y')
*
* (3) XDIST='R' & YDIST = 'C'
* Size(WORK) = Mp0 + Nq0
* + MAX[ CEIL(Mpb,LCMP)*MB (if IXROW <> -1),
* CEIL(Mpb,LCMP)*MB*MIN(LCMP,CEIL(MM,MB))
* (if IXROW = -1) ]
* + MAX[ CEIL(Nqb,LCMQ)*NB (if IYCOL <> -1),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB))
* (if IYCOL = -1) ]
*
* (4) XDIST='R' & YDIST = 'R'
* Size(WORK) = Mp0 + Nq0
* + Nq0 (if IYROW <> -1 & YWORK <> 'Y')
* + MAX[ CEIL(Mpb,LCMP)*MB (if IXROW <> -1),
* CEIL(Mpb,LCMP)*MB*MIN(LCMP,CEIL(MM,MB))
* (if IXROW = -1) ]
*
* Notes
* -----
* More precise space can be computed as
*
* CEIL(Mpb,LCMP)*MB => NUMROC( NUMROC(MM,MB,0,0,NPROW), MB, 0, 0, LCMP)
* = NUMROC( Mp0, MB, 0, 0, LCMP )
* CEIL(Nqb,LCMQ)*NB => NUMROC( NUMROC(NN,NB,0,0,NPCOL), NB, 0, 0, LCMQ)
* = NUMROC( Nq0, NB, 0, 0, LCMQ )
*
* =====================================================================
*
* ..
* .. Parameters ..
COMPLEX ONE, ZERO
PARAMETER ( ONE = ( 1.0E+0, 0.0E+0 ),
$ ZERO = ( 0.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
CHARACTER*1 COMMX, COMMY
LOGICAL XCOL, XDATA, YCOL, YDATA
INTEGER INFO, IPX, IPY, MP, MYCOL, MYROW, NPCOL, NPROW,
$ NQ
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER NUMROC
EXTERNAL LSAME, NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, CGEBR2D, CGEBS2D, CGERC,
$ PBCTRNV, PBCVECADD, PXERBLA
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.( ALPHA.EQ.ZERO ) )
$ RETURN
*
CALL BLACS_GRIDINFO( ICONTXT, NPROW, NPCOL, MYROW, MYCOL )
*
XCOL = LSAME( XDIST, 'C' )
YCOL = LSAME( YDIST, 'C' )
*
* Test the input parameters.
*
INFO = 0
IF( .NOT.XCOL .AND. .NOT.LSAME( XDIST, 'R' ) ) THEN
INFO = 2
ELSE IF( .NOT.YCOL .AND. .NOT.LSAME( YDIST, 'R' ) ) THEN
INFO = 3
ELSE IF( M .LT.0 ) THEN
INFO = 4
ELSE IF( N .LT.0 ) THEN
INFO = 5
ELSE IF( MB .LT.1 ) THEN
INFO = 6
ELSE IF( NB .LT.1 ) THEN
INFO = 7
ELSE IF( MZ .LT.0 .OR. MZ .GE. MB ) THEN
INFO = 8
ELSE IF( NZ .LT.0 .OR. NZ .GE. NB ) THEN
INFO = 9
ELSE IF( INCX.EQ.0 ) THEN
INFO = 12
ELSE IF( INCY.EQ.0 ) THEN
INFO = 14
ELSE IF( IAROW.LT.0 .OR. IAROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IACOL.LT.0 .OR. IACOL.GE.NPCOL ) THEN
INFO = 22
END IF
*
10 CONTINUE
IF( INFO .NE. 0 ) THEN
CALL PXERBLA( ICONTXT, 'PBCGERC ', INFO )
RETURN
END IF
*
* Initialize parameters
*
MP = NUMROC( M+MZ, MB, MYROW, IAROW, NPROW )
IF( MYROW.EQ.IAROW ) MP = MP - MZ
NQ = NUMROC( N+NZ, NB, MYCOL, IACOL, NPCOL )
IF( MYCOL.EQ.IACOL ) NQ = NQ - NZ
COMMX = XCOMM
IF( LSAME( COMMX, ' ' ) ) COMMX = '1'
COMMY = YCOMM
IF( LSAME( COMMY, ' ' ) ) COMMY = '1'
*
IF( LDA.LT.MAX(1,MP) ) INFO = 16
*
XDATA = .FALSE.
YDATA = .FALSE.
* ___________ ___________
* | | || | |
* | | || | |
* | | || ___________ | |
* | A | = alpha * |X * -----Y----- + | A |
* | | || | |
* | | || | |
* |___________| || |___________|
*
* Broadcast Y columnwise first, then X rowwise
*
IPX = 1
IPY = 1
*
IF( LSAME( BR1ST, 'Y' ) ) THEN
*
* Broadcast Y to Y or WORK if necessary ( IYROW <> -1 )
*
IF( YCOL ) THEN
IF( IYROW.LT. 0 .OR. IYROW.GE.NPROW ) THEN
INFO = 19
ELSE IF( IYCOL.LT.-1 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 20
END IF
*
IPX = NQ + 1
CALL PBCTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, Y, INCY, ZERO,
$ WORK(IPY), 1, IYROW, IYCOL, -1, IACOL,
$ WORK(IPX) )
*
ELSE
IF( IYROW.LT.-1 .OR. IYROW.GE.NPROW ) THEN
INFO = 19
ELSE IF( IYCOL.NE.IACOL ) THEN
INFO = 20
END IF
*
IF( IYROW.EQ.-1 ) YDATA = .TRUE.
IF( .NOT.YDATA ) THEN
IF( LSAME( YWORK, 'Y' ) ) THEN
IF( MYROW.EQ.IYROW ) THEN
CALL CGEBS2D( ICONTXT, 'Col', COMMY, 1, NQ, Y, INCY )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', COMMY, 1, NQ, Y, INCY,
$ IYROW, MYCOL )
END IF
YDATA = .TRUE.
ELSE
IF( MYROW.EQ.IYROW ) THEN
CALL PBCVECADD( ICONTXT, 'V', NQ, ONE, Y, INCY, ZERO,
$ WORK(IPY), 1 )
CALL CGEBS2D( ICONTXT, 'Col', COMMY, 1, NQ,
$ WORK(IPY), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', COMMY, 1, NQ,
$ WORK(IPY), 1, IYROW, MYCOL )
END IF
IPX = NQ + 1
END IF
END IF
END IF
*
* Broadcast X to X or WORK if necessary ( IXCOL <> -1 )
*
IF( XCOL ) THEN
IF( IXROW.NE.IAROW ) THEN
INFO = 17
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 18
END IF
IF( IXCOL.EQ.-1 ) XDATA = .TRUE.
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXCOL ) THEN
CALL CGEBS2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX,
$ MYROW, IXCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXCOL ) THEN
CALL PBCVECADD( ICONTXT, 'V', MP, ONE, X, INCX, ZERO,
$ WORK(IPX), 1 )
CALL CGEBS2D( ICONTXT, 'Row', COMMX, 1, MP,
$ WORK(IPX), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', COMMX, 1, MP,
$ WORK(IPX), 1, MYROW, IXCOL )
END IF
END IF
END IF
*
ELSE
IF( IXROW.LT.-1 .OR. IXROW.GE.NPROW ) THEN
INFO = 17
ELSE IF( IXCOL.LT. 0 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 18
END IF
*
CALL PBCTRNV( ICONTXT, 'Row', 'T', M, MB, MZ, X, INCX, ZERO,
$ WORK(IPX), 1, IXROW, IXCOL, IAROW, -1,
$ WORK(MP+IPX) )
END IF
*
* Broadcast X rowwise first, then Y columnwise
*
ELSE
*
* Broadcast X to X or WORK if necessary ( IXCOL <> -1 )
*
IF( XCOL ) THEN
IF( IXROW.NE.IAROW ) THEN
INFO = 17
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 18
END IF
IF( IXCOL.EQ.-1 ) XDATA = .TRUE.
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXCOL ) THEN
CALL CGEBS2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX,
$ MYROW, IXCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXCOL ) THEN
CALL PBCVECADD( ICONTXT, 'V', MP, ONE, X, INCX, ZERO,
$ WORK(IPX), 1 )
CALL CGEBS2D( ICONTXT, 'Row', COMMX, 1, MP,
$ WORK(IPX), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', COMMX, 1, MP,
$ WORK(IPX), 1, MYROW, IXCOL )
END IF
IPY = MP + 1
END IF
END IF
ELSE
IF( IXROW.LT.-1 .OR. IXROW.GE.NPROW ) THEN
INFO = 17
ELSE IF( IXCOL.LT. 0 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 18
END IF
*
IPY = MP + 1
CALL PBCTRNV( ICONTXT, 'Row', 'T', M, MB, MZ, X, INCX, ZERO,
$ WORK(IPX), 1, IXROW, IXCOL, IAROW, -1,
$ WORK(IPY) )
END IF
*
* Broadcast Y to Y or WORK if necessary ( IYROW <> -1 )
*
IF( YCOL ) THEN
IF( IYROW.LT. 0 .OR. IYROW.GE.NPROW ) THEN
INFO = 19
ELSE IF( IYCOL.LT.-1 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 20
END IF
*
CALL PBCTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, Y, INCY, ZERO,
$ WORK(IPY), 1, IYROW, IYCOL, -1, IACOL,
$ WORK(IPY+NQ) )
*
ELSE
IF( IYROW.LT.-1 .OR. IYROW.GE.NPROW ) THEN
INFO = 19
ELSE IF( IYCOL.NE.IACOL ) THEN
INFO = 20
END IF
*
IF( IYROW.EQ.-1 ) YDATA = .TRUE.
IF( .NOT.YDATA ) THEN
IF( LSAME( YWORK, 'Y' ) ) THEN
IF( MYROW.EQ.IYROW ) THEN
CALL CGEBS2D( ICONTXT, 'Col', COMMY, 1, NQ, Y, INCY )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', COMMY, 1, NQ, Y, INCY,
$ IYROW, MYCOL )
END IF
YDATA = .TRUE.
ELSE
IF( MYROW.EQ.IYROW ) THEN
CALL PBCVECADD( ICONTXT, 'V', NQ, ONE, Y, INCY, ZERO,
$ WORK(IPY), 1 )
CALL CGEBS2D( ICONTXT, 'Col', COMMY, 1, NQ,
$ WORK(IPY), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', COMMY, 1, NQ,
$ WORK(IPY), 1, IYROW, MYCOL )
END IF
END IF
END IF
END IF
END IF
*
IF( INFO.NE.0 ) GO TO 10
*
* Compute A
*
IF( XDATA ) THEN
IF( YDATA ) THEN
CALL CGERC( MP, NQ, ALPHA, X, INCX, Y, INCY, A, LDA )
ELSE
CALL CGERC( MP, NQ, ALPHA, X, INCX, WORK(IPY), 1, A, LDA )
END IF
ELSE
IF( YDATA ) THEN
CALL CGERC( MP, NQ, ALPHA, WORK(IPX), 1, Y, INCY, A, LDA )
ELSE
CALL CGERC( MP, NQ, ALPHA, WORK(IPX), 1, WORK(IPY), 1,
$ A, LDA )
END IF
END IF
*
RETURN
*
* End of PBCGERC
*
END
|
