1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
|
SUBROUTINE PBCTRMV( ICONTXT, UPLO, TRANS, DIAG, XDIST, N, NB, NZ,
$ A, LDA, X, INCX, IAROW, IACOL, IXPOS, XWORK,
$ MULLEN, WORK )
*
* -- PB-BLAS routine (version 2.1) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory.
* April 28, 1996
*
* Jaeyoung Choi, Oak Ridge National Laboratory
* Jack Dongarra, University of Tennessee and Oak Ridge National Lab.
* David Walker, Oak Ridge National Laboratory
*
* .. Scalar Arguments ..
CHARACTER*1 DIAG, TRANS, UPLO, XDIST, XWORK
INTEGER IACOL, IAROW, ICONTXT, INCX, IXPOS, LDA,
$ MULLEN, N, NB, NZ
* ..
* .. Array Arguments ..
COMPLEX A( LDA, * ), WORK( * ), X( * )
*
* Purpose
* =======
*
* PBCTRMV is a parallel blocked version of the Level 2 BLAS routine
* CTRMV.
* PBCTRMV performs the matrix-matrix operations
*
* X := A*X, or X := A'*X,
*
* where X is an N element vector and A is an N-by-N unit, or non-unit,
* upper or lower triangular matrix.
*
* The first elements of the matrices A is located in the middle of the
* first block ((NZ+1,NZ+1) position) and the first element of X starts
* from the (NZ+1)-th position.
* X is broadcast or transposed if necessary, and the resultant X is
* collected.
*
* Parameters
* ==========
*
* ICONTXT (input) INTEGER
* ICONTXT is the BLACS mechanism for partitioning communication
* space. A defining property of a context is that a message in
* a context cannot be sent or received in another context. The
* BLACS context includes the definition of a grid, and each
* process' coordinates in it.
*
* UPLO (input) CHARACTER*1
* UPLO specifies whether the upper or lower triangular part of
* the symmetric matrix A is to be referenced as follows:
*
* UPLO = 'U', Only the upper triangular part of the
* symmetric matrix is to be referenced.
* UPLO = 'L', Only the lower triangular part of the
* symmetric matrix is to be referenced.
*
* TRANS (input) CHARACTER*1
* TRANS specifies the operation to be performed as follows:
*
* TRANS = 'N', X := A * X.
* TRANS = 'T', X := A**T * X.
* TRANS = 'C', X := A**C * X.
*
* DIAG (input) CHARACTER*1
* DIAG specifies whether or not A is unit triangular as
* follows:
*
* DIAG = 'U', A is assumed to be unit triangular.
* DIAG = 'N', A is not assumed to be unit triangular.
*
* XDIST (input) CHARACTER*1
* XDIST specifies the distribution of vector X as follows:
*
* XDIST = 'C', X is distributed columnwise
* or in a column of processors
* XDIST = 'R', X is distributed rowwise
* or in a row of processors
*
* N (input) INTEGER
* N specifies the (global) number of row and columns of the
* matrix A. N >= 0.
*
* NB (input) INTEGER
* NB specifies the row and column block size of matrix A.
* It also specifies the block size of the vector X. NB >= 1.
*
* NZ (input) INTEGER
* NZ is the row and column offset to specify the row and column
* distance from the beginning of the block to the first
* element of A. And it also specifies the offset to the first
* element of the vector X. 0 <= NZ < NB.
*
* A (input) COMPLEX array of DIMENSION ( LDA, Nq ),
* Before entry with UPLO = 'U', the leading N-by-N upper
* triangular part of the (global) array A must contain the
* upper triangular matrix and the strictly lower triangular
* part of A is not referenced.
* Before entry with UPLO = 'L', the leading N-by-N lower
* triangular part of the (global) array A must contain the
* lower triangular matrix and the strictly upper triangular
* part of A is not referenced.
* Note that when DIAG = 'U', the diagonal elements of A are
* not referenced either, but are assumed to be unity.
*
* LDA (input) INTEGER
* LDA specifies the leading dimension of (local) A as declared
* in the calling (sub) program. LDA >= MAX(1,Np).
*
* X (input/output) COMPLEX array of DIMENSION at least
* ( 1 + ( Np - 1 ) * abs( INCX ) ) if XDIST = 'C', or
* ( 1 + ( Nq - 1 ) * abs( INCX ) ) if XDIST = 'R'.
* The incremented array X must contain the vector X.
* On exit, X is overwritten by the updated vector X.
*
* INCX (input) INTEGER
* INCX specifies the increment for the elements of X.
* INCX <> 0.
*
* IAROW (input) INTEGER
* IAROW specifies a row of the processor template, which holds
* the first block of the matrix A. 0 <= IAROW < NPROW.
*
* IACOL (input) INTEGER
* IACOL specifies a column of the processor template, which
* holds the first block of the matrix A. 0 <= IACOL < NPCOL.
*
* IXPOS (input) INTEGER
* If XDIST = 'C', IXPOS specifies a column of the processor
* template which holds the vector X. If XDIST = 'R', IXPOS
* specifies a row of the processor template which holds the
* vector X.
*
* XWORK (input) CHARACTER*1
* XWORK determines whether X is a workspace or not.
*
* XWORK = 'Y': X is workspace in other processors.
* It is assumed that processors have
* sufficient space to store (local) X.
* XWORK = 'N': Data of X in other processors will be
* untouched (unchanged).
*
* MULLEN (input) INTEGER
* It specifies multiplication length of the optimum column
* number of a block row A for multiplying A with X. The value
* depends on machine characteristics.
*
* WORK (workspace) COMPLEX array of dimension Size(WORK).
* It will store copy of x and/or partial A.
*
* Parameters Details
* ==================
*
* Nx It is a local portion of N owned by a processor, where x is
* replaced by either p (=NPROW) or q (=NPCOL)). The value is
* determined by N, NB, NZ, x, and MI, where NB is a block size,
* NZ is a offset from the beginning of the block, and MI is a
* row or column position in a processor template. Nx is equal
* to or less than Nx0 = CEIL( N+NZ, NB*x ) * NB.
*
* Communication Scheme
* ====================
*
* The communication schemes of the routine are fixed as fan-out and
* fan-in schemes (COMM = '1-tree', for details, see BLACS user's guide)
*
* Memory Requirement of WORK
* ==========================
*
* NN = N + NZ
* Npb = CEIL( NN, NB*NPROW )
* Nqb = CEIL( NN, NB*NPCOL )
* Np0 = NUMROC( NN, NB, 0, 0, NPROW ) ~= Npb * NB
* Nq0 = NUMROC( NN, NB, 0, 0, NPCOL ) ~= Nqb * NB
* LCMP = LCM / NPROW
* LCMQ = LCM / NPCOL
* ISZCMP = CEIL(MULLEN, LCMQ*NB)
* SZCMP = ISZCMP * ISZCMP * LCMQ*NB * LCMP*NB
*
* (1) XDIST = 'Col'
* Size(WORK) = Nq0
* + Np0 (if IXPOS != -1 and XWORK <> 'Y')
* + MAX[ SZCMP,
* CEIL(Nqb,LCMQ)*NB ( if IXPOS <> -1 ),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB))
* ( if IXPOS = -1 ) ]
*
* (2) XDIST = 'Row'
* Size(WORK) = Np0
* + Nq0 (if IXPOS != -1 and XWORK <> 'Y')
* + MAX[ SZCMP,
* CEIL(Npb,LCMP)*NB ( if IXPOS <> -1 ),
* CEIL(Npb,LCMP)*NB*MIN(LCMP,CEIL(NN,NB))
* ( if IXPOS = -1 ) ]
*
* Notes
* -----
* More precise space can be computed as
*
* CEIL(Npb,LCMP)*NB => NUMROC( NUMROC(NN,NB,0,0,NPROW), NB, 0, 0, LCMP)
* = NUMROC( Np0, NB, 0, 0, LCMP )
* CEIL(Nqb,LCMQ)*NB => NUMROC( NUMROC(NN,NB,0,0,NPCOL), NB, 0, 0, LCMQ)
* = NUMROC( Nq0, NB, 0, 0, LCMQ )
*
* =====================================================================
*
* .. Parameters ..
COMPLEX ONE, ZERO
PARAMETER ( ONE = ( 1.0E+0, 0.0E+0 ),
$ ZERO = ( 0.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
CHARACTER*1 FORM
LOGICAL COLUMN, NOTRAN, UPPER, XDATA
INTEGER INFO, IPBZ, IPW, IPX, IPZ, IQBZ, ISZCMP, IZ,
$ JJ, JNPBZ, JNQBZ, JPBZ, JQBZ, JZ, KI, KIZ, KJ,
$ KJZ, KZ, LCM, LCMP, LCMQ, LMW, LNW, LPBZ, LQBZ,
$ MRCOL, MRROW, MYCOL, MYROW, MZCOL, MZROW, NN,
$ NP, NPCOL, NPROW, NQ
COMPLEX DUMMY, TBETA
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER ICEIL, ILCM, NUMROC
EXTERNAL ICEIL, ILCM, LSAME, NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, CCOPY, CGEBR2D, CGEBS2D, CGEMM,
$ CGSUM2D, CLASET, PBCLACP1, PXERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, MIN
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
IF( N.EQ.0 ) RETURN
*
CALL BLACS_GRIDINFO( ICONTXT, NPROW, NPCOL, MYROW, MYCOL )
*
UPPER = LSAME( UPLO, 'U' )
NOTRAN = LSAME( TRANS, 'N' )
COLUMN = LSAME( XDIST, 'C' )
*
* Test the input parameters.
*
INFO = 0
IF( ( .NOT.UPPER ) .AND.
$ ( .NOT.LSAME( UPLO, 'L' ) ) ) THEN
INFO = 2
ELSE IF( .NOT.NOTRAN .AND.
$ .NOT.LSAME( TRANS, 'T' ).AND.
$ .NOT.LSAME( TRANS, 'C' ) ) THEN
INFO = 3
ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
$ .NOT.LSAME( DIAG , 'N' ) ) THEN
INFO = 4
ELSE IF( ( .NOT.COLUMN ).AND.
$ ( .NOT.LSAME( XDIST, 'R') ) ) THEN
INFO = 5
ELSE IF( N .LT.0 ) THEN
INFO = 6
ELSE IF( NB .LT.0 ) THEN
INFO = 7
ELSE IF( NZ .LT.0 .OR. NZ.GE.NB ) THEN
INFO = 8
ELSE IF( INCX.EQ.0 ) THEN
INFO = 12
ELSE IF( IAROW.LT.0 .OR. IAROW.GE.NPROW ) THEN
INFO = 13
ELSE IF( IACOL.LT.0 .OR. IACOL.GE.NPCOL ) THEN
INFO = 14
END IF
*
10 CONTINUE
IF( INFO.NE.0 ) THEN
CALL PXERBLA( ICONTXT, 'PBCTRMV ', INFO )
RETURN
END IF
*
* Start the operations.
*
NN = N + NZ
NP = NUMROC( NN, NB, MYROW, IAROW, NPROW )
IF( MYROW.EQ.IAROW ) NP = NP - NZ
NQ = NUMROC( NN, NB, MYCOL, IACOL, NPCOL )
IF( MYCOL.EQ.IACOL ) NQ = NQ - NZ
*
IZ = 0
IF( MYROW.EQ.IAROW ) IZ = NZ
JZ = 0
IF( MYCOL.EQ.IACOL ) JZ = NZ
KZ = 0
*
* LCM : the least common multiple of NPROW and NPCOL
*
LCM = ILCM( NPROW, NPCOL )
LCMP = LCM / NPROW
LCMQ = LCM / NPCOL
LPBZ = LCMP * NB
LQBZ = LCMQ * NB
*
MRROW = MOD( NPROW+MYROW-IAROW, NPROW )
MRCOL = MOD( NPCOL+MYCOL-IACOL, NPCOL )
XDATA = .FALSE.
IF( LDA.LT.MAX(1,NP) ) INFO = 10
*
* PART 1: Distribute a vector X
* ====================================
*
* If X is distributed columnwise
*
IF( COLUMN ) THEN
*
* Form x := A * x
* _____________
* || |\_ | ||
* || | \_ | ||
* || | \_ | ||
* (x) = | A_ | * (x)
* || | \_ | ||
* || | \_ | ||
* || |____________\| ||
*
IF( IXPOS.LT.0 .OR. IXPOS.GE.NPCOL ) INFO = 15
IF( INFO.NE.0 ) GO TO 10
*
IF( NOTRAN ) THEN
*
* Transpose a column vector X to WORK(IPX)
*
IPZ = 1
IF( LSAME( XWORK, 'Y' ) ) THEN
IPX = 1
XDATA = .TRUE.
ELSE
IPX = NP + 1
END IF
IPW = NQ + IPX
*
CALL PBCTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK(IPX), 1, IAROW, IXPOS, -1, IACOL,
$ WORK(IPW) )
*
IF( XDATA ) THEN
CALL PBCVECADD( ICONTXT, 'G', NP, ZERO, DUMMY, 1, ZERO,
$ X, INCX )
ELSE
CALL PBCVECADD( ICONTXT, 'G', NP, ZERO, DUMMY, 1, ZERO,
$ WORK(IPZ), 1 )
END IF
*
ELSE
*
* Broadcast X if necessary
*
IPZ = 1
IPX = NQ + IPZ
IPW = IPX
*
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXPOS ) THEN
CALL CGEBS2D( ICONTXT, 'Row', '1-tree', 1, NP, X, INCX )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', '1-tree', 1, NP, X, INCX,
$ MYROW, IXPOS )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXPOS ) THEN
CALL CCOPY( NP, X, INCX, WORK(IPX), 1 )
CALL CGEBS2D( ICONTXT, 'Row', '1-tree', 1, NP,
$ WORK(IPX), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Row', '1-tree', 1, NP,
$ WORK(IPX), 1, MYROW, IXPOS )
END IF
IPW = NP + IPX
END IF
*
CALL PBCVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK(IPZ), 1 )
END IF
*
* If X is distributed rowwise
*
ELSE
*
* Form x := A * x
* _____________
* |\_ |
* | \_ |
* | \_ |
* =====(x)===== = | A_ | * =====(x)=====
* | \_ |
* | \_ |
* |____________\|
*
IF( IXPOS.LT.0 .OR. IXPOS.GE.NPROW ) INFO = 15
IF( INFO.NE.0 ) GO TO 10
*
IF( NOTRAN ) THEN
*
* Broadcast X if necessary
*
IPZ = 1
IPX = NP + IPZ
IPW = IPX
*
IF( XDATA ) THEN
IF( MYROW.EQ.IXPOS ) THEN
CALL CGEBS2D( ICONTXT, 'Col', '1-tree', 1, NQ, X, INCX )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', '1-tree', 1, NQ, X, INCX,
$ IXPOS, MYCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYROW.EQ.IXPOS ) THEN
CALL CCOPY( NQ, X, INCX, WORK(IPX), 1 )
CALL CGEBS2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPX), 1 )
ELSE
CALL CGEBR2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPX), 1, IXPOS, MYCOL )
END IF
IPW = NQ + IPX
END IF
*
CALL PBCVECADD( ICONTXT, 'G', NP, ZERO, DUMMY, 1, ZERO,
$ WORK(IPZ), 1 )
*
* Transpose a row vector X to WORK(IPX)
*
ELSE
*
IPZ = 1
IF( LSAME( XWORK, 'Y' ) ) THEN
IPX = 1
XDATA = .TRUE.
ELSE
IPX = NQ + IPZ
END IF
IPW = NP + IPX
*
CALL PBCTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK(IPX), 1, IXPOS, IACOL, IAROW, -1,
$ WORK(IPW) )
*
IF( XDATA ) THEN
CALL PBCVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ X, INCX )
ELSE
CALL PBCVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK(IPZ), 1 )
END IF
END IF
END IF
*
* PART 2: Compute x <= A * x
* ==========================
*
IF( NP.EQ.0 .OR. NQ.EQ.0 ) GO TO 100
*
* If A is an upper triangular matrix,
*
IF( UPPER ) THEN
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 50 JJ = 1, ICEIL(NQ+JZ, IQBZ)
LMW = MIN( IPBZ-IZ, NP-JPBZ )
LNW = MIN( IQBZ-JZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
JNQBZ = JQBZ + LNW
*
* Copy the upper triangular matrix A to WORK(IPW)
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
IF( MYCOL.EQ.IACOL ) KZ = JZ
*
DO 30 KJ = 0, LCMQ-1
20 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 20
END IF
KIZ = MAX( 0, KI*NB-IZ )
KJZ = MAX( 0, KJ*NB-JZ )
IF( KJZ.GE.LNW ) GO TO 40
FORM = 'G'
IF( MZROW.EQ.MZCOL ) FORM = 'T'
MZCOL = MZCOL + NPCOL
*
CALL PBCLACP1( ICONTXT, 'Upper', FORM, DIAG, KIZ, NB, KZ,
$ A(JPBZ+1,JQBZ+KJZ+1), LDA, WORK(KJZ*LMW+IPW),
$ LMW, LPBZ, LQBZ, LMW, LNW-KJZ )
KZ = 0
30 CONTINUE
*
* Compute X
*
40 CONTINUE
IF( COLUMN ) THEN
IF( NOTRAN ) THEN
IF( XDATA ) THEN
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), WORK(JQBZ+IPX), 1, ZERO,
$ X(JPBZ*INCX+1), INCX )
CALL CGEMV( 'No', JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(JQBZ+IPX), 1, ONE, X, INCX )
ELSE
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW), MAX(1,LMW),
$ WORK(JQBZ+IPX), 1, ZERO, WORK(JPBZ+IPZ), 1 )
CALL CGEMV( 'No', JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(JQBZ+IPX), 1, ONE, WORK(IPZ), 1 )
END IF
ELSE
IF( XDATA ) THEN
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), X(JPBZ*INCX+1), INCX,
$ ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ X, INCX, ONE, WORK(JQBZ+IPZ), 1 )
ELSE
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),MAX(1,LMW),
$ WORK(JPBZ+IPX), 1, ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(IPX), 1, ONE, WORK(JQBZ+IPZ), 1 )
END IF
END IF
*
ELSE
IF( NOTRAN ) THEN
IF( XDATA ) THEN
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), X(JQBZ*INCX+1), INCX,
$ ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( 'No', JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ X(JQBZ*INCX+1), INCX, ONE, WORK(IPZ), 1 )
ELSE
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW), MAX(1,LMW),
$ WORK(JQBZ+IPX), 1, ZERO, WORK(JPBZ+IPZ), 1 )
CALL CGEMV( 'No', JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(JQBZ+IPX), 1, ONE, WORK(IPZ), 1 )
END IF
ELSE
IF( XDATA ) THEN
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), WORK(JPBZ+IPX), 1, ZERO,
$ X(JQBZ*INCX+1), INCX )
CALL CGEMV( TRANS, JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(IPX), 1, ONE, X(JQBZ*INCX+1), INCX )
ELSE
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),MAX(1,LMW),
$ WORK(JPBZ+IPX), 1, ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, JPBZ, LNW, ONE, A(1,JQBZ+1), LDA,
$ WORK(IPX), 1, ONE, WORK(JQBZ+IPZ), 1 )
END IF
END IF
END IF
*
JPBZ = JNPBZ
JQBZ = JNQBZ
IZ = 0
JZ = 0
50 CONTINUE
*
* If A is a lower triangular matrix,
*
ELSE
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
TBETA = ZERO
*
DO 90 JJ = 1, ICEIL(NQ+JZ, IQBZ)
LMW = MIN( IPBZ-IZ, NP-JPBZ )
LNW = MIN( IQBZ-JZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
JNQBZ = JQBZ + LNW
*
* Copy the lower triangular matrix A to WORK(IPW)
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
IF( MYCOL.EQ.IACOL ) KZ = JZ
*
DO 70 KJ = 0, LCMQ-1
60 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 60
END IF
KIZ = MAX( 0, KI*NB-IZ )
KJZ = MAX( 0, KJ*NB-JZ )
IF( KJZ.GE.LNW ) GO TO 80
FORM = 'G'
IF( MZROW.EQ.MZCOL ) FORM = 'T'
MZCOL = MZCOL + NPCOL
*
CALL PBCLACP1( ICONTXT, 'Lower', FORM, DIAG, KIZ, NB, KZ,
$ A(JPBZ+1,JQBZ+KJZ+1), LDA, WORK(KJZ*LMW+IPW),
$ LMW, LPBZ, LQBZ, LMW, LNW-KJZ )
KZ = 0
70 CONTINUE
*
* Compute X
*
80 CONTINUE
IF( COLUMN ) THEN
IF( NOTRAN ) THEN
IF( XDATA ) THEN
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), WORK(JQBZ+IPX), 1, TBETA,
$ X(JPBZ*INCX+1),INCX )
CALL CGEMV( 'No', NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, WORK(JQBZ+IPX), 1,
$ TBETA, X(JNPBZ*INCX+1), INCX )
ELSE
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW), MAX(1,LMW),
$ WORK(JQBZ+IPX), 1, TBETA, WORK(JPBZ+IPZ),1 )
CALL CGEMV( 'No', NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, WORK(JQBZ+IPX), 1,
$ TBETA, WORK(JNPBZ+IPZ), 1 )
END IF
ELSE
IF( XDATA ) THEN
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), X(JPBZ*INCX+1), INCX,
$ ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, X(JNPBZ*INCX+1),
$ INCX, ONE, WORK(JQBZ+IPZ), 1 )
ELSE
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),MAX(1,LMW),
$ WORK(JPBZ+IPX), 1, ZERO, WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, WORK(JNPBZ+IPX), 1,
$ ONE, WORK(JQBZ+IPZ), 1 )
*
END IF
END IF
*
ELSE
IF( NOTRAN ) THEN
IF( XDATA ) THEN
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), X(JQBZ*INCX+1), INCX,
$ TBETA, WORK(JPBZ+IPZ), 1 )
CALL CGEMV( 'No', NP-JNPBZ, LNW, ONE, A(JNPBZ+1,JQBZ+1),
$ LDA, X(JQBZ*INCX+1), INCX, TBETA,
$ WORK(JNPBZ+IPZ), 1 )
ELSE
CALL CGEMV( 'No', LMW, LNW, ONE, WORK(IPW), MAX(1,LMW),
$ WORK(JQBZ+IPX),1, TBETA, WORK(JPBZ+IPZ),1 )
CALL CGEMV( 'No', NP-JNPBZ, LNW, ONE, A(JNPBZ+1,JQBZ+1),
$ LDA, WORK(JQBZ+IPX), 1, TBETA,
$ WORK(JNPBZ+IPZ), 1 )
END IF
ELSE
IF( XDATA ) THEN
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), WORK(JPBZ+IPX), 1,
$ ZERO, X(JQBZ*INCX+1), INCX )
CALL CGEMV( TRANS, NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, WORK(JNPBZ+IPX), 1,
$ ONE, X(JQBZ*INCX+1), INCX )
ELSE
CALL CGEMV( TRANS, LMW, LNW, ONE, WORK(IPW),
$ MAX(1,LMW), WORK(JPBZ+IPX), 1, ZERO,
$ WORK(JQBZ+IPZ), 1 )
CALL CGEMV( TRANS, NP-JNPBZ, LNW, ONE,
$ A(JNPBZ+1,JQBZ+1), LDA, WORK(JNPBZ+IPX), 1,
$ ONE, WORK(JQBZ+IPZ), 1 )
END IF
END IF
END IF
*
TBETA = ONE
JPBZ = JNPBZ
JQBZ = JNQBZ
IZ = 0
JZ = 0
90 CONTINUE
END IF
*
100 CONTINUE
*
* PART 3: Collect X, and transpose it if necessary
* ================================================
*
IF( COLUMN ) THEN
*
* Add WORK(IPZ) rowwise
*
IF( NOTRAN ) THEN
IF( XDATA ) THEN
CALL CGSUM2D( ICONTXT, 'Row', '1-tree', 1, NP, X, INCX,
$ MYROW, IXPOS )
ELSE
IF( MYCOL.EQ.IXPOS ) THEN
CALL CCOPY( NP, WORK(IPZ), 1, X, INCX )
CALL CGSUM2D( ICONTXT, 'Row', '1-tree', 1, NP, X, INCX,
$ MYROW, IXPOS )
ELSE
CALL CGSUM2D( ICONTXT, 'Row', '1-tree', 1, NP, WORK(IPZ),
$ 1, MYROW, IXPOS )
END IF
END IF
*
* Add WORK(IPZ) columnwise
*
ELSE
CALL CGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, WORK(IPZ), 1,
$ IAROW, MYCOL)
CALL PBCTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, WORK(IPZ), 1,
$ ZERO, X, INCX, IAROW, IACOL, IAROW, IXPOS,
$ WORK(IPX) )
END IF
*
ELSE
*
* Add WORK(IPZ) rowwise
*
IF( NOTRAN ) THEN
CALL CGSUM2D( ICONTXT, 'Row', '1-tree', 1, NP, WORK(IPZ), 1,
$ MYROW, IACOL)
CALL PBCTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, WORK(IPZ), 1,
$ ZERO, X, INCX, IAROW, IACOL, IXPOS, IACOL,
$ WORK(IPX) )
*
* Add WORK(IPZ) columnwise
*
ELSE
IF( XDATA ) THEN
CALL CGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, X, INCX,
$ IXPOS, MYCOL )
ELSE
IF( MYROW.EQ.IXPOS ) THEN
CALL CCOPY( NQ, WORK(IPZ), 1, X, INCX )
CALL CGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, X, INCX,
$ IXPOS, MYCOL )
ELSE
CALL CGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, WORK(IPZ),
$ 1, IXPOS, MYCOL )
END IF
END IF
END IF
END IF
*
RETURN
*
* End of PBCTRMV
*
END
|
