1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
|
SUBROUTINE PBDGEMV( ICONTXT, TRANS, XDIST, YDIST, M, N, MB, NB,
$ MZ, NZ, ALPHA, A, LDA, X, INCX, BETA, Y, INCY,
$ IAROW, IACOL, IXROW, IXCOL, IYROW, IYCOL,
$ XCOMM, XWORK, YWORK, WORK )
*
* -- PB-BLAS routine (version 2.1) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory.
* April 28, 1996
*
* Jaeyoung Choi, Oak Ridge National Laboratory
* Jack Dongarra, University of Tennessee and Oak Ridge National Lab.
* David Walker, Oak Ridge National Laboratory
*
* .. Scalar Arguments ..
CHARACTER*1 TRANS, XCOMM, XDIST, XWORK, YDIST, YWORK
INTEGER IACOL, IAROW, ICONTXT, INCX, INCY, IXCOL,
$ IXROW, IYCOL, IYROW, LDA, M, MB, MZ, N, NB, NZ
DOUBLE PRECISION ALPHA, BETA
* ..
* .. Array Arguments ..
DOUBLE PRECISION A( LDA, * ), X( * ), Y( * ), WORK( * )
* ..
*
* Purpose
* =======
*
* PBDGEMV is a parallel blocked version of DGEMV.
* PBDGEMV performs one of the matrix-vector operations based on block
* cyclic distribution.
*
* y := alpha*A*x + beta*y, or y := alpha*A'*x + beta*y,
*
* where alpha and beta are scalars, x and y are vectors and A is an
* M-by-N matrix.
*
* The first element of the matrices A is located in the middle of
* the first block ((MZ+1,NZ+1) position). If TRANS = `N', the first
* elements of X and Y start from (NZ+1)-th position and (MZ+1)-th
* position, respectively, otherwise (MZ+1)-th position and (NZ+1)-th
* position, respectively.
*
* X is broadcast columnwise or rowwise if necessary, and the resultant
* Y is collected.
*
* Parameters
* ==========
*
* ICONTXT (input) INTEGER
* ICONTXT is the BLACS mechanism for partitioning communication
* space. A defining property of a context is that a message in
* a context cannot be sent or received in another context. The
* BLACS context includes the definition of a grid, and each
* process' coordinates in it.
*
* TRANS (input) CHARACTER*1
* TRANS specifies the operation to be performed as follows:
*
* TRANS = 'N', y := alpha*A*x + beta*y.
* TRANS = 'T', y := alpha*A'*x + beta*y.
* TRANS = 'C', y := alpha*A'*x + beta*y.
*
* XDIST (input) CHARACTER*1
* XDIST specifies the distribution of vector x as follows:
*
* XDIST = 'C', x is distributed columnwise
* or in a column of processes
* XDIST = 'R', x is distributed rowwise
* or in a row of processes
*
* YDIST (input) CHARACTER*1
* YDIST specifies the distribution of vector y as follows:
*
* YDIST = 'C', y is distributed columnwise
* or in a column of processes
* YDIST = 'R', y is distributed rowwise
* or in a row of processes
*
* M (input) INTEGER
* M specifies the (global) number of rows of the matrix A.
* M >= 0.
*
* N (input) INTEGER
* N specifies the (global) number of columns of the matrix A.
* N >= 0.
*
* MB (input) INTEGER
* MB specifies the row block size of the matrix A. It also
* specifies the block size of the vector Y if TRANS = 'N', or
* the vector X if TRANS = 'T'/'C'. MB >= 1.
*
* NB (input) INTEGER
* NB specifies the column block size of the matrix A. It also
* specifies the block size of the vector X if TRANS = 'N', or
* the vector Y if TRANS = 'T'/'C'. NB >= 1.
*
* MZ (input) INTEGER
* MZ is the row offset to specify the row distance from the
* beginning of the block to the first element of A.
* It also specifies the offset to the first element of Y if
* TRANS = 'N', or to the first element of X if TRANS = 'T'/'C'.
* 0 <= MZ < MB.
*
* NZ (input) INTEGER
* NZ is the column offset to specify the column distance from
* the beginning of the block to the first element of A. It
* also specifies the offset to the first element of X if TRANS
* = 'N', or to the first element of Y if TRANS = 'T'/'C'.
* 0 <= NZ < NB.
*
* ALPHA (input) DOUBLE PRECISION
* ALPHA specifies the scalar alpha.
*
* A (input) DOUBLE PRECISION array of DIMENSION ( LDA, Nq ),
* The leading Mp-by-Nq part of the array A must contain the
* matrix A.
*
* LDA (input) INTEGER
* LDA specifies the first dimension of (local) A as declared
* in the calling (sub) program. LDA >= MAX(1,Mp).
*
* X (input) DOUBLE PRECISION array of DIMENSION at least
* (1+(Np-1)*abs(INCX)) if TRANS = 'N' and XDIST = 'C',
* (1+(Nq-1)*abs(INCX)) if TRANS = 'N' and XDIST = 'R',
* (1+(Mp-1)*abs(INCX)) if TRANS = 'T'/'C' and XDIST = 'C',
* (1+(Mq-1)*abs(INCX)) if TRANS = 'T'/'C' and XDIST = 'R'.
* The incremented array X must contain the vector X.
*
* INCX (input) INTEGER
* INCX specifies the increment for the elements of X.
* INCX <> 0.
*
* BETA (input) DOUBLE PRECISION
* BETA specifies the scalar beta. When BETA is supplied as
* zero then Y need not be set on input.
*
* Y (input/output) DOUBLE PRECISION array of DIMENSION at least
* (1+(Mp-1)*abs(INCY)) if TRANS = 'N' and YDIST = 'C',
* (1+(Mq-1)*abs(INCY)) if TRANS = 'N' and YDIST = 'R',
* (1+(Np-1)*abs(INCY)) if TRANS = 'T'/'C' and YDIST = 'C',
* (1+(Nq-1)*abs(INCY)) if TRANS = 'T'/'C' and YDIST = 'R'.
* On entry with BETA non-zero, the incremented array Y must
* contain the vector Y.
* On exit, Y is overwritten by the updated vector Y.
*
* INCY (input) INTEGER
* INCY specifies the increment for the elements of Y.
* INCY <> 0.
*
* IAROW (input) INTEGER
* IAROW specifies a row of the process template, which holds
* the first block of the matrix A.
*
* IACOL (input) INTEGER
* IACOL specifies a column of the process template, which
* holds the first block of the matrix A.
*
* IXROW (input) INTEGER
* IXROW specifies the current row of process template
* which has the first element of X. If all row processes
* have their own copies of X, which is a row vector,
* set IXROW = -1.
*
* IXCOL (input) INTEGER
* IXCOL specifies the current column of process template
* which has the first element of X. If all column processes
* have their own copies of X, which is a column vector, set
* IXCOL = -1.
*
* IYROW (input) INTEGER
* IYROW specifies the current row of process template which
* has the first element of Y.
*
* IYCOL (input) INTEGER
* IYCOL specifies the current column of process template
* which has the first element of Y.
*
* XCOMM (input) CHARACTER*1
* XCOMM specifies the communication scheme of row or column of
* X. It follows topology definition of BLACS. If vector
* transpose of X is involved, the value is ignored and
* it is set to '1-tree'.
*
* XWORK (input) CHARACTER*1
* XWORK determines whether X is a workspace or not.
*
* XWORK = 'Y': X is workspace in other processes.
* X is sent to X position in other processes.
* It is assumed that processes have
* sufficient space to store (local) X.
* XWORK = 'N': Data in X will be untouched (unchanged).
*
* If transposition of X is involved with the computation of Y,
* the argument is ignored.
*
* YWORK (input) CHARACTER*1
* YWORK determines whether Y is a workspace or not.
*
* YWORK = 'Y': Y is workspace in other processes.
* It is assumed that processes have
* sufficient space to store temporary
* (local) Y.
* YWORK = 'N': Data in Y will be untouched (unchanged)
* in other processes.
*
* If transposition of Y is required during computation,
* the argument is ignored.
*
* WORK (workspace) DOUBLE PRECISION array of dimension Size(WORK).
* It will store copy of X and/or copy of Y. (see requirements)
*
* Parameters Details
* ==================
*
* Lx It is a local portion of L (L is replaced by either M or N,
* and x is replaced by either p (=NPROW) or q (=NPCOL)), owned
* by a process. The value is determined by L, LB, LZ, x, and
* MI, where LB is a block size, LZ is a offset from the
* beginning of the block, MI is a row or column position in
* process template. Lx is equal to or less than CEIL( L+LZ,
* LB*x ) * LB.
*
* Memory Requirement of WORK
* ==========================
*
* MM = M + MZ
* NN = N + NZ
* Mpb = CEIL( MM, MB*NPROW )
* Nqb = CEIL( NN, NB*NPCOL )
* Mp0 = NUMROC( MM, MB, 0, 0, NPROW ) ~= Mpb * MB
* Nq0 = NUMROC( NN, NB, 0, 0, NPCOL ) ~= Nqb * NB
* LCMQ = LCM / NPCOL
* LCMP = LCM / NPROW
*
* (1) TRANS = 'N'
* (i) XDIST = 'Col' & YDIST = 'Col'
* Size(WORK) = Nq0
* + MAX[ Mp0 (if YWORK <> 'Y'),
* CEIL(Nqb,LCMQ)*NB (if IXCOL <> -1),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB))
* (if IXCOL = -1) ]
* (ii) XDIST = 'Col' & YDIST = 'Row'
* Size(WORK) = Mp0
* + MAX[ CEIL(Mpb,LCMP)*MB,
* Nq0 + MAX[ CEIL(Nqb,LCMQ)*NB (if IXCOL <> -1),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB))
* (if IXCOL = -1) ] ]
*
* (iii) XDIST = 'Row' & YDIST = 'Col'
* Size(WORK) = Nq0 (if XWORK <> 'Y' & IXCOL <> -1)
* + Mp0 (if YWORK <> 'Y')
*
* (iv) XDIST = 'Row' & YDIST = 'Row'
* Size(WORK) = Mp0
* + MAX[ Nq0 (if XWORK <> 'Y' & IXCOL <> -1),
* CEIL(Mqb,LCMQ)*MB ]
*
* (2) TRANS = 'T'/'C'
* (i) XDIST = 'Col' & YDIST = 'Col'
* Size(WORK) = Nq0
* + MAX[ CEIL(Npb,LCMP)*NB,
* Mp0 (if XWORK <> 'Y' & IXCOL <> -1) ]
*
* (ii) XDIST = 'Col' & YDIST = 'Row'
* Size(WORK) = Mp0 (if XWORK <> 'Y' & IXCOL <> -1)
* + Nq0 (if YWORK <> 'Y')
*
* (iii) XDIST = 'Row' & YDIST = 'Col'
* Size(WORK) = Nq0
* + MAX[ CEIL(Nqb,LCMQ)*NB,
* Mp0 + MAX[ CEIL(Mpb,LCMP)*MB (if IXROW <> -1),
* CEIL(Mpb,LCMP)*MB*MIN(LCMP,CEIL(MM,MB))
* (if IXROW = -1) ] ]
*
* (iv) XDIST = 'Row' & YDIST = 'Row'
* Size(WORK) = Mp0
* + MAX[ Nq0 (if YWORK <> 'Y'),
* CEIL(Mpb,LCMP)*MB (if IXROW <> -1),
* CEIL(Mpb,LCMP)*MB*MIN(LCMP,CEIL(MM,MB))
* (if IXROW = -1) ]
*
* Notes
* -----
* More precise space can be computed as
*
* CEIL(Mpb,LCMP)*MB => NUMROC( NUMROC(MM,MB,0,0,NPROW), MB, 0, 0, LCMP)
* = NUMROC( Mp0, MB, 0, 0, LCMP )
* CEIL(Nqb,LCMQ)*NB => NUMROC( NUMROC(NN,NB,0,0,NPCOL), NB, 0, 0, LCMQ)
* = NUMROC( Nq0, NB, 0, 0, LCMQ )
*
* =====================================================================
*
* ..
* .. Parameters ..
DOUBLE PRECISION ONE, ZERO
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
* ..
* .. Local Scalars ..
CHARACTER*1 COMMX
LOGICAL NOTRAN, XDATA, XCOL, YCOL
INTEGER INFO, IPX, IPY, MP, MYCOL, MYROW, NPCOL, NPROW,
$ NQ
DOUBLE PRECISION DUMMY, TBETA
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER NUMROC
EXTERNAL LSAME, NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, DGEBR2D, DGEBS2D, DGEMV,
$ DGSUM2D, PBDTRNV, PBDVECADD, PXERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC MOD
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
IF( M.EQ.0 .OR. N.EQ.0 .OR. ( ALPHA.EQ.ZERO .AND. BETA.EQ.ONE ) )
$ RETURN
*
CALL BLACS_GRIDINFO( ICONTXT, NPROW, NPCOL, MYROW, MYCOL )
*
NOTRAN = LSAME( TRANS, 'N' )
XCOL = LSAME( XDIST, 'C' )
YCOL = LSAME( YDIST, 'C' )
*
* Test the input parameters.
*
INFO = 0
IF( ( .NOT.NOTRAN ).AND.
$ ( .NOT.LSAME( TRANS, 'C' ) ).AND.
$ ( .NOT.LSAME( TRANS, 'T' ) ) ) THEN
INFO = 2
ELSE IF( ( .NOT.XCOL ).AND.
$ ( .NOT.LSAME( XDIST, 'R' ) ) ) THEN
INFO = 3
ELSE IF( ( .NOT.YCOL ).AND.
$ ( .NOT.LSAME( YDIST, 'R' ) ) ) THEN
INFO = 4
ELSE IF( M .LT.0 ) THEN
INFO = 5
ELSE IF( N .LT.0 ) THEN
INFO = 6
ELSE IF( MB .LT.1 ) THEN
INFO = 7
ELSE IF( NB .LT.1 ) THEN
INFO = 8
ELSE IF( MZ .LT.0 .OR. MZ .GE. MB ) THEN
INFO = 9
ELSE IF( NZ .LT.0 .OR. NZ .GE. NB ) THEN
INFO = 10
ELSE IF( INCX.EQ.0 ) THEN
INFO = 15
ELSE IF( INCY.EQ.0 ) THEN
INFO = 18
ELSE IF( IAROW.LT.0 .OR. IAROW.GE.NPROW ) THEN
INFO = 19
ELSE IF( IACOL.LT.0 .OR. IACOL.GE.NPCOL ) THEN
INFO = 20
END IF
*
10 CONTINUE
IF( INFO.NE.0 ) THEN
CALL PXERBLA( ICONTXT, 'PBDGEMV ', INFO )
RETURN
END IF
*
* Quick return if possible.
*
IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
$ ( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
$ RETURN
*
* Initialize parameters
*
MP = NUMROC( M+MZ, MB, MYROW, IAROW, NPROW )
IF( MYROW.EQ.IAROW ) MP = MP - MZ
NQ = NUMROC( N+NZ, NB, MYCOL, IACOL, NPCOL )
IF( MYCOL.EQ.IACOL ) NQ = NQ - NZ
IF( LDA.LT.MAX(1,MP) ) INFO = 13
COMMX = XCOMM
IF( LSAME( COMMX, ' ' ) ) COMMX = '1'
*
* Start the operations.
*
* If A is not transposed,
*
IF( NOTRAN ) THEN
IF( XCOL ) THEN
IF( YCOL ) THEN
*
* Form y := alpha*A*x + beta*y,
* where x and y are distributed columnwise.
* __________
* || | | ||
* || | | || ||
* || | | || ||
* (y) = alpha * | A | * (x) + beta *(y)
* || | | || ||
* || | | || ||
* || |__________| ||
*
IF( IXROW.LT.0 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.NE.IAROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Transpose X to WORK
*
IPY = NQ + 1
CALL PBDTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK, 1, IXROW, IXCOL, -1, IACOL, WORK(IPY) )
*
* Compute Y if Y is distributed columnwise
*
IF( LSAME( YWORK, 'Y' ) ) THEN
TBETA = ZERO
IF( MYCOL.EQ.IYCOL ) TBETA = BETA
*
IF( NQ.GT.0 ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK, 1, TBETA,
$ Y, INCY )
ELSE IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL
$ .OR. MYCOL.EQ.IYCOL ) THEN
CALL PBDVECADD( ICONTXT, 'V', MP, ZERO, DUMMY, 1, TBETA,
$ Y, INCY )
END IF
*
* Add Y rowwise
*
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, Y, INCY,
$ MYROW, IYCOL )
*
ELSE
IF( NQ.GT.0 ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK, 1, ZERO,
$ WORK(IPY), 1 )
ELSE
CALL PBDVECADD( ICONTXT, 'G', MP, ZERO, DUMMY, 1, ZERO,
$ WORK(IPY), 1 )
END IF
*
* Add WORK(IPY) rowwise
*
IF( MYCOL.EQ.IYCOL ) THEN
CALL PBDVECADD( ICONTXT, 'G', MP, ONE, WORK(IPY), 1,
$ BETA, Y, INCY )
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, Y,
$ INCY, MYROW, IYCOL )
ELSE
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ WORK(IPY), 1, MYROW, IYCOL )
END IF
END IF
*
ELSE
*
* Form y := alpha*A*x + beta*y,
* where x is distributed columnwise & y is distributed rowwise
* __________
* | |
* | | ||
* | | ||
* =====(y)===== = a * | A | * (x) + b * =====(y)=====
* | | ||
* | | ||
* |__________|
*
IF( IXROW.LT.0 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Transpose X to WORK
*
IPX = MP + 1
CALL PBDTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK(IPX), 1, IXROW, IXCOL, -1, IACOL,
$ WORK(NQ+IPX) )
*
IF( NQ.GT.0 ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK(IPX), 1,
$ ZERO, WORK, 1 )
ELSE
CALL PBDVECADD( ICONTXT, 'G', MP, ZERO, DUMMY, 1, ZERO,
$ WORK, 1 )
END IF
*
* Add Y (=WORK) rowwise and transpose it.
*
IF( N+NZ.GT.NB )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, WORK, 1,
$ MYROW, IACOL )
CALL PBDTRNV( ICONTXT, 'Col', 'T', M, MB, MZ, WORK, 1, BETA,
$ Y, INCY, IAROW, IACOL, IYROW, IYCOL,
$ WORK(IPX) )
END IF
*
ELSE
IF( YCOL ) THEN
*
* Form y := alpha*A*x + beta*y,
* where x is distributed rowwise & y is distributed columnwise
* __________
* || | | ||
* || | | ||
* || | | ||
* (y) = alpha*| A |* ====(x)=== + beta*(y)
* || | | ||
* || | | ||
* || |__________| ||
*
IF( IXROW.LT.-1 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.NE.IACOL ) THEN
INFO = 22
ELSE IF( IYROW.NE.IAROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
XDATA = .FALSE.
IF( IXROW.EQ.-1 ) XDATA = .TRUE.
IPY = 1
*
* Broadcast X to X or WORK if necessary ( IXCOL <> -1 )
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYROW.EQ.IXROW ) THEN
CALL DGEBS2D( ICONTXT, 'Col', COMMX, 1, NQ, X, INCX )
ELSE
CALL DGEBR2D( ICONTXT, 'Col', COMMX, 1, NQ, X, INCX,
$ IXROW, MYCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYROW.EQ.IXROW ) THEN
CALL PBDVECADD( ICONTXT, 'V', NQ, ONE, X, INCX, ZERO,
$ WORK, 1 )
CALL DGEBS2D( ICONTXT, 'Col', COMMX, 1, NQ, WORK, 1 )
ELSE
CALL DGEBR2D( ICONTXT, 'Col', COMMX, 1, NQ, WORK, 1,
$ IXROW, MYCOL )
END IF
IPY = NQ + 1
END IF
END IF
*
* Compute Y
*
IF( LSAME( YWORK, 'Y' ) ) THEN
TBETA = ZERO
IF( MYCOL.EQ.IYCOL ) TBETA = BETA
*
IF( NQ.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, X, INCX,
$ TBETA, Y, INCY )
ELSE
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK, 1,
$ TBETA, Y, INCY )
END IF
ELSE IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL
$ .OR. MYCOL.EQ.IYCOL ) THEN
CALL PBDVECADD( ICONTXT, 'V', MP, ZERO, DUMMY, 1, TBETA,
$ Y, INCY )
END IF
*
* Add Y rowwise
*
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, Y, INCY,
$ MYROW, IYCOL )
ELSE
IF( NQ.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, X, INCX,
$ ZERO, WORK(IPY), 1 )
ELSE
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK, 1,
$ ZERO, WORK(IPY), 1 )
END IF
ELSE
CALL PBDVECADD( ICONTXT, 'G', MP, ZERO, DUMMY, 1, ZERO,
$ WORK(IPY), 1 )
END IF
*
* Add Y rowwise
*
IF( MYCOL.EQ.IYCOL ) THEN
CALL PBDVECADD( ICONTXT, 'G', MP, ONE, WORK(IPY), 1,
$ BETA, Y, INCY )
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, Y,
$ INCY, MYROW, IYCOL )
ELSE
IF( N+NZ.GT.NB .OR. IACOL.NE.IYCOL )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ WORK(IPY), 1, MYROW, IYCOL )
END IF
END IF
*
ELSE
*
* Form y := alpha*A*x + beta*y,
* where x and y are distributed rowwise.
* __________
* | |
* | |
* | |
* ======(y)===== = a*| A |* ====(x)=== + b* ======(y)=====
* | |
* | |
* |__________|
*
IF( IXROW.LT.0 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.NE.IACOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
XDATA = .FALSE.
IF( IXROW.EQ.-1 ) XDATA = .TRUE.
IPX = MP + 1
*
* Broadcast X to X or WORK(IPX) if necessary ( IXCOL <> -1 )
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYROW.EQ.IXROW ) THEN
CALL DGEBS2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ X, INCX )
ELSE
CALL DGEBR2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ X, INCX, IXROW, MYCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYROW.EQ.IXROW ) THEN
CALL PBDVECADD( ICONTXT, 'V', NQ, ONE, X, INCX, ZERO,
$ WORK(IPX), 1 )
CALL DGEBS2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPX), 1 )
ELSE
CALL DGEBR2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPX), 1, IXROW, MYCOL )
END IF
END IF
END IF
*
* Compute Y
*
IF( NQ.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, X, INCX,
$ ZERO, WORK, 1 )
ELSE
CALL DGEMV( 'No', MP, NQ, ALPHA, A, LDA, WORK(IPX), 1,
$ ZERO, WORK, 1 )
END IF
ELSE
CALL PBDVECADD( ICONTXT, 'G', MP, ZERO, DUMMY, 1, ZERO,
$ WORK, 1 )
END IF
*
* Add Y rowwise and transpose it.
*
IF( N+NZ.GT.NB )
$ CALL DGSUM2D( ICONTXT, 'Row', '1-tree', 1, MP, WORK, 1,
$ MYROW, IACOL )
CALL PBDTRNV( ICONTXT, 'Col', 'T', M, MB, MZ, WORK, 1, BETA,
$ Y, INCY, IAROW, IACOL, IYROW, IYCOL,
$ WORK(IPX) )
END IF
END IF
*
ELSE
IF( XCOL ) THEN
IF( YCOL ) THEN
*
* Form Y := alpha*(A')*X + beta*Y.
* where X and Y are distributed columnwise.
* __________
* | | ||
* || | | || ||
* || | | || ||
* (y) = alpha * | (A') | * (x) + beta *(y)
* || | | || ||
* || | | || ||
* |__________| ||
*
*
IF( IXROW.NE.IAROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
XDATA = .FALSE.
IF( IXCOL.EQ.-1 ) XDATA = .TRUE.
IPX = NQ + 1
*
* Broadcast X to X or WORK(IPX) if necessary ( IXCOL <> -1 )
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXCOL ) THEN
CALL DGEBS2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ X, INCX )
ELSE
CALL DGEBR2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ X, INCX, MYROW, IXCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXCOL ) THEN
CALL PBDVECADD( ICONTXT, 'V', MP, ONE, X, INCX, ZERO,
$ WORK(IPX), 1 )
CALL DGEBS2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ WORK(IPX), 1 )
ELSE
CALL DGEBR2D( ICONTXT, 'Row', '1-tree', 1, MP,
$ WORK(IPX), 1, MYROW, IXCOL )
END IF
END IF
END IF
*
* Compute Y' (<= X' * A )
*
IF( MP.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, X, INCX, ZERO,
$ WORK, 1 )
ELSE
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK(IPX), 1,
$ ZERO, WORK, 1 )
END IF
ELSE
CALL PBDVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK, 1 )
END IF
*
* Transpose Y (= WORK) and transpose it.
*
IF( M+MZ.GT.MB )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, WORK, 1,
$ IAROW, MYCOL )
CALL PBDTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, WORK, 1, BETA,
$ Y, INCY, IAROW, IACOL, IYROW, IYCOL,
$ WORK(IPX) )
*
ELSE
*
* Form y := alpha*(A')*x + beta*y.
* where x is distributed columnwise & y is distributed rowwise
* __________
* | | ||
* | | ||
* | | ||
* ====(y)==== = alpha * | (A') | * (x) + beta * ====(y)====
* | | ||
* | | ||
* |__________| ||
*
*
IF( IXROW.LT.IAROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.-1 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.NE.IACOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
XDATA = .FALSE.
IF( IXCOL.EQ.-1 ) XDATA = .TRUE.
IPY = 1
*
* Broadcast X to X or WORK(IPX) if necessary ( IXCOL <> -1 )
*
IF( .NOT.XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXCOL ) THEN
CALL DGEBS2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX )
ELSE
CALL DGEBR2D( ICONTXT, 'Row', COMMX, 1, MP, X, INCX,
$ MYROW, IXCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXCOL ) THEN
CALL PBDVECADD( ICONTXT, 'V', MP, ONE, X, INCX, ZERO,
$ WORK, 1 )
CALL DGEBS2D( ICONTXT, 'Row', COMMX, 1, MP, WORK, 1 )
ELSE
CALL DGEBR2D( ICONTXT, 'Row', COMMX, 1, MP, WORK, 1,
$ MYROW, IXCOL )
END IF
IPY = MP + 1
END IF
END IF
*
* Compute Y' (<= X' * A )
*
IF( LSAME( YWORK, 'Y' ) ) THEN
TBETA = ZERO
IF( MYROW.EQ.IYROW ) TBETA = BETA
*
IF( MP.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, X, INCX,
$ TBETA, Y, INCY )
ELSE
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK, 1,
$ TBETA, Y, INCY )
END IF
ELSE IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW .OR.
$ MYROW.EQ.IYROW ) THEN
CALL PBDVECADD( ICONTXT, 'V', NQ, ZERO, DUMMY, 1, TBETA,
$ Y, INCY )
END IF
*
* Add Y columnwise
*
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, Y, INCY,
$ IYROW, MYCOL )
*
ELSE
IF( MP.GT.0 ) THEN
IF( XDATA ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, X, INCX,
$ ZERO, WORK(IPY), 1 )
ELSE
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK, 1,
$ ZERO, WORK(IPY), 1 )
END IF
ELSE
CALL PBDVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK(IPY), 1 )
END IF
*
* Add Y (= WORK(IPY)) columnwise
*
IF( MYROW.EQ.IYROW ) THEN
CALL PBDVECADD( ICONTXT, 'G', NQ, ONE, WORK(IPY), 1,
$ BETA, Y, INCY )
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ Y, INCY, IYROW, MYCOL )
ELSE
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPY), 1, IYROW, MYCOL )
END IF
END IF
END IF
*
ELSE
IF( YCOL ) THEN
*
* Form y := alpha*A*x + beta*y,
* where x is distributed rowwise & y is distributed columnwise
* __________
* | |
* || | | ||
* || | | ||
* (y) = alpha*| (A') |* =====(x)===== + beta*(y)
* || | | ||
* || | | ||
* |__________|
*
IF( IXROW.LT.-1 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.0 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.LT.0 .OR. IYCOL.GE.NPCOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Transpose X to WORK
*
IPX = NQ + 1
CALL PBDTRNV( ICONTXT, 'Row', 'T', M, MB, MZ, X, INCX, ZERO,
$ WORK(IPX), 1, IXROW, IXCOL, IAROW, -1,
$ WORK(MP+IPX) )
*
* Compute Y
*
IF( MP.GT.0 ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK(IPX), 1,
$ ZERO, WORK, 1 )
ELSE
CALL PBDVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK, 1 )
END IF
*
* Add Y columnwise and transpose it.
*
IF( M+MZ.GT.MB )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, WORK, 1,
$ IAROW, MYCOL )
CALL PBDTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, WORK, 1, BETA,
$ Y, INCY, IAROW, IACOL, IYROW, IYCOL,
$ WORK(IPX) )
*
ELSE
*
* Form y := alpha*(A')*x + beta*y.
* where x and y are distributed rowwise.
* __________
* | |
* | |
* | |
* =====(y)==== = a*| (A') |* ======(x)===== + b* =====(y)====
* | |
* | |
* |__________|
*
IF( IXROW.LT.-1 .OR. IXROW.GE.NPROW ) THEN
INFO = 21
ELSE IF( IXCOL.LT.0 .OR. IXCOL.GE.NPCOL ) THEN
INFO = 22
ELSE IF( IYROW.LT.0 .OR. IYROW.GE.NPROW ) THEN
INFO = 23
ELSE IF( IYCOL.NE.IACOL ) THEN
INFO = 24
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Transpose X to WORK
*
IPY = MP + 1
CALL PBDTRNV( ICONTXT, 'Row', 'T', M, MB, MZ, X, INCX, ZERO,
$ WORK, 1, IXROW, IXCOL, IAROW, -1, WORK(IPY) )
*
* Compute Y
*
IF( LSAME( YWORK, 'Y' ) ) THEN
TBETA = ZERO
IF( MYROW.EQ.IYROW ) TBETA = BETA
*
IF( MP.GT.0 ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK, 1,
$ TBETA, Y, INCY )
ELSE IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW
$ .OR. MYROW.EQ.IYROW ) THEN
CALL PBDVECADD( ICONTXT, 'V', NQ, ZERO, DUMMY, 1, TBETA,
$ Y, INCY )
END IF
*
* Add Y columnwise if necessary
*
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ, Y, INCY,
$ IYROW, MYCOL )
*
ELSE
IF( MP.GT.0 ) THEN
CALL DGEMV( TRANS, MP, NQ, ALPHA, A, LDA, WORK, 1, ZERO,
$ WORK(IPY), 1 )
ELSE
CALL PBDVECADD( ICONTXT, 'G', NQ, ZERO, DUMMY, 1, ZERO,
$ WORK(IPY), 1 )
END IF
*
* Add Y columnwise if necessary
*
IF( MYROW.EQ.IYROW ) THEN
CALL PBDVECADD( ICONTXT, 'G', NQ, ONE, WORK(IPY), 1,
$ BETA, Y, INCY )
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ Y, INCY, IYROW, MYCOL )
ELSE
IF( M+MZ.GT.MB .OR. IAROW.NE.IYROW )
$ CALL DGSUM2D( ICONTXT, 'Col', '1-tree', 1, NQ,
$ WORK(IPY), 1, IYROW, MYCOL )
END IF
END IF
END IF
END IF
END IF
*
RETURN
*
* End of PBDGEMV
*
END
|
