1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
|
SUBROUTINE PBZHER( ICONTXT, UPLO, XDIST, N, NB, NZ, ALPHA, X,
$ INCX, A, LDA, IXPOS, IAROW, IACOL, XCOMM,
$ XWORK, AWORK, MULLEN, WORK )
*
* -- PB-BLAS routine (version 2.1) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory.
* April 28, 1996
*
* Jaeyoung Choi, Oak Ridge National Laboratory
* Jack Dongarra, University of Tennessee and Oak Ridge National Lab.
* David Walker, Oak Ridge National Laboratory
*
* .. Scalar Arguments ..
CHARACTER*1 AWORK, UPLO, XCOMM, XDIST, XWORK
INTEGER IACOL, IAROW, ICONTXT, INCX, IXPOS, LDA,
$ MULLEN, N, NB, NZ
DOUBLE PRECISION ALPHA
* ..
* .. Array Arguments ..
COMPLEX*16 A( LDA, * ), X( * ), WORK( * )
* ..
*
* Purpose
* =======
*
* PBZHER is a parallel blocked version of ZHER.
* PBZHER performs the Hermitian rank 1 operation
*
* A := alpha*x*x' + A,
*
* where alpha is a scalar, x is an N-element vector distributed on a
* column or a row of the process template, and A is an N-by-N
* Hermitian matrix.
*
* The first elements of the vector X and the matrix A can be located in
* the middle of the first blocks.
* X can be broadcast if necessary and then transposed. The communica-
* tion scheme can be selected.
*
* Parameters
* ==========
*
* ICONTXT (input) INTEGER
* ICONTXT is the BLACS mechanism for partitioning communication
* space. A defining property of a context is that a message in
* a context cannot be sent or received in another context. The
* BLACS context includes the definition of a grid, and each
* process' coordinates in it.
*
* UPLO (input) CHARACTER*1
* UPLO specifies whether the upper or lower triangular part of
* the array A is to be referenced as follows:
*
* UPLO = 'U', Only the upper triangular part of A
* is to be referenced.
* UPLO = 'L', Only the lower triangular part of A
* is to be referenced.
*
* XDIST (input) CHARACTER*1
* XDIST specifies the distribution of the vector x as follows:
*
* XDIST = 'C', x is distributed columnwise
* or in a column of processes
* XDIST = 'R', x is distributed rowwise
* or in a row of processes
*
* N (input) INTEGER
* N specifies the (global) size of the matrix A. N >= 0.
*
* NB (input) INTEGER
* NB specifies the row and column block size of the matrix A
* It also specifies block size of the vector X. NB >= 1.
*
* NZ (input) INTEGER
* NZ is the row and column offset to specify the row and column
* distance from the beginning of the block to the first element
* of A. And it also specifies the offset to the first element
* of the vector X. 0 <= NZ < NB.
*
* ALPHA (input) DOUBLE PRECISION
* ALPHA specifies the scalar alpha.
*
* X (input) COMPLEX*16 array of DIMENSION at least
* ( 1 + ( Np - 1 ) * abs( INCX ) ) if XDIST = 'C', or
* ( 1 + ( Nq - 1 ) * abs( INCX ) ) if XDIST = 'R'.
* The incremented array X must contain the vector X.
*
* INCX (input) INTEGER
* INCX specifies the increment for the elements of X.
* INCX <> 0.
*
* A (input/output) COMPLEX*16 array of local DIMENSION (LDA,Nq).
* On entry with UPLO = 'U', the leading N-by-N upper triangular
* part of the (global) array A must contain the upper triangu-
* lar part of the Hermitian matrix and the strictly lower
* triangular part of A is not referenced. On exit, the upper
* triangular part of the array A is overwritten by the upper
* triangular part of the updated matrix.
* On entry with UPLO= 'L', the leading N-by-N lower triangular
* part of the (global) array A must contain the lower
* triangular part of the Hermitian matrix and the strictly
* upper triangular part of A is not referenced. On exit,
* the lower triangular part of the array A is overwritten by
* the lower triangular part of the updated matrix.
*
* LDA (input) INTEGER
* LDA specifies the leading dimension of the (local) array A.
* LDA >= MAX(1,Np).
*
* IXPOS (input) INTEGER
* If XDIST = 'C', IXPOS specifies a column of process template,
* which holds the vector X. And if XDIST = 'R', IXPOS speci-
* fies a row of the template, which holds the vector X.
* If all columns or rows of processes have their own copies of
* X, then set IXPOS = -1.
*
* IAROW (input) INTEGER
* It specifies a row of process template which has the
* first block of A. It also represents a row of the template
* which holds the first blcok of the vector X if XDIST = 'C'.
*
* IACOL (input) INTEGER
* It specifies a column of process template which has the
* first block of A. It also represents the column of the
* template which holds the first blcok of the vector X if
* XDIST = 'R'.
*
* XCOMM (input) CHARACTER*1
* XCOMM specifies the communication scheme of the vector X if
* communication is necessary. It follows topology definition
* of BLACS.
*
* XWORK (input) CHARACTER*1
* XWORK determines whether X is a workspace or not.
*
* XWORK = 'Y': X is workspace in other processes.
* X is sent to X position in other processes.
* It is assumed that processes have
* sufficient space to store (local) X.
* XWORK = 'N': Data in X will be untouched (unchanged).
*
* AWORK (input) CHARACTER*1
* AWORK determines whether the other triangular part of A is
* accessed and modified or not.
*
* AWORK = 'N': if UPLO = 'U', only upper triangular portion
* portion of the matrix A is accessed and the
* lower triangular portion is untouched.
* Likewise if UPLO = 'L', only lower triangular
* portion of the matrix A is accessed and the
* upper triangular portion is untouched.
* AWORK = 'Y': if UPLO = 'U', only lower triangular portion
* of the matrix A may be accessed and modified
* for fast computation. And if UPLO = 'L', the
* upper triangular portion of the matrix A may
* be accessed and modified for fast computation.
*
* MULLEN (input) INTEGER
* MULLEN specifies multiplication length of the optimum column
* number of the matrix A for multiplying X with X'. The value
* depends on machine characteristics.
*
* WORK (workspace) COMPLEX*16 array of DIMENSION SIZE(WORK).
* It will store copy of X and/or X'.
*
* Parameters Details
* ==================
*
* Lx It is a local portion of L owned by a process, (L is
* replaced by M, or N, and x is replaced by either p
* (=NPROW) or q (=NPCOL)). The value is determined by L, LB,
* x, and MI, where LB is a block size and MI is a row or
* column position in a process template. Lx is equal to or
* less than Lx0 = CEIL( L, LB*x ) * LB.
*
* Memory Requirement of WORK
* ==========================
*
* NN = N + NZ
* Npb = CEIL( NN, NB*NPROW )
* Nqb = CEIL( NN, NB*NPCOL )
* Np0 = NUMROC( NN, NB, 0, 0, NPROW ) ~= Npb * NB
* Nq0 = NUMROC( NN, NB, 0, 0, NPCOL ) ~= Nqb * NB
* LCMQ = LCM / NPCOL
* LCMP = LCM / NPROW
* ISZCMP = CEIL(MULLEN, LCMQ*NB)
* SZCMP = ISZCMP * ISZCMP * LCMQ*NB * LCMP*NB
*
* (1) XDIST = 'Col'
* Size(WORK) = Nq0
* + Np0 ( if IXPOS <> -1 and XWORK <> 'Y' )
* + MAX[ SZCMP ( if AWORK <> 'Y' ),
* CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(NN,NB) ]
* (b) XDIST = 'Row'
* Size(WORK) = Np0
* + Nq0 ( if IXPOS <> -1 and XWORK <> 'Y' )
* + MAX[ SZCMP ( if AWORK <> 'Y' ),
* CEIL(Npb,LCMP)*NB*MIN(LCMP,CEIL(NN,NB) ]
*
* Notes
* -----
* More precise space can be computed as
*
* CEIL(Nqb,LCMQ)*NB => NUMROC( NUMROC(NN,NB,0,0,NPCOL), NB, 0, 0, LCMQ)
* = NUMROC( Nq0, NB, 0, 0, LCMQ )
* CEIL(Npb,LCMP)*NB => NUMROC( NUMROC(NN,NB,0,0,NPROW), NB, 0, 0, LCMP)
* = NUMROC( Np0, NB, 0, 0, LCMP )
*
* =====================================================================
*
* ..
* .. Parameters ..
DOUBLE PRECISION RZERO
PARAMETER ( RZERO = 0.0D+0 )
COMPLEX*16 ONE, ZERO
PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ),
$ ZERO = ( 0.0D+0, 0.0D+0 ) )
* ..
* .. Local Scalars ..
CHARACTER*1 COMMX, FORM
LOGICAL ASPACE, COLUMN, UPPER, XDATA
INTEGER INFO, IPBZ, IPT, IPW, IQBZ, ISZCMP, IZ, JJ,
$ JNPBZ, JPBZ, JQBZ, JZ, KI, KIZ, KJ, KJZ, KZ,
$ LCM, LCMP, LCMQ, LMW, LNW, LPBZ, LQBZ, MRCOL,
$ MRROW, MYCOL, MYROW, MZCOL, MZROW, NN, NP,
$ NPCOL, NPROW, NQ
COMPLEX*16 DUMMY, TALPHA
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER ICEIL, ILCM, NUMROC
EXTERNAL ICEIL, ILCM, LSAME, NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, PBZTRAD1, PBZTRNV, PBZVECADD,
$ PXERBLA, ZGEBR2D, ZGEBS2D, ZGERC
* ..
* .. Intrinsic Functions ..
INTRINSIC DCMPLX, MAX, MIN
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
IF( N.EQ.0 .OR. ALPHA.EQ.RZERO ) RETURN
*
CALL BLACS_GRIDINFO( ICONTXT, NPROW, NPCOL, MYROW, MYCOL )
*
UPPER = LSAME( UPLO, 'U' )
COLUMN = LSAME( XDIST, 'C' )
*
* Test the input parameters.
*
INFO = 0
IF( ( .NOT.UPPER ).AND.
$ ( .NOT.LSAME( UPLO, 'L' ) ) ) THEN
INFO = 2
ELSE IF( ( .NOT.COLUMN ).AND.
$ ( .NOT.LSAME( XDIST, 'R' ) ) ) THEN
INFO = 3
ELSE IF( N .LT.0 ) THEN
INFO = 4
ELSE IF( NB .LT.1 ) THEN
INFO = 5
ELSE IF( NZ .LT.0 .OR. NZ.GE.NB ) THEN
INFO = 6
ELSE IF( INCX.EQ.0 ) THEN
INFO = 9
ELSE IF( IAROW.LT.0 .OR. IAROW.GE.NPROW ) THEN
INFO = 13
ELSE IF( IACOL.LT.0 .OR. IACOL.GE.NPCOL ) THEN
INFO = 14
END IF
*
10 CONTINUE
IF( INFO.NE.0 ) THEN
CALL PXERBLA( ICONTXT, 'PBZHER ', INFO )
RETURN
END IF
*
* Start the operations.
*
IZ = 0
JZ = 0
NN = N + NZ
NP = NUMROC( NN, NB, MYROW, IAROW, NPROW )
IF( MYROW.EQ.IAROW ) THEN
NP = NP - NZ
IZ = NZ
END IF
*
NQ = NUMROC( NN, NB, MYCOL, IACOL, NPCOL )
IF( MYCOL.EQ.IACOL ) THEN
NQ = NQ - NZ
JZ = NZ
END IF
KZ = 0
*
ASPACE = LSAME( AWORK, 'Y' )
XDATA = .FALSE.
IF( IXPOS.EQ.-1 ) XDATA = .TRUE.
COMMX = XCOMM
IF( LSAME( COMMX, ' ' ) ) COMMX = '1'
*
* LCM : the least common multiple of NPROW and NPCOL
*
LCM = ILCM( NPROW, NPCOL )
LCMP = LCM / NPROW
LCMQ = LCM / NPCOL
LPBZ = LCMP * NB
LQBZ = LCMQ * NB
*
MRROW = MOD( NPROW+MYROW-IAROW, NPROW )
MRCOL = MOD( NPCOL+MYCOL-IACOL, NPCOL )
TALPHA = DCMPLX( ALPHA )
*
IF( LDA .LT. MAX(1,NP) ) INFO = 11
*
* PART 1: Distribute a column (or row) vector X and its transpose
* ===============================================================
*
IF( COLUMN ) THEN
*
* Form A := alpha*X*X' + A.
* _____________ _____________
* |\_ | || |\_ |
* | \_ | || | \_ |
* | \_ | || _____________ | \_ |
* | A_ | = a * |X * ------X'----- + | A_ |
* | \_ | || | \_ |
* | \_ | || | \_ |
* |____________\| || |____________\|
*
IF( IXPOS.LT.-1 .OR. IXPOS.GE.NPCOL ) INFO = 12
IF( INFO.NE.0 ) GO TO 10
*
* Broadcast X if necessary
*
IPT = 1
IF( .NOT. XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYCOL.EQ.IXPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Row', COMMX, 1, NP, X, INCX )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMX, 1, NP, X, INCX,
$ MYROW, IXPOS )
END IF
XDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IXPOS ) THEN
CALL PBZVECADD( ICONTXT, 'V', NP, ONE, X, INCX, ZERO,
$ WORK, 1 )
CALL ZGEBS2D( ICONTXT, 'Row', COMMX, 1, NP, WORK, 1 )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMX, 1, NP, WORK, 1,
$ MYROW, IXPOS )
END IF
IPT = NP + 1
END IF
END IF
*
* Transpose the vector X to WORK(IPT), where X is distributed
*
IPW = NQ + IPT
IF( XDATA ) THEN
CALL PBZTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK(IPT), 1, IAROW, -1, -1, IACOL, WORK(IPW) )
ELSE
CALL PBZTRNV( ICONTXT, 'Col', 'T', N, NB, NZ, WORK, 1, ZERO,
$ WORK(IPT), 1, IAROW, -1, -1, IACOL, WORK(IPW) )
END IF
*
ELSE
*
* Form A := alpha*x'*x + A.
* _____________ _____________
* |\_ | || |\_ |
* | \_ | || | \_ |
* | \_ | || _____________ | \_ |
* | A_ | = a * X' * ------X------ + | A_ |
* | \_ | || | \_ |
* | \_ | || | \_ |
* |____________\| || |____________\|
*
IF( IXPOS.LT.-1 .OR. IXPOS.GE.NPROW ) INFO = 12
IF( INFO.NE.0 ) GO TO 10
*
* Broadcast X if necessary
*
IPT= 1
IF( .NOT. XDATA ) THEN
IF( LSAME( XWORK, 'Y' ) ) THEN
IF( MYROW.EQ.IXPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Col', COMMX, 1, NQ, X, INCX )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMX, 1, NQ, X, INCX,
$ IXPOS, MYCOL )
END IF
XDATA = .TRUE.
ELSE
IF( MYROW.EQ.IXPOS ) THEN
CALL PBZVECADD( ICONTXT, 'G', NQ, ONE, X, INCX, ZERO,
$ WORK, 1 )
CALL ZGEBS2D( ICONTXT, 'Col', COMMX, 1, NQ, WORK, 1 )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMX, 1, NQ, WORK, 1,
$ IXPOS, MYCOL )
END IF
IPT = NQ + 1
END IF
END IF
*
* Transpose the vector X to WORK(IPT), where X is distributed
*
IPW = NP + IPT
IF( XDATA ) THEN
CALL PBZTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, X, INCX, ZERO,
$ WORK(IPT), 1, -1, IACOL, IAROW, -1, WORK(IPW) )
ELSE
CALL PBZTRNV( ICONTXT, 'Row', 'T', N, NB, NZ, WORK, 1, ZERO,
$ WORK(IPT), 1, -1, IACOL, IAROW, -1, WORK(IPW) )
END IF
END IF
*
* PART 2: Update A with X and X'
* ==============================
*
IF( NP.EQ.0 .OR. NQ.EQ.0 ) RETURN
*
* If A is a Hermitian upper triangular matrix,
*
IF( UPPER ) THEN
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 40 JJ = 1, ICEIL(NQ+JZ, IQBZ)
LMW = MIN( IPBZ-IZ, NP-JPBZ )
LNW = MIN( IQBZ-JZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the lower triangular part
*
IF( ASPACE ) THEN
*
* if XDIST = 'Column'
*
IF( COLUMN ) THEN
IF( XDATA ) THEN
CALL ZGERC( JNPBZ, LNW, TALPHA, X, INCX, WORK(JQBZ+IPT),
$ 1, A(1,JQBZ+1), LDA )
ELSE
CALL ZGERC( JNPBZ, LNW, TALPHA, WORK, 1, WORK(JQBZ+IPT),
$ 1, A(1,JQBZ+1), LDA )
END IF
*
* if XDIST = 'Row'
*
ELSE
IF( XDATA ) THEN
CALL ZGERC( JNPBZ, LNW, TALPHA, WORK(IPT), 1,
$ X(JQBZ*INCX+1), INCX, A(1,JQBZ+1), LDA )
ELSE
CALL ZGERC( JNPBZ, LNW, TALPHA, WORK(IPT), 1,
$ WORK(JQBZ+1), 1, A(1,JQBZ+1), LDA )
END IF
END IF
*
* Update data in the upper triangular matrix
* and save data in the lower triangular matrix
*
ELSE
*
* if XDIST = 'Column'
*
IF( COLUMN ) THEN
IF( XDATA ) THEN
CALL ZGERC( JPBZ, LNW, TALPHA, X, INCX,
$ WORK(JQBZ+IPT), 1, A(1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, X(JPBZ*INCX+1), INCX,
$ WORK(JQBZ+IPT), 1, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGERC( JPBZ, LNW, TALPHA, WORK, 1, WORK(JQBZ+IPT),
$ 1, A(1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+1), 1,
$ WORK(JQBZ+IPT), 1, WORK(IPW), MAX(1,LMW) )
END IF
*
* if XDIST = 'Row'
*
ELSE
IF( XDATA ) THEN
CALL ZGERC( JPBZ, LNW, TALPHA, WORK(IPT), 1,
$ X(JQBZ*INCX+1), INCX, A(1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ X(JQBZ*INCX+1), INCX, WORK(IPW), MAX(1,LMW))
ELSE
CALL ZGERC( JPBZ, LNW, TALPHA, WORK(IPT), 1,
$ WORK(JQBZ+1), 1, A(1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ WORK(JQBZ+1), 1, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
IF( MYCOL.EQ.IACOL ) KZ = JZ
*
DO 30 KJ = 0, LCMQ-1
20 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 20
END IF
KIZ = MAX( 0, KI*NB-IZ )
KJZ = MAX( 0, KJ*NB-JZ )
IF( KJZ.GE.LNW )
$ GO TO 40
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
CALL PBZTRAD1( ICONTXT, 'Upper', FORM, KIZ, NB, KZ, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, ONE,
$ A( JPBZ+1, JQBZ+KJZ+1 ), LDA,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
KZ = 0
30 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
IZ = 0
JZ = 0
40 CONTINUE
*
* If A is a Hermitian lower triangular matrix,
*
ELSE
*
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 70 JJ = 1, ICEIL(NQ+JZ, IQBZ)
LMW = MIN( IPBZ-IZ, NP-JPBZ )
LNW = MIN( IQBZ-JZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the upper triangular part
*
IF( ASPACE ) THEN
*
* if XDIST = 'Column'
*
IF( COLUMN ) THEN
IF( XDATA ) THEN
CALL ZGERC( NP-JPBZ, LNW, TALPHA, X(JPBZ*INCX+1), INCX,
$ WORK(JQBZ+IPT), 1, A(JPBZ+1,JQBZ+1), LDA )
ELSE
CALL ZGERC( NP-JPBZ, LNW, TALPHA, WORK(JPBZ+1), 1,
$ WORK(JQBZ+IPT), 1, A(JPBZ+1,JQBZ+1), LDA )
END IF
*
* if XDIST = 'Row'
*
ELSE
IF( XDATA ) THEN
CALL ZGERC( NP-JPBZ, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ X(JQBZ*INCX+1), INCX, A(JPBZ+1,JQBZ+1), LDA)
ELSE
CALL ZGERC( NP-JPBZ, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ WORK(JQBZ+1), 1, A(JPBZ+1,JQBZ+1), LDA )
END IF
END IF
*
* Update data in the lower triangular matrix
* and save data in the upper triangular matrix
*
ELSE
*
* if XDIST = 'Column'
*
IF( COLUMN ) THEN
IF( XDATA ) THEN
CALL ZGERC( NP-JNPBZ, LNW, TALPHA, X(JNPBZ*INCX+1),
$ INCX, WORK(JQBZ+IPT), 1, A(JNPBZ+1,JQBZ+1),
$ LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, X(JPBZ*INCX+1), INCX,
$ WORK(JQBZ+IPT), 1, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGERC( NP-JNPBZ, LNW, TALPHA, WORK(JNPBZ+1), 1,
$ WORK(JQBZ+IPT), 1, A(JNPBZ+1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+1), 1,
$ WORK(JQBZ+IPT), 1, WORK(IPW), MAX(1,LMW) )
END IF
*
* if XDIST = 'Row'
*
ELSE
IF( XDATA ) THEN
CALL ZGERC( NP-JNPBZ, LNW, TALPHA, WORK(JNPBZ+IPT), 1,
$ X(JQBZ*INCX+1), INCX, A(JNPBZ+1,JQBZ+1),LDA)
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ X(JQBZ*INCX+1), INCX, WORK(IPW), MAX(1,LMW))
ELSE
CALL ZGERC( NP-JNPBZ, LNW, TALPHA, WORK(JNPBZ+IPT), 1,
$ WORK(JQBZ+1), 1, A(JNPBZ+1,JQBZ+1), LDA )
CALL PBZVECADD( ICONTXT, 'G', LMW*LNW, ZERO, DUMMY, 1,
$ ZERO, WORK(IPW), 1 )
CALL ZGERC( LMW, LNW, TALPHA, WORK(JPBZ+IPT), 1,
$ WORK(JQBZ+1), 1, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
IF( MYCOL.EQ.IACOL ) KZ = JZ
*
DO 60 KJ = 0, LCMQ-1
50 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 50
END IF
KIZ = MAX( 0, KI*NB-IZ )
KJZ = MAX( 0, KJ*NB-JZ )
IF( KJZ.GE.LNW )
$ GO TO 70
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
*
CALL PBZTRAD1( ICONTXT, 'Lower', FORM, KIZ, NB, KZ, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, ONE,
$ A( JPBZ+1, JQBZ+KJZ+1 ), LDA,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
KZ = 0
60 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
IZ = 0
JZ = 0
70 CONTINUE
END IF
*
RETURN
*
* End of PBZHER
*
END
|
