1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
|
SUBROUTINE PBZHER2K( ICONTXT, MATBLK, UPLO, TRANS, N, K, NB,
$ ALPHA, A, LDA, B, LDB, BETA, C, LDC, IAPOS,
$ IBPOS, ICROW, ICCOL, ABCOMM, AWORK, BWORK,
$ CWORK, MULLEN, WORK )
*
* -- PB-BLAS routine (version 2.1) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory.
* April 28, 1996
*
* Jaeyoung Choi, Oak Ridge National Laboratory
* Jack Dongarra, University of Tennessee and Oak Ridge National Lab.
* David Walker, Oak Ridge National Laboratory
*
* .. Scalar Arguments ..
CHARACTER*1 ABCOMM, AWORK, BWORK, CWORK, MATBLK, TRANS,
$ UPLO
INTEGER IAPOS, IBPOS, ICCOL, ICONTXT, ICROW, K, LDA,
$ LDB, LDC, MULLEN, N, NB
COMPLEX*16 ALPHA
DOUBLE PRECISION BETA
* ..
* .. Array Arguments ..
COMPLEX*16 A( LDA, * ), B( LDB, * ), C( LDC, * ),
$ WORK( * )
* ..
*
* Purpose
* =======
*
* PBZHER2K is a parallel blocked version of ZHER2K.
* PBZHER2K performs one of the Hermitian rank k operations
*
* C := alpha*A*B' + alpha'*B*A' + beta*C,
*
* or
*
* C := alpha*A'*B + alpha'*B'*A + beta*C,
*
* where alpha and beta are scalars, C is an n by n Hermitian matrix
* and A and B are an n by k matrix in the first case and a k by n
* matrix in the second case. k is limited to the block size NB, so that
* A and B are block columns (if TRANS = 'No') or block rows (if TRANS =
* 'Conju').
*
* The first elements of the matrices A, B, and C should be located at
* the beginnings of their first blocks. (not the middle of the blocks.)
* A and B can be broadcast if necessary and then transposed. The
* communication scheme can be selected.
*
* Parameters
* ==========
*
* ICONTXT (input) INTEGER
* ICONTXT is the BLACS mechanism for partitioning communication
* space. A defining property of a context is that a message in
* a context cannot be sent or received in another context. The
* BLACS context includes the definition of a grid, and each
* process' coordinates in it.
*
* MATBLK (input) CHARACTER*1
* MATBLK specifies whether C is a (full) block matrix or
* a single block as follows:
*
* MATBLK = 'M', C is a (full) block matrix,
* MATBLK = 'B', C is a single block.
*
* UPLO (input) CHARACTER*1
* UPLO specifies whether the upper or lower triangular part
* of the array C is to be referenced as follows:
*
* UPLO = 'U', Only the upper triangular part of C
* is to be referenced.
* UPLO = 'L', Only the lower triangular part of C
* is to be referenced.
*
* TRANS (input) CHARACTER*1
* TRANS specifies the operation to be performed as follows:
*
* TRANS = 'N', C := alpha*A*B' + alpha'*B*A' + beta*C.
* TRANS = 'C', C := alpha*A'*B + alpha'*B'*A + beta*C.
*
* N (input) INTEGER
* N specifies the order of the matrix C. N >= 0.
*
* K (input) INTEGER
* If TRANS = 'N', K specifies the number of columns of the
* matrix A, and if TRANS = 'C', K specifies the number of rows
* of the matrix A. K >= 0.
*
* NB (input) INTEGER
* NB specifies the row and column block size of the matrix C.
* It also specifies the row block size of the matrices A and B
* if MATBLK = 'M' and TRANS = 'N', or MATBLK = 'B' and TRANS =
* 'C'; and the column block size of the matrices A and B
* if MATBLK = 'M' and TRANS = 'C', or MATBLK = 'B' and
* TRANS = 'N'. NB >= 1.
*
* ALPHA (input) COMPLEX*16
* ALPHA specifies the scalar alpha.
*
* A (input) COMPLEX*16 array of local DIMENSION ( LDA, ka ),
* where ka is Kq when TRANS = 'N', or Nq otherwise.
* If TRANS = 'N', the leading Np-by-Kq part of the array A
* must contain the (local) matrix A, otherwise the leading Kp-
* by-Nq part of the array A must contain the (local) matrix A.
*
* LDA (input) INTEGER
* LDA specifies the first dimension of (local) A as declared
* in the calling (sub) program.
* LDA >= MAX(1,Np) if MATBLK = 'M' & TRANS = 'N',
* or MATBLK = 'B' & TRANS = 'C',
* LDA >= MAX(1,Kp) if MATBLK = 'M' & TRANS = 'C',
* or MATBLK = 'B' & TRANS = 'N'.
*
* B (input) COMPLEX*16 array of local DIMENSION ( LDB, ka ),
* where ka is Kq when TRANS = 'N', or Nq otherwise.
* If TRANS = 'N', the leading Np-by-Kq part of the array B
* must contain the (local) matrix B, otherwise the leading Kp-
* by-Nq part of the array B must contain the (local) matrix B.
*
* LDB (input) INTEGER
* LDB specifies the leading dimension of (local) B as declared
* in the calling (sub) program.
* LDB >= MAX(1,Np) if MATBLK = 'M' & TRANS = 'N',
* or MATBLK = 'B' & TRANS = 'C',
* LDB >= MAX(1,Kp) if MATBLK = 'M' & TRANS = 'C',
* or MATBLK = 'B' & TRANS = 'N'.
*
* BETA (input) DOUBLE PRECISION
* BETA specifies the scalar beta.
*
* C (input/output) COMPLEX*16 array of local DIMENSION (LDC,Nq).
* On entry with UPLO = 'U', the leading N-by-N upper triangular
* part of the (global) array C must contain the upper triangu-
* lar part of the Hermitian matrix and the strictly lower
* triangular part of C is not referenced. On exit, the upper
* triangular part of the array C is overwritten by the upper
* triangular part of the updated matrix. Before entry with
* UPLO='L', the leading N-by-N lower triangular part of the
* (global) array C must contain the lower triangular part of
* the Hermitian matrix and the strictly upper triangular part
* of C is not referenced. On exit the lower triangular part
* of the array C is overwritten by the lower triangular part
* of the updated matrix.
*
* LDC (input) INTEGER
* LDC specifies the leading dimension of (local) C as declared
* in the calling (sub) program. LDC >= MAX(1,Np).
*
* IAPOS (input) INTEGER
* If TRANS = 'N', IAPOS specifies a column of process
* template, which holds the first block of A. And if TRANS =
* 'C', IAPOS specifies a row of the template, which holds the
* first block of A.
* If MATBLK = 'M' and all columns or rows of processes have
* a copy of A, then set IAPOS = -1.
* And if MATBLK = 'B', IAPOS should be the same as IBPOS.
*
* IBPOS (input) INTEGER
* If TRANS = 'N', IAPOS specifies a column of process
* template, which holds the first block of B. And if TRANS =
* 'C', IBPOS specifies a row of the template, which holds the
* first block of A.
* If MATBLK = 'M' and all columns or rows of processes have
* a copy of B, then set IBPOS = -1.
* And if MATBLK = 'B', IBPOS should be the same as IAPOS.
*
* ICROW (input) INTEGER
* It specifies a row of process template which has the
* first block of C. It also represents the first (row)
* process of the column block C if TRANS = 'N'.
* When MATBLK = 'B', and all rows of processes have their
* own copies of C, set ICROW = -1.
*
* ICCOL (input) INTEGER
* It specifies a column of process template which has the
* first block of C. It also represents the first (column)
* process of the row block C if TRANS = 'C'.
* When MATBLK = 'B', and all columns of processes have
* their own copies of C, set ICCOL = -1.
*
* ABCOMM (input) CHARACTER*1
* When MATBLK = 'M', ABCOMM specifies the communication scheme
* of column or row block of A and B if communication is ne-
* cessary. It follows topology definition of BLACS.
* When MATBLK = 'B', the argument is ignored.
*
* AWORK (input) CHARACTER*1
* When MATBLK = 'M', AWORK determines whether A is a
* workspace or not.
*
* AWORK = 'Y': A is workspace in other processes.
* A is sent to A position in other processes.
* It is assumed that processes have
* sufficient space to store (local) A.
* AWORK = 'N': Data in A will be untouched (unchanged).
*
* When MATBLK = 'B', it is ignored.
*
* BWORK (input) CHARACTER*1
* When MATBLK = 'M', BWORK determines whether B is a
* workspace or not.
*
* BWORK = 'Y': B is workspace in other processes.
* B is sent to B position in other processes.
* It is assumed that processes have
* sufficient space to store (local) B.
* BWORK = 'N': Data in B will be untouched (unchanged).
*
* When MATBLK = 'B', it is ignored.
*
* CWORK (input) CHARACTER*1
* When MATBLK = 'M', CWORK determines whether the other
* triangular part of C is accessed and modified or not.
*
* CWORK = 'N': if UPLO = 'U', only upper triangular portion
* portion of the matrix C is accessed and the
* lower triangular portion is untouched.
* Likewise if UPLO = 'L', only lower triangular
* portion of the matrix C is accessed and the
* upper triangular portion is untouched.
* CWORK = 'Y': if UPLO = 'U', only lower triangular portion
* of the matrix C may be accessed and modified
* for fast computation. And if UPLO = 'L', the
* upper triangular portion of the matrix C may
* be accessed and modified for fast computation.
*
* And when MATBLK = 'B', CWORK determines whether C is a
* workspace or not.
*
* CWORK = 'Y': C is workspace in other processes.
* C is sent to C position in other processes.
* It is assumed that processes have
* sufficient space to store C.
* CWORK = 'N': Data in C will be untouched (unchanged)
* in other processes.
*
* MULLEN (input) INTEGER
* When MATBLK = 'M', MULLEN specifies multiplication length of
* the optimum column number of a row block A if TRANS = 'C',
* or A' if TRANS = 'N' for multiplying A with A'. The value
* depends on machine characteristics.
* When MATBLK = 'B', it is ignored.
*
* WORK (workspace) COMPLEX*16 array of dimension Size(WORK).
* It will store copy of A, A' B, and/or B'.
*
* Parameters Details
* ==================
*
* Lx It is a local portion of L owned by a process, (L is
* replaced by M, or N, and x is replaced by either p
* (=NPROW) or q (=NPCOL)). The value is determined by L, LB,
* x, and MI, where LB is a block size and MI is a row or
* column position in a process template. Lx is equal to or
* less than Lx0 = CEIL( L, LB*x ) * LB.
*
* Memory Requirement of WORK
* ==========================
*
* Npb = CEIL( N, NB*NPROW )
* Nqb = CEIL( N, NB*NPCOL )
* Np0 = NUMROC( N, NB, 0, 0, NPROW ) ~= Npb * NB
* Nq0 = NUMROC( N, NB, 0, 0, NPCOL ) ~= Nqb * NB
* LCMQ = LCM / NPCOL
* LCMP = LCM / NPROW
* ISZCMP = CEIL(MULLEN, LCMQ*NB)
* SZCMP = ISZCMP * ISZCMP * LCMQ*NB * LCMP*NB
*
* (1) MATBLK = 'M'
* (a) TRANS = 'N'
* Size(WORK) = K * Nq0
* + K * Np0 ( if IAPOS <> -1 and AWORK <> 'Y' )
* + K * Np0 ( if IBPOS <> -1 and BWORK <> 'Y' )
* + MAX[ SZCMP ( if CWORK <> 'Y' ),
* K*CEIL(Nqb,LCMQ)*NB*MIN(LCMQ,CEIL(N,NB) ]
* (b) TRANS = 'C'
* Size(WORK) = K * Np0
* + K * Nq0 ( if IAPOS <> -1 and AWORK <> 'Y' )
* + K * Nq0 ( if IBPOS <> -1 and BWORK <> 'Y' )
* + MAX[ SZCMP ( if CWORK <> 'Y' ),
* K*CEIL(Npb,LCMP)*NB*MIN(LCMP,CEIL(N,NB) ]
*
* (2) MATBLK = 'B'
* (a) TRANS = 'N' (on a row of processes ICROW only )
* Size(WORK) = N * (N+1) / 2 ( if CWORK = 'Y')
* Size(WORK) = N * N ( if CWORK <> 'Y')
* (b) TRANS = 'C' (on a column of processes ICCOL only )
* Size(WORK) = N * (N+1) / 2 ( if CWORK = 'Y')
* Size(WORK) = N * N ( if CWORK <> 'Y')
*
* Notes
* -----
* More precise space can be computed as
*
* CEIL(Nqb,LCMQ)*NB => NUMROC( NUMROC(N,NB,0,0,NPCOL), NB, 0, 0, LCMQ )
* = NUMROC( Nq0, NB, 0, 0, LCMQ )
* CEIL(Npb,LCMP)*NB => NUMROC( NUMROC(N,NB,0,0,NPROW), NB, 0, 0, LCMP )
* = NUMROC( Np0, NB, 0, 0, LCMP )
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION RONE, RZERO
PARAMETER ( RONE = 1.0D+0, RZERO = 0.0D+0 )
COMPLEX*16 ONE, ZERO
PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ),
$ ZERO = ( 0.0D+0, 0.0D+0 ) )
* ..
* .. Local Scalars ..
CHARACTER*1 COMMAB, FORM
LOGICAL ADATA, ASPACE, BDATA, BSPACE, CMAT, CSPACE,
$ NOTRAN, UPPER
INTEGER INFO, IPB, IPBZ, IPT, IPW, IQBZ, ISZCMP, JJ,
$ JNPBZ, JPBZ, JQBZ, KI, KIZ, KJ, KJZ, LCM, LCMP,
$ LCMQ, LKK, LMW, LNW, LPBZ, LQBZ, MRCOL, MRROW,
$ MYCOL, MYROW, MZCOL, MZROW, NP, NPCOL, NPROW,
$ NQ
COMPLEX*16 TALPHA, TBETA
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER ICEIL, ILCM, NUMROC
EXTERNAL ICEIL, ILCM, LSAME, NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, PBZMATADD, PBZT1CPY, PBZT2CPY,
$ PBZT3CPY, PBZTRADD, PBZTRAN, PXERBLA, ZGEBR2D,
$ ZGEBS2D, ZGEMM, ZHER2K
* ..
* .. Intrinsic Functions ..
INTRINSIC DCONJG, DCMPLX, MAX, MIN
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
IF( N.EQ.0 .OR.
$ ( ( ALPHA.EQ.ZERO .OR. K.EQ.0 ) .AND. BETA.EQ.RONE ) )
$ RETURN
*
CALL BLACS_GRIDINFO( ICONTXT, NPROW, NPCOL, MYROW, MYCOL )
*
CMAT = LSAME( MATBLK, 'M' )
UPPER = LSAME( UPLO, 'U' )
NOTRAN = LSAME( TRANS, 'N' )
*
* Test the input parameters.
*
INFO = 0
IF( ( .NOT.CMAT ).AND.
$ ( .NOT.LSAME( MATBLK, 'B' ) ) ) THEN
INFO = 2
ELSE IF( ( .NOT.UPPER ).AND.
$ ( .NOT.LSAME( UPLO, 'L' ) ) ) THEN
INFO = 3
ELSE IF( ( .NOT.NOTRAN ).AND.
$ ( .NOT.LSAME( TRANS, 'C' ) ) ) THEN
INFO = 4
ELSE IF( N .LT.0 ) THEN
INFO = 5
ELSE IF( K .LT.0 ) THEN
INFO = 6
ELSE IF( NB .LT.1 ) THEN
INFO = 7
END IF
*
10 CONTINUE
IF( INFO.NE.0 ) THEN
CALL PXERBLA( ICONTXT, 'PBZHER2K ', INFO )
RETURN
END IF
*
* Start the operations.
*
* === If C is a matrix ===
*
IF( CMAT ) THEN
NP = NUMROC( N, NB, MYROW, ICROW, NPROW )
NQ = NUMROC( N, NB, MYCOL, ICCOL, NPCOL )
*
IF( LDC.LT.MAX(1,NP) ) THEN
INFO = 15
ELSE IF( ICROW.LT.0 .OR. ICROW.GE.NPROW ) THEN
INFO = 18
ELSE IF( ICCOL.LT.0 .OR. ICCOL.GE.NPCOL ) THEN
INFO = 19
END IF
*
ADATA = .FALSE.
IF( IAPOS.EQ.-1 ) ADATA = .TRUE.
BDATA = .FALSE.
IF( IBPOS.EQ.-1 ) BDATA = .TRUE.
CSPACE = LSAME( CWORK, 'Y' )
ASPACE = LSAME( AWORK, 'Y' )
BSPACE = LSAME( BWORK, 'Y' )
COMMAB = ABCOMM
IF( LSAME( COMMAB, ' ' ) ) COMMAB = '1'
TALPHA = DCONJG( ALPHA )
*
* LCM : the least common multiple of NPROW and NPCOL
*
LCM = ILCM( NPROW, NPCOL )
LCMP = LCM / NPROW
LCMQ = LCM / NPCOL
LPBZ = LCMP * NB
LQBZ = LCMQ * NB
*
MRROW = MOD( NPROW+MYROW-ICROW, NPROW )
MRCOL = MOD( NPCOL+MYCOL-ICCOL, NPCOL )
TBETA = DCMPLX( BETA )
LKK = MAX( 1, K )
*
* PART 1: Distribute a column (or row) block A & B and transpose B
* ================================================================
*
IF( NOTRAN ) THEN
*
* Form C := alpha*A*B' + alpha'*B*A' + beta*C.
* __________ _ _ __________
* |\_ | | | | | |\_ |
* | \_ | | | | | | \_ |
* | \ | | | ___________ | | ___________ | \ |
* | C_ |=a*|A|*|____(B')___|+a'*|B|*|____(A')___|+b*| C_ |
* | \_ | | | | | | \_ |
* |_________\| |_| |_| |_________\|
*
IF( LDA.LT.MAX(1,NP) .AND. ( ASPACE .OR.
$ IAPOS.EQ.MYCOL .OR. IAPOS.EQ.-1 ) ) THEN
INFO = 10
ELSE IF( LDB.LT.MAX(1,NP) .AND. ( BSPACE .OR.
$ IBPOS.EQ.MYCOL .OR. IBPOS.EQ.-1 ) ) THEN
INFO = 12
ELSE IF( IAPOS.LT.-1 .OR. IAPOS.GE.NPCOL ) THEN
INFO = 16
ELSE IF( IBPOS.LT.-1 .OR. IBPOS.GE.NPCOL ) THEN
INFO = 17
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Broadcast A and B if necessary
*
IPT = 1
IPB = 1
IF( .NOT.ADATA ) THEN
IF( ASPACE ) THEN
IF( MYCOL.EQ.IAPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Row', COMMAB, NP, K, A, LDA )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMAB, NP, K, A, LDA,
$ MYROW, IAPOS )
END IF
ADATA = .TRUE.
ELSE
IF( MYCOL.EQ.IAPOS ) THEN
CALL PBZMATADD( ICONTXT, 'V', NP, K, ONE, A, LDA, ZERO,
$ WORK, NP )
CALL ZGEBS2D( ICONTXT, 'Row', COMMAB, NP, K, WORK, NP )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMAB, NP, K, WORK, NP,
$ MYROW, IAPOS )
END IF
IPT = NP * K + 1
IPB = IPT
END IF
END IF
*
IF( .NOT.BDATA ) THEN
IF( BSPACE ) THEN
IF( MYCOL.EQ.IBPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Row', COMMAB, NP, K, B, LDB )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMAB, NP, K, B, LDB,
$ MYROW, IBPOS )
END IF
BDATA = .TRUE.
ELSE
IF( MYCOL.EQ.IBPOS ) THEN
CALL PBZMATADD( ICONTXT, 'V', NP, K, ONE, B, LDB, ZERO,
$ WORK(IPB), NP )
CALL ZGEBS2D( ICONTXT, 'Row', COMMAB, NP, K,
$ WORK(IPB), NP )
ELSE
CALL ZGEBR2D( ICONTXT, 'Row', COMMAB, NP, K,
$ WORK(IPB), NP, MYROW, IBPOS )
END IF
IPT = NP * K + IPT
END IF
END IF
*
* Transpose column blocks of B to WORK(IPT).
*
IPW = K * NQ + IPT
IF( BDATA ) THEN
CALL PBZTRAN( ICONTXT, 'Col', 'C', N, K, NB, B, LDB,
$ ZERO, WORK(IPT), K, ICROW, -1, -1, ICCOL,
$ WORK(IPW) )
ELSE
CALL PBZTRAN( ICONTXT, 'Col', 'C', N, K, NB, WORK(IPB), NP,
$ ZERO, WORK(IPT), K, ICROW, -1, -1, ICCOL,
$ WORK(IPW) )
END IF
*
ELSE
*
* Form C := alpha*A'*B + alpha'*B'*A + beta*C.
* __________ _ _ __________
* |\_ | | | | | |\_ |
* | \_ | | | | | | \_ |
* | \ | | | ___________ | | ___________ | \ |
* | C_ |=a* A'*|_____B_____|+a'* B'*|_____A_____|+b*| C_ |
* | \_ | | | | | | \_ |
* |_________\| |_| |_| |_________\|
*
IF( LDA.LT.MAX(1,K) .AND. ( ASPACE .OR.
$ IAPOS.EQ.MYROW .OR. IAPOS.EQ.-1 ) ) THEN
INFO = 10
ELSE IF( LDB.LT.MAX(1,K) .AND. ( BSPACE .OR.
$ IBPOS.EQ.MYROW .OR. IBPOS.EQ.-1 ) ) THEN
INFO = 12
ELSE IF( IAPOS.LT.-1 .OR. IAPOS.GE.NPROW ) THEN
INFO = 16
ELSE IF( IBPOS.LT.-1 .OR. IBPOS.GE.NPROW ) THEN
INFO = 17
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Broadcast A and B if necessary
*
IPT = 1
IPB = 1
IF( .NOT.ADATA ) THEN
IF( ASPACE ) THEN
IF( MYROW.EQ.IAPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Col', COMMAB, K, NQ, A, LDA )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMAB, K, NQ, A, LDA,
$ IAPOS, MYCOL )
END IF
ADATA = .TRUE.
ELSE
IF( MYROW.EQ.IAPOS ) THEN
CALL PBZMATADD( ICONTXT, 'G', K, NQ, ONE, A, LDA, ZERO,
$ WORK, K )
CALL ZGEBS2D( ICONTXT, 'Col', COMMAB, K, NQ, WORK, K )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMAB, K, NQ, WORK, K,
$ IAPOS, MYCOL )
END IF
IPT = K * NQ + 1
IPB = IPT
END IF
END IF
*
IF( .NOT.BDATA ) THEN
IF( BSPACE ) THEN
IF( MYROW.EQ.IBPOS ) THEN
CALL ZGEBS2D( ICONTXT, 'Col', COMMAB, K, NQ, B, LDB )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMAB, K, NQ, B, LDB,
$ IBPOS, MYCOL )
END IF
BDATA = .TRUE.
ELSE
IF( MYROW.EQ.IBPOS ) THEN
CALL PBZMATADD( ICONTXT, 'G', K, NQ, ONE, B, LDB, ZERO,
$ WORK(IPB), K )
CALL ZGEBS2D( ICONTXT, 'Col', COMMAB, K, NQ,
$ WORK(IPB), K )
ELSE
CALL ZGEBR2D( ICONTXT, 'Col', COMMAB, K, NQ,
$ WORK(IPB), K, IBPOS, MYCOL )
END IF
IPT = K * NQ + IPT
END IF
END IF
*
* Transpose column blocks of B to WORK(IPT).
*
IPW = NP * K + IPT
IF( BDATA ) THEN
CALL PBZTRAN( ICONTXT, 'Row', 'C', K, N, NB, B, LDB, ZERO,
$ WORK(IPT), NP, -1, ICCOL, ICROW, -1,
$ WORK(IPW) )
ELSE
CALL PBZTRAN( ICONTXT, 'Row', 'C', K, N, NB, WORK(IPB), K,
$ ZERO, WORK(IPT), NP, -1, ICCOL, ICROW, -1,
$ WORK(IPW) )
END IF
END IF
*
* PART 2: Update C with A and B'
* ==============================
*
IF( NP.EQ.0 .OR. NQ.EQ.0 ) GO TO 80
*
* If C is a Hermitian upper triangular matrix,
*
IF( UPPER ) THEN
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 40 JJ = 1, ICEIL(NQ, IQBZ)
LMW = MIN( IPBZ, NP-JPBZ )
LNW = MIN( IQBZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the lower triangular part
*
IF( CSPACE ) THEN
*
* Update C := alpha*A*B' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, ALPHA,
$ A, LDA, WORK(JQBZ*K+IPT), LKK, TBETA,
$ C(1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, ALPHA,
$ WORK, NP, WORK(JQBZ*K+IPT), LKK, TBETA,
$ C(1,JQBZ+1), LDC )
END IF
*
* Update C := alpha'*B'*A + beta*C, if TRANS = 'C'
*
ELSE
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, TALPHA,
$ WORK(IPT), NP, A(1,JQBZ+1), LDA, TBETA,
$ C(1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, TALPHA,
$ WORK(IPT), NP, WORK(JQBZ*K+1), LKK, TBETA,
$ C(1,JQBZ+1), LDC )
END IF
END IF
*
* Update data in the upper triangular matrix
* and save data in the lower triangular matrix
*
ELSE
*
* Update C := alpha*A*B' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, ALPHA, A, LDA,
$ WORK(JQBZ*K+IPT), LKK, TBETA,
$ C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ A(JPBZ+1,1), LDA, WORK(JQBZ*K+IPT), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, ALPHA,
$ WORK, NP, WORK(JQBZ*K+IPT), LKK, TBETA,
$ C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+1), NP, WORK(JQBZ*K+IPT), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
END IF
*
* Update C := alpha'*B'*A + beta*C, if TRANS = 'C'
*
ELSE
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, TALPHA,
$ WORK(IPT), NP, A(1,JQBZ+1), LDA, TBETA,
$ C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, A(1,JQBZ+1), LDA,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, TALPHA,
$ WORK(IPT), NP, WORK(JQBZ*K+1), LKK,
$ TBETA, C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+1), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
*
DO 30 KJ = 0, LCMQ-1
20 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 20
END IF
KIZ = KI * NB
KJZ = KJ * NB
IF( KJZ.GE.LNW )
$ GO TO 40
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
*
CALL PBZTRADD( ICONTXT, 'Upper', FORM, KIZ, NB, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, TBETA,
$ C( JPBZ+1, JQBZ+KJZ+1 ), LDC,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
30 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
40 CONTINUE
*
* If C is a Hermitian lower triangular matrix,
*
ELSE
*
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 70 JJ = 1, ICEIL(NQ, IQBZ)
LMW = MIN( IPBZ, MAX(NP-JPBZ, 0) )
LNW = MIN( IQBZ, MAX(NQ-JQBZ, 0) )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the upper triangular part
*
IF( CSPACE ) THEN
*
* Update C := alpha*A*B' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, ALPHA,
$ A(JPBZ+1,1), LDA, WORK(JQBZ*K+IPT), LKK,
$ TBETA, C(JPBZ+1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, ALPHA,
$ WORK(JPBZ+1), NP, WORK(JQBZ*K+IPT), LKK,
$ TBETA, C(JPBZ+1,JQBZ+1), LDC )
END IF
*
* Update C := alpha'*B'*A + beta*C, if TRANS = 'C'
*
ELSE
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, A(1,JQBZ+1), LDA,
$ TBETA, C(JPBZ+1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+1), LKK,
$ TBETA, C(JPBZ+1,JQBZ+1), LDC )
END IF
END IF
*
* Update data in the lower triangular matrix
* and save data in the upper triangular matrix
*
ELSE
*
* Update C := alpha*A*B' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, ALPHA,
$ A(JNPBZ+1,1), LDA, WORK(JQBZ*K+IPT), LKK,
$ TBETA, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ A(JPBZ+1,1), LDA, WORK(JQBZ*K+IPT), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, ALPHA,
$ WORK(JNPBZ+1), NP, WORK(JQBZ*K+IPT), LKK,
$ TBETA, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+1), NP, WORK(JQBZ*K+IPT), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
END IF
*
* Update C := alpha'*B'*A + beta*C, if TRANS = 'C'
*
ELSE
IF( ADATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, TALPHA,
$ WORK(JNPBZ+IPT), NP, A(1,JQBZ+1), LDA,
$ TBETA, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, A(1,JQBZ+1), LDA,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, TALPHA,
$ WORK(JNPBZ+IPT), NP, WORK(JQBZ*K+1), LKK,
$ TBETA, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+1), LKK,
$ ZERO, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
*
DO 60 KJ = 0, LCMQ-1
50 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 50
END IF
KIZ = KI * NB
KJZ = KJ * NB
IF( KJZ.GE.LNW ) GO TO 70
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
*
CALL PBZTRADD( ICONTXT, 'Lower', FORM, KIZ, NB, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, TBETA,
$ C( JPBZ+1, JQBZ+KJZ+1 ), LDC,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
60 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
70 CONTINUE
END IF
*
80 CONTINUE
*
* PART 3: Transpose A' (A is already distributed)
* ===============================================
*
IF( NOTRAN ) THEN
IF( ADATA ) THEN
CALL PBZTRAN( ICONTXT, 'Col', 'C', N, K, NB, A, LDA, ZERO,
$ WORK(IPT), K, ICROW, -1, -1, ICCOL,
$ WORK(IPW) )
ELSE
CALL PBZTRAN( ICONTXT, 'Col', 'C', N, K, NB, WORK, NP, ZERO,
$ WORK(IPT), K, ICROW, -1, -1, ICCOL,
$ WORK(IPW) )
END IF
*
ELSE
IF( ADATA ) THEN
CALL PBZTRAN( ICONTXT, 'Row', 'C', K, N, NB, A, LDA, ZERO,
$ WORK(IPT), NP, -1, ICCOL, ICROW, -1,
$ WORK(IPW) )
ELSE
CALL PBZTRAN( ICONTXT, 'Row', 'C', K, N, NB, WORK, K, ZERO,
$ WORK(IPT), NP, -1, ICCOL, ICROW, -1,
$ WORK(IPW) )
END IF
END IF
*
* PART 4: Update C with B and A'
* =====================================
*
IF( NP.EQ.0 .OR. NQ.EQ.0 ) RETURN
*
* If C is a Hermitian upper triangular matrix,
*
IF( UPPER ) THEN
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 110 JJ = 1, ICEIL(NQ, IQBZ)
LMW = MIN( IPBZ, NP-JPBZ )
LNW = MIN( IQBZ, NQ-JQBZ )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the lower triangular part
*
IF( CSPACE ) THEN
*
* Update C := alpha'*B*A' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, TALPHA,
$ B, LDB, WORK(JQBZ*K+IPT), LKK,
$ ONE, C(1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, TALPHA,
$ WORK(IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(1,JQBZ+1), LDC )
END IF
*
* Update C := alpha*A'*B + beta*C, if TRANS = 'C'
*
ELSE
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, ALPHA,
$ WORK(IPT), NP, B(1,JQBZ+1), LDB,
$ ONE, C(1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', JNPBZ, LNW, K, ALPHA,
$ WORK(IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ONE, C(1,JQBZ+1), LDC )
END IF
END IF
*
* Update data in the upper triangular matrix
* and save data in the lower triangular matrix
*
ELSE
*
* Update C := alpha'*B*A' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, TALPHA,
$ B, LDB, WORK(JQBZ*K+IPT), LKK,
$ ONE, C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ B(JPBZ+1,1), LDB, WORK(JQBZ*K+IPT),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, TALPHA,
$ WORK(IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
END IF
*
* Update C := alpha*A'*B + beta*C, if TRANS = 'C'
*
ELSE
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, ALPHA,
$ WORK(IPT), NP, B(1,JQBZ+1), LDB,
$ ONE, C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, B(1,JQBZ+1), LDB,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', JPBZ, LNW, K, ALPHA,
$ WORK(IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ONE, C(1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
*
DO 100 KJ = 0, LCMQ-1
90 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 90
END IF
KIZ = KI * NB
KJZ = KJ * NB
IF( KJZ.GE.LNW )
$ GO TO 110
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
*
CALL PBZTRADD( ICONTXT, 'Upper', FORM, KIZ, NB, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, ONE,
$ C( JPBZ+1, JQBZ+KJZ+1 ), LDC,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
100 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
110 CONTINUE
*
* If C is a Hermitian lower triangular matrix,
*
ELSE
*
ISZCMP = ICEIL( MULLEN, LQBZ )
IF( ISZCMP.LE.0 ) ISZCMP = 1
IPBZ = ISZCMP * LPBZ
IQBZ = ISZCMP * LQBZ
JPBZ = 0
JQBZ = 0
*
DO 140 JJ = 1, ICEIL(NQ, IQBZ)
LMW = MIN( IPBZ, MAX(NP-JPBZ, 0) )
LNW = MIN( IQBZ, MAX(NQ-JQBZ, 0) )
JNPBZ = JPBZ + LMW
*
* Modify (change) data in the upper triangular part
*
IF( CSPACE ) THEN
*
* Update C := alpha'*B*A' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, TALPHA,
$ B(JPBZ+1,1), LDB, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(JPBZ+1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, TALPHA,
$ WORK(JPBZ+IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(JPBZ+1,JQBZ+1), LDC )
END IF
*
* Update C := alpha*A'*B+alpha*B'*A+beta*C, if TRANS = 'C'
*
ELSE
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, B(1,JQBZ+1), LDB,
$ ONE, C(JPBZ+1,JQBZ+1), LDC )
ELSE
CALL ZGEMM( 'No', 'No', NP-JPBZ, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ONE, C(JPBZ+1,JQBZ+1), LDC )
END IF
END IF
*
* Update data in the lower triangular matrix
* and save data in the upper triangular matrix
*
ELSE
*
* Update C := alpha'*B*A' + beta*C, if TRANS = 'N'
*
IF( NOTRAN ) THEN
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, TALPHA,
$ B(JNPBZ+1,1), LDB, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ B(JPBZ+1,1), LDB, WORK(JQBZ*K+IPT),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, TALPHA,
$ WORK(JNPBZ+IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ONE, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, TALPHA,
$ WORK(JPBZ+IPB), NP, WORK(JQBZ*K+IPT),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
END IF
*
* Update C := alpha*A'*B + beta*C, if TRANS = 'C'
*
ELSE
IF( BDATA ) THEN
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, ALPHA,
$ WORK(JNPBZ+IPT), NP, B(1,JQBZ+1), LDB,
$ ONE, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, B(1,JQBZ+1), LDB,
$ ZERO, WORK(IPW), MAX(1,LMW) )
ELSE
CALL ZGEMM( 'No', 'No', NP-JNPBZ, LNW, K, ALPHA,
$ WORK(JNPBZ+IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ONE, C(JNPBZ+1,JQBZ+1), LDC )
CALL ZGEMM( 'No', 'No', LMW, LNW, K, ALPHA,
$ WORK(JPBZ+IPT), NP, WORK(JQBZ*K+IPB),
$ LKK, ZERO, WORK(IPW), MAX(1,LMW) )
END IF
END IF
*
* Compute diagonal blocks.
*
MZROW = MRROW
MZCOL = MRCOL
KI = 0
*
DO 130 KJ = 0, LCMQ-1
120 CONTINUE
IF( MZROW.LT.MZCOL ) THEN
MZROW = MZROW + NPROW
KI = KI + 1
GO TO 120
END IF
KIZ = KI * NB
KJZ = KJ * NB
IF( KJZ.GE.LNW )
$ GO TO 140
FORM = 'G'
IF( MZROW.EQ.MZCOL )
$ FORM = 'H'
MZCOL = MZCOL + NPCOL
*
CALL PBZTRADD( ICONTXT, 'Lower', FORM, KIZ, NB, ONE,
$ WORK( KJZ*LMW+IPW ), LMW, ONE,
$ C( JPBZ+1, JQBZ+KJZ+1 ), LDC,
$ LPBZ, LQBZ, LMW, LNW-KJZ )
130 CONTINUE
END IF
*
JPBZ = JNPBZ
JQBZ = JQBZ + LNW
140 CONTINUE
END IF
*
* === If C is just a block ===
*
ELSE
IF( NOTRAN .AND. MYROW.EQ.ICROW ) THEN
*
* Form C := alpha*A*(B') + alpha*B*(A') +beta * C.
* _ _
* | | | |
* | | | |
* _ _____________ | | _____________ | | _
* |_| = a*|______A______|*(B') + a*|______B______|*(A') + b*|_|
* C | | | | C
* | | | |
* |_| |_|
*
NQ = NUMROC( K, NB, MYCOL, IAPOS, NPCOL )
CSPACE = LSAME( CWORK, 'Y' )
*
IF( LDA.LT.MAX(1,N) ) THEN
INFO = 10
ELSE IF( LDB.LT.MAX(1,N) ) THEN
INFO = 12
ELSE IF( LDC.LT.MAX(1,N) .AND. ( CSPACE .OR.
$ ICCOL.EQ.MYCOL .OR. ICCOL.EQ.-1 ) ) THEN
INFO = 15
ELSE IF( IAPOS.LT.0 .OR. IAPOS.GE.NPCOL ) THEN
INFO = 16
ELSE IF( IBPOS.NE.IAPOS ) THEN
INFO = 17
ELSE IF( ICROW.LT.0 .OR. ICROW.GE.NPROW ) THEN
INFO = 18
ELSE IF( ICCOL.LT.-1 .OR. ICCOL.GE.NPCOL ) THEN
INFO = 19
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Compute C
*
IF( MYCOL.EQ.ICCOL ) THEN
CALL ZHER2K( UPLO, TRANS, N, NQ, ALPHA, A, LDA, B, LDB,
$ BETA, C, LDC )
CALL PBZT1CPY( UPLO, JJ, N, C, LDC, WORK )
CALL ZGSUM2D( ICONTXT, 'Row', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
CALL PBZT2CPY( UPLO, JJ, N, C, LDC, WORK )
*
ELSE
IF( CSPACE ) THEN
CALL ZHER2K( UPLO, TRANS, N, NQ, ALPHA, A, LDA, B, LDB,
$ RZERO, C, LDC )
CALL PBZT1CPY( UPLO, JJ, N, C, LDC, WORK )
CALL ZGSUM2D( ICONTXT, 'Row', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
ELSE
CALL ZHER2K( UPLO, TRANS, N, NQ, ALPHA, A, LDA, B, LDB,
$ RZERO, WORK, N )
CALL PBZT3CPY( UPLO, JJ, N, WORK )
CALL ZGSUM2D( ICONTXT, 'Row', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
END IF
END IF
*
ELSE IF( LSAME( TRANS, 'C' ) .AND. MYCOL.EQ.ICCOL ) THEN
*
* Form B := alpha*B / op( A ).
* _ _
* | | | |
* | | | |
* _ _____________ | | _____________ | | _
* |_| = a*|_____(B')____| * |A| + a*|_____(A')____| * |B| + b*|_|
* C | | | | C
* | | | |
* |_| |_|
*
NP = NUMROC( K, NB, MYROW, IAPOS, NPROW )
CSPACE = LSAME( CWORK, 'Y' )
*
IF( LDA.LT.MAX(1,NP) ) THEN
INFO = 10
ELSE IF( LDB.LT.MAX(1,NP) ) THEN
INFO = 12
ELSE IF( LDC.LT.MAX(1,N) .AND. ( CSPACE .OR.
$ ICROW.EQ.MYROW .OR. ICROW.EQ.-1 ) ) THEN
INFO = 15
ELSE IF( IAPOS.LT.0 .OR. IAPOS.GE.NPROW ) THEN
INFO = 16
ELSE IF( IBPOS.NE.IAPOS ) THEN
INFO = 17
ELSE IF( ICROW.LT.-1 .OR. ICROW.GE.NPROW ) THEN
INFO = 18
ELSE IF( ICCOL.LT.0 .OR. ICCOL.GE.NPCOL ) THEN
INFO = 19
END IF
IF( INFO.NE.0 ) GO TO 10
*
* Compute C
*
IF( MYROW.EQ.ICROW ) THEN
CALL ZHER2K( UPLO, TRANS, N, NP, ALPHA, A, LDA, B, LDB,
$ BETA, C, LDC )
CALL PBZT1CPY( UPLO, JJ, N, C, LDC, WORK )
CALL ZGSUM2D( ICONTXT, 'Col', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
CALL PBZT2CPY( UPLO, JJ, N, C, LDC, WORK )
*
ELSE
IF( CSPACE ) THEN
CALL ZHER2K( UPLO, TRANS, N, NP, ALPHA, A, LDA, B, LDB,
$ RZERO, C, LDC )
CALL PBZT1CPY( UPLO, JJ, N, C, LDC, WORK )
CALL ZGSUM2D( ICONTXT, 'Col', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
ELSE
CALL ZHER2K( UPLO, TRANS, N, NP, ALPHA, A, LDA, B, LDB,
$ RZERO, WORK, N )
CALL PBZT3CPY( UPLO, JJ, N, WORK )
CALL ZGSUM2D( ICONTXT, 'Col', '1-tree', 1, JJ, WORK, 1,
$ ICROW, ICCOL )
END IF
END IF
END IF
END IF
*
RETURN
*
* End of PBZHER2K
*
END
|
