1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
SUBROUTINE PSLARED2D( N, IA, JA, DESC, BYROW, BYALL, WORK, LWORK )
*
* -- ScaLAPACK routine (version 1.7) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* May 1, 1997
*
* .. Scalar Arguments ..
INTEGER IA, JA, LWORK, N
* ..
* .. Array Arguments ..
INTEGER DESC( * )
REAL BYALL( * ), BYROW( * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* PSLARED2D redistributes a 1D array
*
* It assumes that the input array, BYROW, is distributed across
* columns and that all process rows contain the same copy of
* BYROW. The output array, BYALL, will be identical on all processes
* and will contain the entire array.
*
* Notes
* =====
*
* Each global data object is described by an associated description
* vector. This vector stores the information required to establish
* the mapping between an object element and its corresponding process
* and memory location.
*
* Let A be a generic term for any 2D block cyclicly distributed array.
* Such a global array has an associated description vector DESCA.
* In the following comments, the character _ should be read as
* "of the global array".
*
* NOTATION STORED IN EXPLANATION
* --------------- -------------- --------------------------------------
* DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
* DTYPE_A = 1.
* CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
* the BLACS process grid A is distribu-
* ted over. The context itself is glo-
* bal, but the handle (the integer
* value) may vary.
* M_A (global) DESCA( M_ ) The number of rows in the global
* array A.
* N_A (global) DESCA( N_ ) The number of columns in the global
* array A.
* MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
* the rows of the array.
* NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
* the columns of the array.
* RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
* row of the array A is distributed.
* CSRC_A (global) DESCA( CSRC_ ) The process column over which the
* first column of the array A is
* distributed.
* LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
* array. LLD_A >= MAX(1,LOCr(M_A)).
*
* Let K be the number of rows or columns of a distributed matrix,
* and assume that its process grid has dimension p x q.
* LOCr( K ) denotes the number of elements of K that a process
* would receive if K were distributed over the p processes of its
* process column.
* Similarly, LOCc( K ) denotes the number of elements of K that a
* process would receive if K were distributed over the q processes of
* its process row.
* The values of LOCr() and LOCc() may be determined via a call to the
* ScaLAPACK tool function, NUMROC:
* LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
* LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
* An upper bound for these quantities may be computed by:
* LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
* LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
* Arguments
* =========
*
* NP = Number of local rows in BYROW()
*
* N (global input) INTEGER
* The number of elements to be redistributed. N >= 0.
*
* IA (global input) INTEGER
* IA must be equal to 1
*
* JA (global input) INTEGER
* JA must be equal to 1
*
* DESC (global/local input) INTEGER Array of dimension DLEN_
* A 2D array descriptor, which describes BYROW
*
* BYROW (local input) distributed block cyclic REAL array
* global dimension (N), local dimension NP
* BYCOL is distributed across the process columns
* All process rows are assumed to contain the same value
*
* BYALL (global output) REAL global dimension( N )
* local dimension (N)
* BYALL is exactly duplicated on all processes
* It contains the same values as BYCOL, but it is replicated
* across all processes rather than being distributed
*
* BYALL(i) = BYCOL( NUMROC(i,NB,MYROW,0,NPROW ) on the procs
* whose MYROW == mod((i-1)/NB,NPROW)
*
* WORK (local workspace) REAL dimension (LWORK)
* Used to hold the buffers sent from one process to another
*
* LWORK (local input) INTEGER size of WORK array LWORK >=
* LWORK >= NUMROC(N, DESC( NB_ ), 0, 0, NPCOL)
*
* .. Parameters ..
INTEGER BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
$ MB_, NB_, RSRC_, CSRC_, LLD_
PARAMETER ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DTYPE_ = 1,
$ CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
$ RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
* ..
* .. Local Scalars ..
INTEGER ALLI, BUFLEN, I, II, MB, MYCOL, MYROW, NPCOL,
$ NPROW, PROW
* ..
* .. External Functions ..
INTEGER NUMROC
EXTERNAL NUMROC
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, SCOPY, SGEBR2D, SGEBS2D
* ..
* .. Intrinsic Functions ..
INTRINSIC MIN
* ..
* .. Executable Statements ..
CALL BLACS_GRIDINFO( DESC( CTXT_ ), NPROW, NPCOL, MYROW, MYCOL )
MB = DESC( MB_ )
*
DO 30 PROW = 0, NPROW - 1
BUFLEN = NUMROC( N, MB, PROW, 0, NPROW )
IF( MYROW.EQ.PROW ) THEN
CALL SCOPY( BUFLEN, BYROW, 1, WORK, 1 )
CALL SGEBS2D( DESC( CTXT_ ), 'C', ' ', BUFLEN, 1, WORK,
$ BUFLEN )
ELSE
CALL SGEBR2D( DESC( CTXT_ ), 'C', ' ', BUFLEN, 1, WORK,
$ BUFLEN, PROW, MYCOL )
END IF
*
ALLI = PROW*MB
DO 20 II = 1, BUFLEN, MB
DO 10 I = 1, MIN( MB, BUFLEN-II+1 )
BYALL( ALLI+I ) = WORK( II-1+I )
10 CONTINUE
ALLI = ALLI + MB*NPROW
20 CONTINUE
30 CONTINUE
*
RETURN
END
|
