1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
|
SUBROUTINE PSLACON( N, V, IV, JV, DESCV, X, IX, JX, DESCX, ISGN,
$ EST, KASE )
*
* -- ScaLAPACK auxiliary routine (version 1.7) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* May 1, 1997
*
* .. Scalar Arguments ..
INTEGER IV, IX, JV, JX, KASE, N
REAL EST
* ..
* .. Array Arguments ..
INTEGER DESCV( * ), DESCX( * ), ISGN( * )
REAL V( * ), X( * )
* ..
*
* Purpose
* =======
*
* PSLACON estimates the 1-norm of a square, real distributed matrix A.
* Reverse communication is used for evaluating matrix-vector products.
* X and V are aligned with the distributed matrix A, this information
* is implicitly contained within IV, IX, DESCV, and DESCX.
*
* Notes
* =====
*
* Each global data object is described by an associated description
* vector. This vector stores the information required to establish
* the mapping between an object element and its corresponding process
* and memory location.
*
* Let A be a generic term for any 2D block cyclicly distributed array.
* Such a global array has an associated description vector DESCA.
* In the following comments, the character _ should be read as
* "of the global array".
*
* NOTATION STORED IN EXPLANATION
* --------------- -------------- --------------------------------------
* DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
* DTYPE_A = 1.
* CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
* the BLACS process grid A is distribu-
* ted over. The context itself is glo-
* bal, but the handle (the integer
* value) may vary.
* M_A (global) DESCA( M_ ) The number of rows in the global
* array A.
* N_A (global) DESCA( N_ ) The number of columns in the global
* array A.
* MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
* the rows of the array.
* NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
* the columns of the array.
* RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
* row of the array A is distributed.
* CSRC_A (global) DESCA( CSRC_ ) The process column over which the
* first column of the array A is
* distributed.
* LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
* array. LLD_A >= MAX(1,LOCr(M_A)).
*
* Let K be the number of rows or columns of a distributed matrix,
* and assume that its process grid has dimension p x q.
* LOCr( K ) denotes the number of elements of K that a process
* would receive if K were distributed over the p processes of its
* process column.
* Similarly, LOCc( K ) denotes the number of elements of K that a
* process would receive if K were distributed over the q processes of
* its process row.
* The values of LOCr() and LOCc() may be determined via a call to the
* ScaLAPACK tool function, NUMROC:
* LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
* LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
* An upper bound for these quantities may be computed by:
* LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
* LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
* Arguments
* =========
*
* N (global input) INTEGER
* The length of the distributed vectors V and X. N >= 0.
*
* V (local workspace) REAL pointer into the local
* memory to an array of dimension LOCr(N+MOD(IV-1,MB_V)). On
* the final return, V = A*W, where EST = norm(V)/norm(W)
* (W is not returned).
*
* IV (global input) INTEGER
* The row index in the global array V indicating the first
* row of sub( V ).
*
* JV (global input) INTEGER
* The column index in the global array V indicating the
* first column of sub( V ).
*
* DESCV (global and local input) INTEGER array of dimension DLEN_.
* The array descriptor for the distributed matrix V.
*
* X (local input/local output) REAL pointer into the
* local memory to an array of dimension
* LOCr(N+MOD(IX-1,MB_X)). On an intermediate return, X
* should be overwritten by
* A * X, if KASE=1,
* A' * X, if KASE=2,
* PSLACON must be re-called with all the other parameters
* unchanged.
*
* IX (global input) INTEGER
* The row index in the global array X indicating the first
* row of sub( X ).
*
* JX (global input) INTEGER
* The column index in the global array X indicating the
* first column of sub( X ).
*
* DESCX (global and local input) INTEGER array of dimension DLEN_.
* The array descriptor for the distributed matrix X.
*
* ISGN (local workspace) INTEGER array, dimension
* LOCr(N+MOD(IX-1,MB_X)). ISGN is aligned with X and V.
*
*
* EST (global output) REAL
* An estimate (a lower bound) for norm(A).
*
* KASE (local input/local output) INTEGER
* On the initial call to PSLACON, KASE should be 0.
* On an intermediate return, KASE will be 1 or 2, indicating
* whether X should be overwritten by A * X or A' * X.
* On the final return from PSLACON, KASE will again be 0.
*
* Further Details
* ===============
*
* The serial version SLACON has been contributed by Nick Higham,
* University of Manchester. It was originally named SONEST, dated
* March 16, 1988.
*
* Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
* a real or complex matrix, with applications to condition estimation",
* ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
*
* =====================================================================
*
* .. Parameters ..
INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
$ LLD_, MB_, M_, NB_, N_, RSRC_
PARAMETER ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DTYPE_ = 1,
$ CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
$ RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
INTEGER ITMAX
PARAMETER ( ITMAX = 5 )
REAL ZERO, ONE, TWO
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0, TWO = 2.0E+0 )
* ..
* .. Local Scalars ..
INTEGER I, ICTXT, IFLAG, IIVX, IMAXROW, IOFFVX, IROFF,
$ ITER, IVXCOL, IVXROW, J, JLAST, JJVX, JUMP,
$ K, MYCOL, MYROW, NP, NPCOL, NPROW
REAL ALTSGN, ESTOLD, JLMAX, TEMP, XMAX
* ..
* .. Local Arrays ..
REAL WORK( 2 )
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, IGSUM2D, INFOG2L, PSAMAX,
$ PSASUM, PSELGET, SGEBR2D,
$ SGEBS2D, SCOPY
* ..
* .. External Functions ..
INTEGER INDXG2L, INDXG2P, INDXL2G, NUMROC
EXTERNAL INDXG2L, INDXG2P, INDXL2G, NUMROC
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, MOD, NINT, REAL, SIGN
* ..
* .. Save statement ..
SAVE
* ..
* .. Executable Statements ..
*
* Get grid parameters.
*
ICTXT = DESCX( CTXT_ )
CALL BLACS_GRIDINFO( ICTXT, NPROW, NPCOL, MYROW, MYCOL )
*
CALL INFOG2L( IX, JX, DESCX, NPROW, NPCOL, MYROW, MYCOL,
$ IIVX, JJVX, IVXROW, IVXCOL )
IF( MYCOL.NE.IVXCOL )
$ RETURN
IROFF = MOD( IX-1, DESCX( MB_ ) )
NP = NUMROC( N+IROFF, DESCX( MB_ ), MYROW, IVXROW, NPROW )
IF( MYROW.EQ.IVXROW )
$ NP = NP - IROFF
IOFFVX = IIVX + (JJVX-1)*DESCX( LLD_ )
*
IF( KASE.EQ.0 ) THEN
DO 10 I = IOFFVX, IOFFVX+NP-1
X( I ) = ONE / REAL( N )
10 CONTINUE
KASE = 1
JUMP = 1
RETURN
END IF
*
GO TO ( 20, 40, 70, 110, 140 )JUMP
*
* ................ ENTRY (JUMP = 1)
* FIRST ITERATION. X HAS BEEN OVERWRITTEN BY A*X
*
20 CONTINUE
IF( N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
V( IOFFVX ) = X( IOFFVX )
EST = ABS( V( IOFFVX ) )
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1,
$ IVXROW, MYCOL )
END IF
* ... QUIT
GO TO 150
END IF
CALL PSASUM( N, EST, X, IX, JX, DESCX, 1 )
IF( DESCX( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1,
$ IVXROW, MYCOL )
END IF
END IF
*
DO 30 I = IOFFVX, IOFFVX+NP-1
X( I ) = SIGN( ONE, X( I ) )
ISGN( I ) = NINT( X( I ) )
30 CONTINUE
KASE = 2
JUMP = 2
RETURN
*
* ................ ENTRY (JUMP = 2)
* FIRST ITERATION. X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X
*
40 CONTINUE
CALL PSAMAX( N, XMAX, J, X, IX, JX, DESCX, 1 )
IF( DESCX( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
WORK( 1 ) = XMAX
WORK( 2 ) = REAL( J )
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 2, 1, WORK, 2 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 2, 1, WORK, 2,
$ IVXROW, MYCOL )
XMAX = WORK( 1 )
J = NINT( WORK( 2 ) )
END IF
END IF
ITER = 2
*
* MAIN LOOP - ITERATIONS 2, 3,...,ITMAX
*
50 CONTINUE
DO 60 I = IOFFVX, IOFFVX+NP-1
X( I ) = ZERO
60 CONTINUE
IMAXROW = INDXG2P( J, DESCX( MB_ ), MYROW, DESCX( RSRC_ ), NPROW )
IF( MYROW.EQ.IMAXROW ) THEN
I = INDXG2L( J, DESCX( MB_ ), MYROW, DESCX( RSRC_ ), NPROW )
X( I ) = ONE
END IF
KASE = 1
JUMP = 3
RETURN
*
* ................ ENTRY (JUMP = 3)
* X HAS BEEN OVERWRITTEN BY A*X
*
70 CONTINUE
CALL SCOPY( NP, X( IOFFVX ), 1, V( IOFFVX ), 1 )
ESTOLD = EST
CALL PSASUM( N, EST, V, IV, JV, DESCV, 1 )
IF( DESCV( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 1, 1, EST, 1,
$ IVXROW, MYCOL )
END IF
END IF
IFLAG = 0
DO 80 I = IOFFVX, IOFFVX+NP-1
IF( NINT( SIGN( ONE, X( I ) ) ).NE.ISGN( I ) ) THEN
IFLAG = 1
GO TO 90
END IF
80 CONTINUE
*
90 CONTINUE
CALL IGSUM2D( ICTXT, 'C', ' ', 1, 1, IFLAG, 1, -1, MYCOL )
*
* REPEATED SIGN VECTOR DETECTED, HENCE ALGORITHM HAS CONVERGED.
* ALONG WITH IT, TEST FOR CYCLING.
*
IF( IFLAG.EQ.0 .OR. EST.LE.ESTOLD )
$ GO TO 120
*
DO 100 I = IOFFVX, IOFFVX+NP-1
X( I ) = SIGN( ONE, X( I ) )
ISGN( I ) = NINT( X( I ) )
100 CONTINUE
KASE = 2
JUMP = 4
RETURN
*
* ................ ENTRY (JUMP = 4)
* X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X
*
110 CONTINUE
JLAST = J
CALL PSAMAX( N, XMAX, J, X, IX, JX, DESCX, 1 )
IF( DESCX( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
WORK( 1 ) = XMAX
WORK( 2 ) = REAL( J )
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 2, 1, WORK, 2 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 2, 1, WORK, 2,
$ IVXROW, MYCOL )
XMAX = WORK( 1 )
J = NINT( WORK( 2 ) )
END IF
END IF
CALL PSELGET( 'Columnwise', ' ', JLMAX, X, JLAST, JX, DESCX )
IF( ( JLMAX.NE.ABS( XMAX ) ).AND.( ITER.LT.ITMAX ) ) THEN
ITER = ITER + 1
GO TO 50
END IF
*
* ITERATION COMPLETE. FINAL STAGE.
*
120 CONTINUE
DO 130 I = IOFFVX, IOFFVX+NP-1
K = INDXL2G( I-IOFFVX+IIVX, DESCX( MB_ ), MYROW,
$ DESCX( RSRC_ ), NPROW )-IX+1
IF( MOD( K, 2 ).EQ.0 ) THEN
ALTSGN = -ONE
ELSE
ALTSGN = ONE
END IF
X( I ) = ALTSGN*( ONE+REAL( K-1 ) / REAL( N-1 ) )
130 CONTINUE
KASE = 1
JUMP = 5
RETURN
*
* ................ ENTRY (JUMP = 5)
* X HAS BEEN OVERWRITTEN BY A*X
*
140 CONTINUE
CALL PSASUM( N, TEMP, X, IX, JX, DESCX, 1 )
IF( DESCX( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
IF( MYROW.EQ.IVXROW ) THEN
CALL SGEBS2D( ICTXT, 'Columnwise', ' ', 1, 1, TEMP, 1 )
ELSE
CALL SGEBR2D( ICTXT, 'Columnwise', ' ', 1, 1, TEMP, 1,
$ IVXROW, MYCOL )
END IF
END IF
TEMP = TWO*( TEMP / REAL( 3*N ) )
IF( TEMP.GT.EST ) THEN
CALL SCOPY( NP, X( IOFFVX ), 1, V( IOFFVX ), 1 )
EST = TEMP
END IF
*
150 CONTINUE
KASE = 0
*
RETURN
*
* End of PSLACON
*
END
|
