1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
|
SUBROUTINE SLARRB2( N, D, LLD, IFIRST, ILAST, RTOL1,
$ RTOL2, OFFSET, W, WGAP, WERR, WORK, IWORK,
$ PIVMIN, LGPVMN, LGSPDM, TWIST, INFO )
*
* -- ScaLAPACK auxiliary routine (version 2.0) --
* Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
* July 4, 2010
*
IMPLICIT NONE
*
* .. Scalar Arguments ..
INTEGER IFIRST, ILAST, INFO, N, OFFSET, TWIST
REAL LGPVMN, LGSPDM, PIVMIN,
$ RTOL1, RTOL2
* ..
* .. Array Arguments ..
INTEGER IWORK( * )
REAL D( * ), LLD( * ), W( * ),
$ WERR( * ), WGAP( * ), WORK( * )
* ..
*
* Purpose
* =======
*
* Given the relatively robust representation(RRR) L D L^T, SLARRB2
* does "limited" bisection to refine the eigenvalues of L D L^T,
* W( IFIRST-OFFSET ) through W( ILAST-OFFSET ), to more accuracy. Initial
* guesses for these eigenvalues are input in W, the corresponding estimate
* of the error in these guesses and their gaps are input in WERR
* and WGAP, respectively. During bisection, intervals
* [left, right] are maintained by storing their mid-points and
* semi-widths in the arrays W and WERR respectively.
*
* NOTE:
* There are very few minor differences between SLARRB from LAPACK
* and this current subroutine SLARRB2.
* The most important reason for creating this nearly identical copy
* is profiling: in the ScaLAPACK MRRR algorithm, eigenvalue computation
* using SLARRB2 is used for refinement in the construction of
* the representation tree, as opposed to the initial computation of the
* eigenvalues for the root RRR which uses SLARRB. When profiling,
* this allows an easy quantification of refinement work vs. computing
* eigenvalues of the root.
*
* Arguments
* =========
*
* N (input) INTEGER
* The order of the matrix.
*
* D (input) REAL array, dimension (N)
* The N diagonal elements of the diagonal matrix D.
*
* LLD (input) REAL array, dimension (N-1)
* The (N-1) elements L(i)*L(i)*D(i).
*
* IFIRST (input) INTEGER
* The index of the first eigenvalue to be computed.
*
* ILAST (input) INTEGER
* The index of the last eigenvalue to be computed.
*
* RTOL1 (input) REAL
* RTOL2 (input) REAL
* Tolerance for the convergence of the bisection intervals.
* An interval [LEFT,RIGHT] has converged if
* RIGHT-LEFT.LT.MAX( RTOL1*GAP, RTOL2*MAX(|LEFT|,|RIGHT|) )
* where GAP is the (estimated) distance to the nearest
* eigenvalue.
*
* OFFSET (input) INTEGER
* Offset for the arrays W, WGAP and WERR, i.e., the IFIRST-OFFSET
* through ILAST-OFFSET elements of these arrays are to be used.
*
* W (input/output) REAL array, dimension (N)
* On input, W( IFIRST-OFFSET ) through W( ILAST-OFFSET ) are
* estimates of the eigenvalues of L D L^T indexed IFIRST through ILAST.
* On output, these estimates are refined.
*
* WGAP (input/output) REAL array, dimension (N-1)
* On input, the (estimated) gaps between consecutive
* eigenvalues of L D L^T, i.e., WGAP(I-OFFSET) is the gap between
* eigenvalues I and I+1. Note that if IFIRST.EQ.ILAST
* then WGAP(IFIRST-OFFSET) must be set to ZERO.
* On output, these gaps are refined.
*
* WERR (input/output) REAL array, dimension (N)
* On input, WERR( IFIRST-OFFSET ) through WERR( ILAST-OFFSET ) are
* the errors in the estimates of the corresponding elements in W.
* On output, these errors are refined.
*
* WORK (workspace) REAL array, dimension (4*N)
* Workspace.
*
* IWORK (workspace) INTEGER array, dimension (2*N)
* Workspace.
*
* PIVMIN (input) REAL
* The minimum pivot in the sturm sequence.
*
* LGPVMN (input) REAL
* Logarithm of PIVMIN, precomputed.
*
* LGSPDM (input) REAL
* Logarithm of the spectral diameter, precomputed.
*
* TWIST (input) INTEGER
* The twist index for the twisted factorization that is used
* for the negcount.
* TWIST = N: Compute negcount from L D L^T - LAMBDA I = L+ D+ L+^T
* TWIST = 1: Compute negcount from L D L^T - LAMBDA I = U- D- U-^T
* TWIST = R: Compute negcount from L D L^T - LAMBDA I = N(r) D(r) N(r)
*
* INFO (output) INTEGER
* Error flag.
*
* .. Parameters ..
REAL ZERO, TWO, HALF
PARAMETER ( ZERO = 0.0E0, TWO = 2.0E0,
$ HALF = 0.5E0 )
INTEGER MAXITR
* ..
* .. Local Scalars ..
INTEGER I, I1, II, INDLLD, IP, ITER, J, K, NEGCNT,
$ NEXT, NINT, OLNINT, PREV, R
REAL BACK, CVRGD, GAP, LEFT, LGAP, MID, MNWDTH,
$ RGAP, RIGHT, SAVGAP, TMP, WIDTH
LOGICAL PARANOID
* ..
* .. External Functions ..
LOGICAL SISNAN
REAL SLAMCH
INTEGER SLANEG2A
EXTERNAL SISNAN, SLAMCH,
$ SLANEG2A
*
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, MAX, MIN
* ..
* .. Executable Statements ..
*
INFO = 0
*
* Turn on paranoid check for rounding errors
* invalidating uncertainty intervals of eigenvalues
*
PARANOID = .TRUE.
*
MAXITR = INT( ( LGSPDM - LGPVMN ) / LOG( TWO ) ) + 2
MNWDTH = TWO * PIVMIN
*
R = TWIST
*
INDLLD = 2*N
DO 5 J = 1, N-1
I=2*J
WORK(INDLLD+I-1) = D(J)
WORK(INDLLD+I) = LLD(J)
5 CONTINUE
WORK(INDLLD+2*N-1) = D(N)
*
IF((R.LT.1).OR.(R.GT.N)) R = N
*
* Initialize unconverged intervals in [ WORK(2*I-1), WORK(2*I) ].
* The Sturm Count, Count( WORK(2*I-1) ) is arranged to be I-1, while
* Count( WORK(2*I) ) is stored in IWORK( 2*I ). The integer IWORK( 2*I-1 )
* for an unconverged interval is set to the index of the next unconverged
* interval, and is -1 or 0 for a converged interval. Thus a linked
* list of unconverged intervals is set up.
*
I1 = IFIRST
* The number of unconverged intervals
NINT = 0
* The last unconverged interval found
PREV = 0
RGAP = WGAP( I1-OFFSET )
DO 75 I = I1, ILAST
K = 2*I
II = I - OFFSET
LEFT = W( II ) - WERR( II )
RIGHT = W( II ) + WERR( II )
LGAP = RGAP
RGAP = WGAP( II )
GAP = MIN( LGAP, RGAP )
IF((ABS(LEFT).LE.16*PIVMIN).OR.(ABS(RIGHT).LE.16*PIVMIN))
$ THEN
INFO = -1
RETURN
ENDIF
IF( PARANOID ) THEN
* Make sure that [LEFT,RIGHT] contains the desired eigenvalue
* Compute negcount from dstqds facto L+D+L+^T = L D L^T - LEFT
*
* Do while( NEGCNT(LEFT).GT.I-1 )
*
BACK = WERR( II )
20 CONTINUE
NEGCNT = SLANEG2A( N, WORK(INDLLD+1), LEFT, PIVMIN, R )
IF( NEGCNT.GT.I-1 ) THEN
LEFT = LEFT - BACK
BACK = TWO*BACK
GO TO 20
END IF
*
* Do while( NEGCNT(RIGHT).LT.I )
* Compute negcount from dstqds facto L+D+L+^T = L D L^T - RIGHT
*
BACK = WERR( II )
50 CONTINUE
NEGCNT = SLANEG2A( N, WORK(INDLLD+1),RIGHT, PIVMIN, R )
IF( NEGCNT.LT.I ) THEN
RIGHT = RIGHT + BACK
BACK = TWO*BACK
GO TO 50
END IF
ENDIF
WIDTH = HALF*ABS( LEFT - RIGHT )
TMP = MAX( ABS( LEFT ), ABS( RIGHT ) )
CVRGD = MAX(RTOL1*GAP,RTOL2*TMP)
IF( WIDTH.LE.CVRGD .OR. WIDTH.LE.MNWDTH ) THEN
* This interval has already converged and does not need refinement.
* (Note that the gaps might change through refining the
* eigenvalues, however, they can only get bigger.)
* Remove it from the list.
IWORK( K-1 ) = -1
* Make sure that I1 always points to the first unconverged interval
IF((I.EQ.I1).AND.(I.LT.ILAST)) I1 = I + 1
IF((PREV.GE.I1).AND.(I.LE.ILAST)) IWORK( 2*PREV-1 ) = I + 1
ELSE
* unconverged interval found
PREV = I
NINT = NINT + 1
IWORK( K-1 ) = I + 1
IWORK( K ) = NEGCNT
END IF
WORK( K-1 ) = LEFT
WORK( K ) = RIGHT
75 CONTINUE
*
* Do while( NINT.GT.0 ), i.e. there are still unconverged intervals
* and while (ITER.LT.MAXITR)
*
ITER = 0
80 CONTINUE
PREV = I1 - 1
I = I1
OLNINT = NINT
DO 100 IP = 1, OLNINT
K = 2*I
II = I - OFFSET
RGAP = WGAP( II )
LGAP = RGAP
IF(II.GT.1) LGAP = WGAP( II-1 )
GAP = MIN( LGAP, RGAP )
NEXT = IWORK( K-1 )
LEFT = WORK( K-1 )
RIGHT = WORK( K )
MID = HALF*( LEFT + RIGHT )
* semiwidth of interval
WIDTH = RIGHT - MID
TMP = MAX( ABS( LEFT ), ABS( RIGHT ) )
CVRGD = MAX(RTOL1*GAP,RTOL2*TMP)
IF( ( WIDTH.LE.CVRGD ) .OR. ( WIDTH.LE.MNWDTH ).OR.
$ ( ITER.EQ.MAXITR ) )THEN
* reduce number of unconverged intervals
NINT = NINT - 1
* Mark interval as converged.
IWORK( K-1 ) = 0
IF( I1.EQ.I ) THEN
I1 = NEXT
ELSE
* Prev holds the last unconverged interval previously examined
IF(PREV.GE.I1) IWORK( 2*PREV-1 ) = NEXT
END IF
I = NEXT
GO TO 100
END IF
PREV = I
*
* Perform one bisection step
*
NEGCNT = SLANEG2A( N, WORK(INDLLD+1), MID, PIVMIN, R )
IF( NEGCNT.LE.I-1 ) THEN
WORK( K-1 ) = MID
ELSE
WORK( K ) = MID
END IF
I = NEXT
100 CONTINUE
ITER = ITER + 1
* do another loop if there are still unconverged intervals
* However, in the last iteration, all intervals are accepted
* since this is the best we can do.
IF( ( NINT.GT.0 ).AND.(ITER.LE.MAXITR) ) GO TO 80
*
*
* At this point, all the intervals have converged
*
* save this gap to restore it after the loop
SAVGAP = WGAP( ILAST-OFFSET )
*
LEFT = WORK( 2*IFIRST-1 )
DO 110 I = IFIRST, ILAST
K = 2*I
II = I - OFFSET
* RIGHT is the right boundary of this current interval
RIGHT = WORK( K )
* All intervals marked by '0' have been refined.
IF( IWORK( K-1 ).EQ.0 ) THEN
W( II ) = HALF*( LEFT+RIGHT )
WERR( II ) = RIGHT - W( II )
END IF
* Left is the boundary of the next interval
LEFT = WORK( K +1 )
WGAP( II ) = MAX( ZERO, LEFT - RIGHT )
110 CONTINUE
* restore the last gap which was overwritten by garbage
WGAP( ILAST-OFFSET ) = SAVGAP
RETURN
*
* End of SLARRB2
*
END
*
*
*
FUNCTION SLANEG2( N, D, LLD, SIGMA, PIVMIN, R )
*
IMPLICIT NONE
*
INTEGER SLANEG2
*
* .. Scalar Arguments ..
INTEGER N, R
REAL PIVMIN, SIGMA
* ..
* .. Array Arguments ..
REAL D( * ), LLD( * )
*
REAL ZERO
PARAMETER ( ZERO = 0.0E0 )
INTEGER BLKLEN
PARAMETER ( BLKLEN = 2048 )
* ..
* .. Local Scalars ..
INTEGER BJ, J, NEG1, NEG2, NEGCNT, TO
REAL DMINUS, DPLUS, GAMMA, P, S, T, TMP, XSAV
LOGICAL SAWNAN
* ..
* .. External Functions ..
LOGICAL SISNAN
EXTERNAL SISNAN
NEGCNT = 0
*
* I) upper part: L D L^T - SIGMA I = L+ D+ L+^T
* run dstqds block-wise to avoid excessive work when NaNs occur
*
S = ZERO
DO 210 BJ = 1, R-1, BLKLEN
NEG1 = 0
XSAV = S
TO = BJ+BLKLEN-1
IF ( TO.LE.R-1 ) THEN
DO 21 J = BJ, TO
T = S - SIGMA
DPLUS = D( J ) + T
IF( DPLUS.LT.ZERO ) NEG1=NEG1 + 1
S = T*LLD( J ) / DPLUS
21 CONTINUE
ELSE
DO 22 J = BJ, R-1
T = S - SIGMA
DPLUS = D( J ) + T
IF( DPLUS.LT.ZERO ) NEG1=NEG1 + 1
S = T*LLD( J ) / DPLUS
22 CONTINUE
ENDIF
SAWNAN = SISNAN( S )
*
IF( SAWNAN ) THEN
NEG1 = 0
S = XSAV
TO = BJ+BLKLEN-1
IF ( TO.LE.R-1 ) THEN
DO 23 J = BJ, TO
T = S - SIGMA
DPLUS = D( J ) + T
IF(ABS(DPLUS).LT.PIVMIN)
$ DPLUS = -PIVMIN
TMP = LLD( J ) / DPLUS
IF( DPLUS.LT.ZERO )
$ NEG1 = NEG1 + 1
S = T*TMP
IF( TMP.EQ.ZERO ) S = LLD( J )
23 CONTINUE
ELSE
DO 24 J = BJ, R-1
T = S - SIGMA
DPLUS = D( J ) + T
IF(ABS(DPLUS).LT.PIVMIN)
$ DPLUS = -PIVMIN
TMP = LLD( J ) / DPLUS
IF( DPLUS.LT.ZERO ) NEG1=NEG1+1
S = T*TMP
IF( TMP.EQ.ZERO ) S = LLD( J )
24 CONTINUE
ENDIF
END IF
NEGCNT = NEGCNT + NEG1
210 CONTINUE
*
* II) lower part: L D L^T - SIGMA I = U- D- U-^T
*
P = D( N ) - SIGMA
DO 230 BJ = N-1, R, -BLKLEN
NEG2 = 0
XSAV = P
TO = BJ-BLKLEN+1
IF ( TO.GE.R ) THEN
DO 25 J = BJ, TO, -1
DMINUS = LLD( J ) + P
IF( DMINUS.LT.ZERO ) NEG2=NEG2+1
TMP = P / DMINUS
P = TMP * D( J ) - SIGMA
25 CONTINUE
ELSE
DO 26 J = BJ, R, -1
DMINUS = LLD( J ) + P
IF( DMINUS.LT.ZERO ) NEG2=NEG2+1
TMP = P / DMINUS
P = TMP * D( J ) - SIGMA
26 CONTINUE
ENDIF
SAWNAN = SISNAN( P )
*
IF( SAWNAN ) THEN
NEG2 = 0
P = XSAV
TO = BJ-BLKLEN+1
IF ( TO.GE.R ) THEN
DO 27 J = BJ, TO, -1
DMINUS = LLD( J ) + P
IF(ABS(DMINUS).LT.PIVMIN)
$ DMINUS = -PIVMIN
TMP = D( J ) / DMINUS
IF( DMINUS.LT.ZERO )
$ NEG2 = NEG2 + 1
P = P*TMP - SIGMA
IF( TMP.EQ.ZERO )
$ P = D( J ) - SIGMA
27 CONTINUE
ELSE
DO 28 J = BJ, R, -1
DMINUS = LLD( J ) + P
IF(ABS(DMINUS).LT.PIVMIN)
$ DMINUS = -PIVMIN
TMP = D( J ) / DMINUS
IF( DMINUS.LT.ZERO )
$ NEG2 = NEG2 + 1
P = P*TMP - SIGMA
IF( TMP.EQ.ZERO )
$ P = D( J ) - SIGMA
28 CONTINUE
ENDIF
END IF
NEGCNT = NEGCNT + NEG2
230 CONTINUE
*
* III) Twist index
*
GAMMA = S + P
IF( GAMMA.LT.ZERO ) NEGCNT = NEGCNT+1
SLANEG2 = NEGCNT
END
*
*
*
FUNCTION SLANEG2A( N, DLLD, SIGMA, PIVMIN, R )
*
IMPLICIT NONE
*
INTEGER SLANEG2A
*
* .. Scalar Arguments ..
INTEGER N, R
REAL PIVMIN, SIGMA
* ..
* .. Array Arguments ..
REAL DLLD( * )
*
REAL ZERO
PARAMETER ( ZERO = 0.0E0 )
INTEGER BLKLEN
PARAMETER ( BLKLEN = 512 )
*
* ..
* .. Intrinsic Functions ..
INTRINSIC INT
* ..
* .. Local Scalars ..
INTEGER BJ, I, J, NB, NEG1, NEG2, NEGCNT, NX
REAL DMINUS, DPLUS, GAMMA, P, S, T, TMP, XSAV
LOGICAL SAWNAN
* ..
* .. External Functions ..
LOGICAL SISNAN
EXTERNAL SISNAN
NEGCNT = 0
*
* I) upper part: L D L^T - SIGMA I = L+ D+ L+^T
* run dstqds block-wise to avoid excessive work when NaNs occur,
* first in chunks of size BLKLEN and then the remainder
*
NB = INT((R-1)/BLKLEN)
NX = NB*BLKLEN
S = ZERO
DO 210 BJ = 1, NX, BLKLEN
NEG1 = 0
XSAV = S
DO 21 J = BJ, BJ+BLKLEN-1
I = 2*J
T = S - SIGMA
DPLUS = DLLD( I-1 ) + T
IF( DPLUS.LT.ZERO ) NEG1=NEG1 + 1
S = T*DLLD( I ) / DPLUS
21 CONTINUE
SAWNAN = SISNAN( S )
*
IF( SAWNAN ) THEN
NEG1 = 0
S = XSAV
DO 23 J = BJ, BJ+BLKLEN-1
I = 2*J
T = S - SIGMA
DPLUS = DLLD( I-1 ) + T
IF(ABS(DPLUS).LT.PIVMIN)
$ DPLUS = -PIVMIN
TMP = DLLD( I ) / DPLUS
IF( DPLUS.LT.ZERO )
$ NEG1 = NEG1 + 1
S = T*TMP
IF( TMP.EQ.ZERO ) S = DLLD( I )
23 CONTINUE
END IF
NEGCNT = NEGCNT + NEG1
210 CONTINUE
*
NEG1 = 0
XSAV = S
DO 22 J = NX+1, R-1
I = 2*J
T = S - SIGMA
DPLUS = DLLD( I-1 ) + T
IF( DPLUS.LT.ZERO ) NEG1=NEG1 + 1
S = T*DLLD( I ) / DPLUS
22 CONTINUE
SAWNAN = SISNAN( S )
*
IF( SAWNAN ) THEN
NEG1 = 0
S = XSAV
DO 24 J = NX+1, R-1
I = 2*J
T = S - SIGMA
DPLUS = DLLD( I-1 ) + T
IF(ABS(DPLUS).LT.PIVMIN)
$ DPLUS = -PIVMIN
TMP = DLLD( I ) / DPLUS
IF( DPLUS.LT.ZERO ) NEG1=NEG1+1
S = T*TMP
IF( TMP.EQ.ZERO ) S = DLLD( I )
24 CONTINUE
ENDIF
NEGCNT = NEGCNT + NEG1
*
* II) lower part: L D L^T - SIGMA I = U- D- U-^T
*
NB = INT((N-R)/BLKLEN)
NX = N-NB*BLKLEN
P = DLLD( 2*N-1 ) - SIGMA
DO 230 BJ = N-1, NX, -BLKLEN
NEG2 = 0
XSAV = P
DO 25 J = BJ, BJ-BLKLEN+1, -1
I = 2*J
DMINUS = DLLD( I ) + P
IF( DMINUS.LT.ZERO ) NEG2=NEG2+1
TMP = P / DMINUS
P = TMP * DLLD( I-1 ) - SIGMA
25 CONTINUE
SAWNAN = SISNAN( P )
*
IF( SAWNAN ) THEN
NEG2 = 0
P = XSAV
DO 27 J = BJ, BJ-BLKLEN+1, -1
I = 2*J
DMINUS = DLLD( I ) + P
IF(ABS(DMINUS).LT.PIVMIN)
$ DMINUS = -PIVMIN
TMP = DLLD( I-1 ) / DMINUS
IF( DMINUS.LT.ZERO )
$ NEG2 = NEG2 + 1
P = P*TMP - SIGMA
IF( TMP.EQ.ZERO )
$ P = DLLD( I-1 ) - SIGMA
27 CONTINUE
END IF
NEGCNT = NEGCNT + NEG2
230 CONTINUE
NEG2 = 0
XSAV = P
DO 26 J = NX-1, R, -1
I = 2*J
DMINUS = DLLD( I ) + P
IF( DMINUS.LT.ZERO ) NEG2=NEG2+1
TMP = P / DMINUS
P = TMP * DLLD( I-1 ) - SIGMA
26 CONTINUE
SAWNAN = SISNAN( P )
*
IF( SAWNAN ) THEN
NEG2 = 0
P = XSAV
DO 28 J = NX-1, R, -1
I = 2*J
DMINUS = DLLD( I ) + P
IF(ABS(DMINUS).LT.PIVMIN)
$ DMINUS = -PIVMIN
TMP = DLLD( I-1 ) / DMINUS
IF( DMINUS.LT.ZERO )
$ NEG2 = NEG2 + 1
P = P*TMP - SIGMA
IF( TMP.EQ.ZERO )
$ P = DLLD( I-1 ) - SIGMA
28 CONTINUE
END IF
NEGCNT = NEGCNT + NEG2
*
* III) Twist index
*
GAMMA = S + P
IF( GAMMA.LT.ZERO ) NEGCNT = NEGCNT+1
SLANEG2A = NEGCNT
END
|
