1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
|
SUBROUTINE CASYMV( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
$ INCY )
*
* -- PBLAS auxiliary routine (version 2.0) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* April 1, 1998
*
* .. Scalar Arguments ..
CHARACTER*1 UPLO
INTEGER INCX, INCY, LDA, N
REAL ALPHA, BETA
* ..
* .. Array Arguments ..
REAL Y( * )
COMPLEX A( LDA, * ), X( * )
* ..
*
* Purpose
* =======
*
* CASYMV performs the following matrix-vector operation
*
* y := abs( alpha )*abs( A )*abs( x )+ abs( beta*y ),
*
* where alpha and beta are real scalars, y is a real vector, x is a
* vector and A is an n by n symmetric matrix.
*
* Arguments
* =========
*
* UPLO (input) CHARACTER*1
* On entry, UPLO specifies whether the upper or lower triangu-
* lar part of the array A is to be referenced as follows:
*
* UPLO = 'U' or 'u' Only the upper triangular part of A is
* to be referenced.
* UPLO = 'L' or 'l' Only the lower triangular part of A is
* to be referenced.
*
* N (input) INTEGER
* On entry, N specifies the order of the matrix A. N must be at
* least zero.
*
* ALPHA (input) REAL
* On entry, ALPHA specifies the real scalar alpha.
*
* A (input) COMPLEX array
* On entry, A is an array of dimension (LDA,N). Before entry
* with UPLO = 'U' or 'u', the leading n by n part of the array
* A must contain the upper triangular part of the symmetric ma-
* trix and the strictly lower triangular part of A is not refe-
* renced. When UPLO = 'L' or 'l', the leading n by n part of
* the array A must contain the lower triangular part of the
* symmetric matrix and the strictly upper trapezoidal part of A
* is not referenced.
*
* LDA (input) INTEGER
* On entry, LDA specifies the leading dimension of the array A.
* LDA must be at least max( 1, N ).
*
* X (input) COMPLEX array of dimension at least
* ( 1 + ( n - 1 )*abs( INCX ) ). Before entry, the incremented
* array X must contain the vector x.
*
* INCX (input) INTEGER
* On entry, INCX specifies the increment for the elements of X.
* INCX must not be zero.
*
* BETA (input) REAL
* On entry, BETA specifies the real scalar beta. When BETA is
* supplied as zero then Y need not be set on input.
*
* Y (input/output) REAL array of dimension at least
* ( 1 + ( n - 1 )*abs( INCY ) ). Before entry with BETA non-
* zero, the incremented array Y must contain the vector y. On
* exit, the incremented array Y is overwritten by the updated
* vector y.
*
* INCY (input) INTEGER
* On entry, INCY specifies the increment for the elements of Y.
* INCY must not be zero.
*
* -- Written on April 1, 1998 by
* Antoine Petitet, University of Tennessee, Knoxville 37996, USA.
*
* =====================================================================
*
* .. Parameters ..
REAL ONE, ZERO
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
* ..
* .. Local Scalars ..
INTEGER I, INFO, IX, IY, J, JX, JY, KX, KY
REAL TALPHA, TEMP0, TEMP1, TEMP2
COMPLEX ZDUM
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. External Subroutines ..
EXTERNAL XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, AIMAG, MAX, REAL
* ..
* .. Statement Functions ..
REAL CABS1
CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
* ..
* .. Executable Statements ..
*
* Test the input parameters.
*
INFO = 0
IF ( .NOT.LSAME( UPLO, 'U' ).AND.
$ .NOT.LSAME( UPLO, 'L' ) )THEN
INFO = 1
ELSE IF( N.LT.0 )THEN
INFO = 2
ELSE IF( LDA.LT.MAX( 1, N ) )THEN
INFO = 5
ELSE IF( INCX.EQ.0 )THEN
INFO = 7
ELSE IF( INCY.EQ.0 )THEN
INFO = 10
END IF
IF( INFO.NE.0 )THEN
CALL XERBLA( 'CASYMV', INFO )
RETURN
END IF
*
* Quick return if possible.
*
IF( ( N.EQ.0 ).OR.( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
$ RETURN
*
* Set up the start points in X and Y.
*
IF( INCX.GT.0 ) THEN
KX = 1
ELSE
KX = 1 - ( N - 1 ) * INCX
END IF
IF( INCY.GT.0 )THEN
KY = 1
ELSE
KY = 1 - ( N - 1 ) * INCY
END IF
*
* Start the operations. In this version the elements of A are
* accessed sequentially with one pass through the triangular part
* of A.
*
* First form y := abs( beta * y ).
*
IF( BETA.NE.ONE ) THEN
IF( INCY.EQ.1 ) THEN
IF( BETA.EQ.ZERO ) THEN
DO 10, I = 1, N
Y( I ) = ZERO
10 CONTINUE
ELSE
DO 20, I = 1, N
Y( I ) = ABS( BETA * Y( I ) )
20 CONTINUE
END IF
ELSE
IY = KY
IF( BETA.EQ.ZERO ) THEN
DO 30, I = 1, N
Y( IY ) = ZERO
IY = IY + INCY
30 CONTINUE
ELSE
DO 40, I = 1, N
Y( IY ) = ABS( BETA * Y( IY ) )
IY = IY + INCY
40 CONTINUE
END IF
END IF
END IF
*
IF( ALPHA.EQ.ZERO )
$ RETURN
*
TALPHA = ABS( ALPHA )
*
IF( LSAME( UPLO, 'U' ) ) THEN
*
* Form y when A is stored in upper triangle.
*
IF( ( INCX.EQ.1 ).AND.( INCY.EQ.1 ) ) THEN
DO 60, J = 1, N
TEMP1 = TALPHA * CABS1( X( J ) )
TEMP2 = ZERO
DO 50, I = 1, J - 1
TEMP0 = CABS1( A( I, J ) )
Y( I ) = Y( I ) + TEMP1 * TEMP0
TEMP2 = TEMP2 + TEMP0 * CABS1( X( I ) )
50 CONTINUE
Y( J ) = Y( J ) + TEMP1 * CABS1( A( J, J ) ) +
$ ALPHA * TEMP2
*
60 CONTINUE
*
ELSE
*
JX = KX
JY = KY
*
DO 80, J = 1, N
TEMP1 = TALPHA * CABS1( X( JX ) )
TEMP2 = ZERO
IX = KX
IY = KY
*
DO 70, I = 1, J - 1
TEMP0 = CABS1( A( I, J ) )
Y( IY ) = Y( IY ) + TEMP1 * TEMP0
TEMP2 = TEMP2 + TEMP0 * CABS1( X( IX ) )
IX = IX + INCX
IY = IY + INCY
70 CONTINUE
Y( JY ) = Y( JY ) + TEMP1 * CABS1( A( J, J ) ) +
$ ALPHA * TEMP2
JX = JX + INCX
JY = JY + INCY
*
80 CONTINUE
*
END IF
*
ELSE
*
* Form y when A is stored in lower triangle.
*
IF( ( INCX.EQ.1 ).AND.( INCY.EQ.1 ) ) THEN
*
DO 100, J = 1, N
*
TEMP1 = TALPHA * CABS1( X( J ) )
TEMP2 = ZERO
Y( J ) = Y( J ) + TEMP1 * CABS1( A( J, J ) )
*
DO 90, I = J + 1, N
TEMP0 = CABS1( A( I, J ) )
Y( I ) = Y( I ) + TEMP1 * TEMP0
TEMP2 = TEMP2 + TEMP0 * CABS1( X( I ) )
*
90 CONTINUE
*
Y( J ) = Y( J ) + ALPHA * TEMP2
*
100 CONTINUE
*
ELSE
*
JX = KX
JY = KY
*
DO 120, J = 1, N
TEMP1 = TALPHA * CABS1( X( JX ) )
TEMP2 = ZERO
Y( JY ) = Y( JY ) + TEMP1 * CABS1( A( J, J ) )
IX = JX
IY = JY
*
DO 110, I = J + 1, N
*
IX = IX + INCX
IY = IY + INCY
TEMP0 = CABS1( A( I, J ) )
Y( IY ) = Y( IY ) + TEMP1 * TEMP0
TEMP2 = TEMP2 + TEMP0 * CABS1( X( IX ) )
*
110 CONTINUE
*
Y( JY ) = Y( JY ) + ALPHA * TEMP2
JX = JX + INCX
JY = JY + INCY
*
120 CONTINUE
*
END IF
*
END IF
*
RETURN
*
* End of CASYMV
*
END
|
