1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
|
SUBROUTINE CHESCAL( UPLO, M, N, IOFFD, ALPHA, A, LDA )
*
* -- PBLAS auxiliary routine (version 2.0) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* April 1, 1998
*
* .. Scalar Arguments ..
CHARACTER*1 UPLO
INTEGER IOFFD, LDA, M, N
REAL ALPHA
* ..
* .. Array Arguments ..
COMPLEX A( LDA, * )
* ..
*
* Purpose
* =======
*
* CHESCAL scales a two-dimensional array A by the real scalar alpha.
* The diagonal entries specified by IOFFD of A are supposed to be real.
*
* Arguments
* =========
*
* UPLO (input) CHARACTER*1
* On entry, UPLO specifies which trapezoidal part of the ar-
* ray A is to be scaled as follows:
* = 'L' or 'l': the lower trapezoid of A is scaled,
* = 'U' or 'u': the upper trapezoid of A is scaled,
* = 'D' or 'd': diagonal specified by IOFFD is scaled,
* Otherwise: all of the array A is scaled.
*
* M (input) INTEGER
* On entry, M specifies the number of rows of the array A. M
* must be at least zero.
*
* N (input) INTEGER
* On entry, N specifies the number of columns of the array A.
* N must be at least zero.
*
* IOFFD (input) INTEGER
* On entry, IOFFD specifies the position of the offdiagonal de-
* limiting the upper and lower trapezoidal part of A as follows
* (see the notes below):
*
* IOFFD = 0 specifies the main diagonal A( i, i ),
* with i = 1 ... MIN( M, N ),
* IOFFD > 0 specifies the subdiagonal A( i+IOFFD, i ),
* with i = 1 ... MIN( M-IOFFD, N ),
* IOFFD < 0 specifies the superdiagonal A( i, i-IOFFD ),
* with i = 1 ... MIN( M, N+IOFFD ).
*
* ALPHA (input) REAL
* On entry, ALPHA specifies the scalar alpha, i.e., the value
* by which the diagonal and offdiagonal entries of the array A
* as specified by UPLO and IOFFD are scaled.
*
* A (input/output) COMPLEX array
* On entry, A is an array of dimension (LDA,N). Before entry
* with UPLO = 'U' or 'u', the leading m by n part of the array
* A must contain the upper trapezoidal part of the Hermitian
* matrix to be scaled as specified by IOFFD, and the strictly
* lower trapezoidal part of A is not referenced. When UPLO is
* 'L' or 'l', the leading m by n part of the array A must con-
* tain the lower trapezoidal part of the Hermitian matrix to be
* scaled as specified by IOFFD, and the strictly upper trape-
* zoidal part of A is not referenced. On exit, the entries of
* the trapezoid part of A determined by UPLO and IOFFD are sca-
* led.
*
* LDA (input) INTEGER
* On entry, LDA specifies the leading dimension of the array A.
* LDA must be at least max( 1, M ).
*
* Notes
* =====
* N N
* ---------------------------- -----------
* | d | | |
* M | d 'U' | | 'U' |
* | 'L' 'D' | |d |
* | d | M | d |
* ---------------------------- | 'D' |
* | d |
* IOFFD < 0 | 'L' d |
* | d|
* N | |
* ----------- -----------
* | d 'U'|
* | d | IOFFD > 0
* M | 'D' |
* | d| N
* | 'L' | ----------------------------
* | | | 'U' |
* | | |d |
* | | | 'D' |
* | | | d |
* | | |'L' d |
* ----------- ----------------------------
*
* -- Written on April 1, 1998 by
* Antoine Petitet, University of Tennessee, Knoxville 37996, USA.
*
* =====================================================================
*
* .. Parameters ..
REAL RONE, RZERO
PARAMETER ( RONE = 1.0E+0, RZERO = 0.0E+0 )
COMPLEX ZERO
PARAMETER ( ZERO = ( 0.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
INTEGER J, JTMP, MN
* ..
* .. External Subroutines ..
EXTERNAL CSSCAL, CTZPAD
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. Intrinsic Functions ..
INTRINSIC CMPLX, MAX, MIN, REAL
* ..
* .. Executable Statements ..
*
* Quick return if possible
*
IF( M.LE.0 .OR. N.LE.0 )
$ RETURN
*
* Start the operations
*
IF( ALPHA.EQ.RONE ) THEN
*
* Zeros the imaginary part of the diagonals
*
IF( LSAME( UPLO, 'L' ).OR.LSAME( UPLO, 'U' ).OR.
$ LSAME( UPLO, 'D' ) ) THEN
DO 10 J = MAX( 0, -IOFFD ) + 1, MIN( M - IOFFD, N )
JTMP = J + IOFFD
A( JTMP, J ) = CMPLX( REAL( A( JTMP, J ) ), RZERO )
10 CONTINUE
END IF
RETURN
ELSE IF( ALPHA.EQ.RZERO ) THEN
CALL CTZPAD( UPLO, 'N', M, N, IOFFD, ZERO, ZERO, A, LDA )
RETURN
END IF
*
IF( LSAME( UPLO, 'L' ) ) THEN
*
* Scales the lower triangular part of the array by ALPHA.
*
MN = MAX( 0, -IOFFD )
DO 20 J = 1, MIN( MN, N )
CALL CSSCAL( M, ALPHA, A( 1, J ), 1 )
20 CONTINUE
DO 30 J = MN + 1, MIN( M - IOFFD, N )
JTMP = J + IOFFD
A( JTMP, J ) = CMPLX( ALPHA * REAL( A( JTMP, J ) ), RZERO )
IF( M.GT.JTMP )
$ CALL CSSCAL( M-JTMP, ALPHA, A( JTMP + 1, J ), 1 )
30 CONTINUE
*
ELSE IF( LSAME( UPLO, 'U' ) ) THEN
*
* Scales the upper triangular part of the array by ALPHA.
*
MN = MIN( M - IOFFD, N )
DO 40 J = MAX( 0, -IOFFD ) + 1, MN
JTMP = J + IOFFD
CALL CSSCAL( JTMP - 1, ALPHA, A( 1, J ), 1 )
A( JTMP, J ) = CMPLX( ALPHA * REAL( A( JTMP, J ) ), RZERO )
40 CONTINUE
DO 50 J = MAX( 0, MN ) + 1, N
CALL CSSCAL( M, ALPHA, A( 1, J ), 1 )
50 CONTINUE
*
ELSE IF( LSAME( UPLO, 'D' ) ) THEN
*
* Scales the diagonal entries by ALPHA.
*
DO 60 J = MAX( 0, -IOFFD ) + 1, MIN( M - IOFFD, N )
JTMP = J + IOFFD
A( JTMP, J ) = CMPLX( ALPHA * REAL( A( JTMP, J ) ), RZERO )
60 CONTINUE
*
ELSE
*
* Scales the entire array by ALPHA.
*
DO 70 J = 1, N
CALL CSSCAL( M, ALPHA, A( 1, J ), 1 )
70 CONTINUE
*
END IF
*
RETURN
*
* End of CHESCAL
*
END
|
