1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
|
SUBROUTINE PZMAX1( N, AMAX, INDX, X, IX, JX, DESCX, INCX )
*
* -- ScaLAPACK auxiliary routine (version 1.7) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* May 1, 1997
*
* .. Scalar Arguments ..
INTEGER INDX, INCX, IX, JX, N
COMPLEX*16 AMAX
* ..
* .. Array Arguments ..
INTEGER DESCX( * )
COMPLEX*16 X( * )
* ..
*
* Purpose
* =======
*
* PZMAX1 computes the global index of the maximum element in absolute
* value of a distributed vector sub( X ). The global index is returned
* in INDX and the value is returned in AMAX,
*
* where sub( X ) denotes X(IX:IX+N-1,JX) if INCX = 1,
* X(IX,JX:JX+N-1) if INCX = M_X.
*
* Notes
* =====
*
* Each global data object is described by an associated description
* vector. This vector stores the information required to establish
* the mapping between an object element and its corresponding process
* and memory location.
*
* Let A be a generic term for any 2D block cyclicly distributed array.
* Such a global array has an associated description vector DESCA.
* In the following comments, the character _ should be read as
* "of the global array".
*
* NOTATION STORED IN EXPLANATION
* --------------- -------------- --------------------------------------
* DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
* DTYPE_A = 1.
* CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
* the BLACS process grid A is distribu-
* ted over. The context itself is glo-
* bal, but the handle (the integer
* value) may vary.
* M_A (global) DESCA( M_ ) The number of rows in the global
* array A.
* N_A (global) DESCA( N_ ) The number of columns in the global
* array A.
* MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
* the rows of the array.
* NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
* the columns of the array.
* RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
* row of the array A is distributed.
* CSRC_A (global) DESCA( CSRC_ ) The process column over which the
* first column of the array A is
* distributed.
* LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
* array. LLD_A >= MAX(1,LOCr(M_A)).
*
* Let K be the number of rows or columns of a distributed matrix,
* and assume that its process grid has dimension p x q.
* LOCr( K ) denotes the number of elements of K that a process
* would receive if K were distributed over the p processes of its
* process column.
* Similarly, LOCc( K ) denotes the number of elements of K that a
* process would receive if K were distributed over the q processes of
* its process row.
* The values of LOCr() and LOCc() may be determined via a call to the
* ScaLAPACK tool function, NUMROC:
* LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
* LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
* An upper bound for these quantities may be computed by:
* LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
* LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
* Because vectors may be viewed as a subclass of matrices, a
* distributed vector is considered to be a distributed matrix.
*
* When the result of a vector-oriented PBLAS call is a scalar, it will
* be made available only within the scope which owns the vector(s)
* being operated on. Let X be a generic term for the input vector(s).
* Then, the processes which receive the answer will be (note that if
* an operation involves more than one vector, the processes which re-
* ceive the result will be the union of the following calculation for
* each vector):
*
* If N = 1, M_X = 1 and INCX = 1, then one can't determine if a process
* row or process column owns the vector operand, therefore only the
* process of coordinate {RSRC_X, CSRC_X} receives the result;
*
* If INCX = M_X, then sub( X ) is a vector distributed over a process
* row. Each process part of this row receives the result;
*
* If INCX = 1, then sub( X ) is a vector distributed over a process
* column. Each process part of this column receives the result;
*
* Based on PZAMAX from Level 1 PBLAS. The change is to use the
* 'genuine' absolute value.
*
* The serial version was contributed to LAPACK by Nick Higham for use
* with ZLACON.
*
* Arguments
* =========
*
* N (global input) pointer to INTEGER
* The number of components of the distributed vector sub( X ).
* N >= 0.
*
* AMAX (global output) pointer to DOUBLE PRECISION
* The absolute value of the largest entry of the distributed
* vector sub( X ) only in the scope of sub( X ).
*
* INDX (global output) pointer to INTEGER
* The global index of the element of the distributed vector
* sub( X ) whose real part has maximum absolute value.
*
* X (local input) COMPLEX*16 array containing the local
* pieces of a distributed matrix of dimension of at least
* ( (JX-1)*M_X + IX + ( N - 1 )*abs( INCX ) )
* This array contains the entries of the distributed vector
* sub( X ).
*
* IX (global input) INTEGER
* The row index in the global array X indicating the first
* row of sub( X ).
*
* JX (global input) INTEGER
* The column index in the global array X indicating the
* first column of sub( X ).
*
* DESCX (global and local input) INTEGER array of dimension DLEN_.
* The array descriptor for the distributed matrix X.
*
* INCX (global input) INTEGER
* The global increment for the elements of X. Only two values
* of INCX are supported in this version, namely 1 and M_X.
* INCX must not be zero.
*
* =====================================================================
*
* .. Parameters ..
INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
$ LLD_, MB_, M_, NB_, N_, RSRC_
PARAMETER ( BLOCK_CYCLIC_2D = 1, DLEN_ = 9, DTYPE_ = 1,
$ CTXT_ = 2, M_ = 3, N_ = 4, MB_ = 5, NB_ = 6,
$ RSRC_ = 7, CSRC_ = 8, LLD_ = 9 )
COMPLEX*16 ZERO
PARAMETER ( ZERO = ( 0.0D+0, 0.0D+0 ) )
* ..
* .. Local Scalars ..
CHARACTER CBTOP, CCTOP, RBTOP, RCTOP
INTEGER ICOFF, ICTXT, IDUMM, IIX, IROFF, IXCOL, IXROW,
$ JJX, LCINDX, LDX, MAXPOS, MYCOL, MYROW, NP,
$ NPCOL, NPROW, NQ
* ..
* .. Local Arrays ..
COMPLEX*16 WORK( 2 )
* ..
* .. External Subroutines ..
EXTERNAL BLACS_GRIDINFO, IGEBR2D, IGEBS2D, INFOG2L,
$ PB_TOPGET, PZTREECOMB, ZCOMBAMAX1, ZGAMX2D
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER IZMAX1, INDXL2G, NUMROC
EXTERNAL IZMAX1, INDXL2G, NUMROC
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, DBLE, DCMPLX, MOD, NINT
* ..
* .. Executable Statements ..
*
* Get grid parameters
*
ICTXT = DESCX( CTXT_ )
CALL BLACS_GRIDINFO( ICTXT, NPROW, NPCOL, MYROW, MYCOL )
*
* Quick return if possible.
*
INDX = 0
AMAX = ZERO
IF( N.LE.0 )
$ RETURN
*
* Retrieve local information for vector X.
*
LDX = DESCX( LLD_ )
CALL INFOG2L( IX, JX, DESCX, NPROW, NPCOL, MYROW, MYCOL, IIX, JJX,
$ IXROW, IXCOL )
*
IF( INCX.EQ.1 .AND. DESCX( M_ ).EQ.1 .AND. N.EQ.1 ) THEN
INDX = JX
AMAX = X( IIX+(JJX-1)*LDX )
RETURN
END IF
*
* Find the maximum value and its index
*
IF( INCX.EQ.DESCX( M_ ) ) THEN
*
IF( MYROW.EQ.IXROW ) THEN
*
ICOFF = MOD( JX-1, DESCX( NB_ ) )
NQ = NUMROC( N+ICOFF, DESCX( NB_ ), MYCOL, IXCOL, NPCOL )
IF( MYCOL.EQ.IXCOL )
$ NQ = NQ-ICOFF
*
CALL PB_TOPGET( ICTXT, 'Broadcast', 'Rowwise', RBTOP )
*
IF( LSAME( RBTOP, ' ' ) ) THEN
*
IF( NQ.GT.0 ) THEN
LCINDX = JJX-1+IZMAX1( NQ, X( IIX+(JJX-1)*LDX ), LDX )
WORK( 1 ) = X( IIX+(LCINDX-1)*LDX )
WORK( 2 ) = DCMPLX( DBLE( INDXL2G( LCINDX,
$ DESCX( NB_ ), MYCOL, DESCX( CSRC_ ), NPCOL ) ) )
ELSE
WORK( 1 ) = ZERO
WORK( 2 ) = ZERO
END IF
*
CALL PZTREECOMB( ICTXT, 'Row', 2, WORK, -1, MYCOL,
$ ZCOMBAMAX1 )
*
AMAX = WORK( 1 )
IF( AMAX.EQ.ZERO ) THEN
INDX = JX
ELSE
INDX = NINT( DBLE( WORK( 2 ) ) )
END IF
*
ELSE
*
CALL PB_TOPGET( ICTXT, 'Combine', 'Rowwise', RCTOP )
*
IF( NQ.GT.0 ) THEN
LCINDX = JJX-1+IZMAX1( NQ, X( IIX+(JJX-1)*LDX ), LDX )
AMAX = X( IIX + (LCINDX-1)*LDX )
ELSE
AMAX = ZERO
END IF
*
* Find the maximum value
*
CALL ZGAMX2D( ICTXT, 'Rowwise', RCTOP, 1, 1, AMAX, 1,
$ IDUMM, MAXPOS, 1, -1, MYROW )
*
IF( AMAX.NE.ZERO ) THEN
*
* Broadcast corresponding global index
*
IF( MYCOL.EQ.MAXPOS ) THEN
INDX = INDXL2G( LCINDX, DESCX( NB_ ), MYCOL,
$ DESCX( CSRC_ ), NPCOL )
CALL IGEBS2D( ICTXT, 'Rowwise', RBTOP, 1, 1, INDX,
$ 1 )
ELSE
CALL IGEBR2D( ICTXT, 'Rowwise', RBTOP, 1, 1, INDX,
$ 1, MYROW, MAXPOS )
END IF
*
ELSE
*
INDX = JX
*
END IF
*
END IF
*
END IF
*
ELSE
*
IF( MYCOL.EQ.IXCOL ) THEN
*
IROFF = MOD( IX-1, DESCX( MB_ ) )
NP = NUMROC( N+IROFF, DESCX( MB_ ), MYROW, IXROW, NPROW )
IF( MYROW.EQ.IXROW )
$ NP = NP-IROFF
*
CALL PB_TOPGET( ICTXT, 'Broadcast', 'Columnwise', CBTOP )
*
IF( LSAME( CBTOP, ' ' ) ) THEN
*
IF( NP.GT.0 ) THEN
LCINDX = IIX-1+IZMAX1( NP, X( IIX+(JJX-1)*LDX ), 1 )
WORK( 1 ) = X( LCINDX + (JJX-1)*LDX )
WORK( 2 ) = DCMPLX( DBLE( INDXL2G( LCINDX,
$ DESCX( MB_ ), MYROW, DESCX( RSRC_ ), NPROW ) ) )
ELSE
WORK( 1 ) = ZERO
WORK( 2 ) = ZERO
END IF
*
CALL PZTREECOMB( ICTXT, 'Column', 2, WORK, -1, MYCOL,
$ ZCOMBAMAX1 )
*
AMAX = WORK( 1 )
IF( AMAX.EQ.ZERO ) THEN
INDX = IX
ELSE
INDX = NINT( DBLE( WORK( 2 ) ) )
END IF
*
ELSE
*
CALL PB_TOPGET( ICTXT, 'Combine', 'Columnwise', CCTOP )
*
IF( NP.GT.0 ) THEN
LCINDX = IIX-1+IZMAX1( NP, X( IIX+(JJX-1)*LDX ), 1 )
AMAX = X( LCINDX + (JJX-1)*LDX )
ELSE
AMAX = ZERO
END IF
*
* Find the maximum value
*
CALL ZGAMX2D( ICTXT, 'Columnwise', CCTOP, 1, 1, AMAX, 1,
$ MAXPOS, IDUMM, 1, -1, MYCOL )
*
IF( AMAX.NE.ZERO ) THEN
*
* Broadcast corresponding global index
*
IF( MYROW.EQ.MAXPOS ) THEN
INDX = INDXL2G( LCINDX, DESCX( MB_ ), MYROW,
$ DESCX( RSRC_ ), NPROW )
CALL IGEBS2D( ICTXT, 'Columnwise', CBTOP, 1, 1,
$ INDX, 1 )
ELSE
CALL IGEBR2D( ICTXT, 'Columnwise', CBTOP, 1, 1,
$ INDX, 1, MAXPOS, MYCOL )
END IF
*
ELSE
*
INDX = IX
*
END IF
*
END IF
*
END IF
*
END IF
*
RETURN
*
* End of PZMAX1
*
END
*
SUBROUTINE ZCOMBAMAX1 ( V1, V2 )
*
* -- ScaLAPACK auxiliary routine (version 1.7) --
* University of Tennessee, Knoxville, Oak Ridge National Laboratory,
* and University of California, Berkeley.
* May 1, 1997
*
* .. Array Arguments ..
COMPLEX*16 V1( 2 ), V2( 2 )
* ..
*
* Purpose
* =======
*
* ZCOMBAMAX1 finds the element having maximum real part absolute
* value as well as its corresponding globl index.
*
* Arguments
* =========
*
* V1 (local input/local output) COMPLEX*16 array of
* dimension 2. The first maximum absolute value element and
* its global index. V1(1) = AMAX, V1(2) = INDX.
*
* V2 (local input) COMPLEX*16 array of dimension 2.
* The second maximum absolute value element and its global
* index. V2(1) = AMAX, V2(2) = INDX.
*
* =====================================================================
*
* .. Intrinsic Functions ..
INTRINSIC ABS, DBLE
* ..
* .. Executable Statements ..
*
IF( ABS( DBLE( V1( 1 ) ) ).LT.ABS( DBLE( V2( 1 ) ) ) ) THEN
V1( 1 ) = V2( 1 )
V1( 2 ) = V2( 2 )
END IF
*
RETURN
*
* End of ZCOMBAMAX1
*
END
|
