1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
// Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
// Copyright (C) 2008 - INRIA
// Copyright (C) 2009 - DIGITEO - Allan CORNET
//
// This file must be used under the terms of the CeCILL.
// This source file is licensed as described in the file COPYING, which
// you should have received as part of this distribution. The terms
// are also available at
// http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
function write_csv(var, fname, sep, dec)
// var : a matrix of numbers or a matrix of strings
// fname : a character string, the path of the file to create
// sep : the column separator mark, a tab by default
// dec : the decimal mark . or ,
// Example
// a = rand(3,5);
// write_csv(a,'/tmp/foo.txt',sep=',')
if exists('sep','local') == 0 then
sep = ascii(9);
end
if exists('dec','local') == 0 then
dec = ',';
end
if ( (type(var) <> 10) & (type(var) <> 1) ) then
error(msprintf(gettext("%s: Wrong type for input argument #%d: ''%s'' or ''%s'' expected.\n"), 'write_csv', 1, 'real', 'string'));
end
if (type(fname) <> 10) then
error(msprintf(gettext("%s: Wrong type for input argument #%d: a string expected.\n"), 'write_csv', 2));
end
if (size(fname,'*')<> 1) then
error(msprintf(gettext("%s: Wrong size for input argument #%d: a string expected.\n"), 'write_csv', 2));
end
if (type(dec) <> 10) then
error(msprintf(gettext("%s: Wrong type for input argument #%d: a string expected.\n"), 'write_csv', 3));
end
if (size(dec,'*')<> 1) then
error(msprintf(gettext("%s: Wrong size for input argument #%d: a string expected.\n"), 'write_csv', 3));
end
if dec <> ['.',','] then
error(msprintf(gettext("%s: Wrong value for input argument #%d: ''%s'' or ''%s'' expected.\n"), 'write_csv', 3, '.', ','));
end
if type(var) == 1 then
var = string(var);
if dec <> '.' then
var = strsubst(var,'.',',');
end
end
t = var(:, 1);
for k=2:size(var, 2)
t = t + sep + var(:, k);
end
mputl(t,fname);
endfunction
|
