1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
#!/bin/sh
#
# ad2c : Convert app-defaults file to C strings decls.
#
# George Ferguson, ferguson@cs.rcohester.edu, 12 Nov 1990.
# 19 Mar 1991: gf
# Made it self-contained.
# 6 Jan 1992: mycroft@gnu.ai.mit.edu (Charles Hannum)
# Removed use of "-n" and ":read" label since Gnu and
# IBM sed print pattern space on "n" command. Still works
# with Sun sed, of course.
# 7 Jan 1992: matthew@sunpix.East.Sun.COM (Matthew Stier)
# Escape quotes after escaping backslashes.
# 8 Jul 1992: Version 1.6
#
sed '
# remove comments
/^!/d
# remove blanks
/^$/d
# escape backslash
s/\\/\\\\/g
# except the line continuation ones
s/\\$//g
# escape quotes
s/"/\\"/g
# add leading quote
s/^/"/
#
: test
/\\$/b slash
s/$/",/
p
d
#
: slash
n
# just like "read" only does not add leading quote
/^!/d
/^$/d
s/"/\\"/g
s/\\\\/\\/g
s/\\n/\\\\n/g
s/\\t/\\\\t/g
s/\\f/\\\\f/g
s/\\b/\\\\b/g
b test' "$@"
|
