1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
# Configure template for GNU shar utilities. -*- Mode: M4 -*-
# Copyright (C) 1994-2015 Free Software Foundation, Inc.
# Process this file with autoconf to produce a configure script.
#
AC_INIT([GNU sharutils],[4.15.2],[bug-gnu-utils@gnu.org])
AC_CONFIG_SRCDIR([src/shar.c])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([1.14 dist-xz])
AC_USE_SYSTEM_EXTENSIONS
AC_SUBST(DIST_ALPHA)
AC_PROG_CC
gl_EARLY
AM_GNU_GETTEXT([no-libtool])
AM_GNU_GETTEXT_VERSION([0.19.3])
gl_INIT
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AM_PROG_CC_C_O
AM_PROG_AR
dnl FIXME: Check that it is GNU diff indeed.
# Carefully avoid gdiff for X as found on SGI systems.
[if (DISPLAY= gdiff /dev/null /dev/null) 2> /dev/null; then]
AC_PATH_PROGS(DIFF, [gnudiff diffgnu gdiff diff], [no])
[else]
AC_PATH_PROGS(DIFF, [gnudiff diffgnu diff], [no])
[fi
my_save_cflags="$CFLAGS"
CFLAGS=${CFLAGS}' -Wno-format-contains-nul']
AC_MSG_CHECKING([whether CC supports -Wformat-contains-nul])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
[AC_MSG_RESULT([yes])]
[AM_CFLAGS="${AM_CFLAGS} -Wno-format-contains-nul"
my_save_cflags="$CFLAGS"],
[AC_MSG_RESULT([no])]
)
[CFLAGS="$my_save_cflags"]
AC_SUBST([AM_CFLAGS])
dnl FIXME: Check that mailer accepts -s.
[PATH_save="$PATH"; PATH="$PATH:/usr/sbin:/usr/ucb:/usr/bin:/bin"]
AC_PATH_PROGS(MAILER, [mailx elm mush mail], [no])
[PATH="$PATH_save"]
AC_PATH_PROGS(SH, [bash ksh dash sh], [no])
AC_PATH_PROGS(TAR, [gnutar targnu gtar tar], [tar])
dnl in m4/sharutils.m4
CHECK_COMPRESS_AND_LINK
AC_SEARCH_LIBS([strerror],[cposix])
AC_SYS_LARGEFILE
[if test $cross_compiling = no; then]
AC_C_CHAR_UNSIGNED
[fi]
AC_C_CONST
AC_C_INLINE
AC_C_BIGENDIAN
AC_CHECK_HEADERS([locale.h stdbool.h])
AC_HEADER_DIRENT
[test X$ac_header_dirent = Xno && {]
AC_MSG_ERROR([a dirent header is required.])
[}
DIRENT_HEADER="<${ac_header_dirent}>"]
AC_DEFINE_UNQUOTED(DIRENT_HEADER, [${DIRENT_HEADER}],
[define to directory entry header file])
AC_SUBST(DIRENT_HEADER)
AC_HEADER_STAT
AC_HEADER_STDC
AC_STRUCT_TIMEZONE
AC_TYPE_SIZE_T
AC_CHECK_FUNCS([fchmod isascii strchr])
AC_FUNC_CLOSEDIR_VOID
AC_FUNC_FSEEKO
AC_REPLACE_FUNCS([memset mktime strftime xmalloc xstrdup])
AC_ARG_ENABLE(uucode,
[AS_HELP_STRING([--disable-uucode],
[disable installation of uuencode and uudecode])])
AM_CONDITIONAL(UUCODE, [test "x$enable_uucode" != xno])
AM_WITH_DMALLOC
# sharutils is somewhat special about internationalization in that it
# always requires the GNU .mo files installed.
[if test "x$CATOBJEXT" = "x.mo" || test "x$CATOBJEXT" = "x.cat"; then
new_CATALOGS=""
for cat in $CATALOGS; do
lang=`echo $cat | sed "s/\(.*\)\..*/\1/"`
new_CATALOGS="$new_CATALOGS $cat $lang.gmo"
done
CATALOGS="$new_CATALOGS"
fi]
# INVOKE_LIBOPTS_MACROS
[ac_cv_header_alloca_h=yes
ac_cv_header_ctype_h=yes
ac_cv_header_getopt_h=yes
ac_cv_header_stddef_h=yes
ac_cv_header_stdio_h=yes
ac_cv_header_stdlib_h=yes
ac_cv_header_stdnoreturn_h=yes
ac_cv_header_string_h=yes
ac_cv_header_sys_utsname_h=yes
ac_cv_header_sys_wait_h=yes
ac_cv_header_time_h=yes
ac_cv_header_unistd_h=yes
]INVOKE_LIBOPTS_MACROS
[AUTOGEN=`command -v autogen`
$AUTOGEN --version >/dev/null 2>&1 || AUTOGEN='touch $@']
AC_SUBST(AUTOGEN)
AH_TOP([#ifndef SHARUTILS_CONFIG_H])
AH_TOP([#define SHARUTILS_CONFIG_H 1])
AH_BOTTOM([#endif /* SHARUTILS_CONFIG_H */])
AC_CONFIG_FILES([
doc/Makefile
intl/Makefile
lib/Makefile
po/Makefile.in
src/Makefile
tests/Makefile
libopts/Makefile
Makefile
])
AC_OUTPUT
dnl Local Variables:
dnl mode: autoconf-mode
dnl tab-width: 8
dnl indent-tabs-mode: nil
dnl sh-indentation: 2
dnl sh-basic-offset: 2
dnl End:
dnl
dnl end of configure.ac
|
