File: acinclude.m4

package info (click to toggle)
shibboleth-sp2 2.6.0%2Bdfsg1-4%2Bdeb9u1~bpo8%2B1
  • links: PTS, VCS
  • area: main
  • in suites: jessie-backports
  • size: 7,896 kB
  • sloc: cpp: 39,404; sh: 11,726; makefile: 866; xml: 371; ansic: 35
file content (71 lines) | stat: -rw-r--r-- 2,512 bytes parent folder | download | duplicates (29)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
dnl @synopsis AC_CXX_NAMESPACES
dnl
dnl If the compiler can prevent names clashes using namespaces, define
dnl HAVE_NAMESPACES.
dnl
dnl @author Luc Maisonobe
dnl
AC_DEFUN([AC_CXX_NAMESPACES],
[AC_CACHE_CHECK(whether the compiler implements namespaces,
ac_cv_cxx_namespaces,
[
 AC_LANG_PUSH([C++])
 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[namespace Outer { namespace Inner { int i = 0; }}]], [[using namespace Outer::Inner; return i;]])],[ac_cv_cxx_namespaces=yes],[ac_cv_cxx_namespaces=no])
 AC_LANG_POP([])
])
if test "$ac_cv_cxx_namespaces" = yes; then
  AC_DEFINE(HAVE_NAMESPACES,1,[define if the compiler implements namespaces])
fi
])


dnl
dnl @author Luc Maisonobe
dnl
AC_DEFUN([AC_CXX_REQUIRE_STL],
[AC_CACHE_CHECK(whether the compiler supports Standard Template Library,
ac_cv_cxx_have_stl,
[AC_REQUIRE([AC_CXX_NAMESPACES])
 AC_LANG_PUSH([C++])
 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <list>
#include <deque>
#ifdef HAVE_NAMESPACES
using namespace std;
#endif]], [[list<int> x; x.push_back(5);
list<int>::iterator iter = x.begin(); if (iter != x.end()) ++iter; return 0;]])],[ac_cv_cxx_have_stl=yes],[ac_cv_cxx_have_stl=no])
 AC_LANG_POP([])
])
if test "x_$ac_cv_cxx_have_stl" != x_yes; then
  AC_MSG_ERROR([C++ Standard Template Libary unsupported])
fi
])

dnl Determine whether we have gcc of a particular version or later,
dnl based on major, minor, patchlevel versions and date.
dnl AC_HAVE_GCC_VERSION(MAJOR_VERSION, MINOR_VERSION, PATCH_LEVEL, 
dnl 	SNAPSHOT_DATE [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
AC_DEFUN([AC_HAVE_GCC_VERSION],
[AC_CACHE_CHECK([gcc is at least version $1.$2.$3.$4],
          ac_cv_gcc_version_$1_$2_$3_$4,
[
  if test x$GCC = x ; then ac_cv_gcc_version_$1_$2_$3_$4=no
  else 
    ac_gcc_date=`$CC -v 2>&1 | grep '^gcc version ' | sed 's/ (.*//; s/.* //'`
    if test 0$ac_gcc_date -eq 0 ; then ac_gcc_date=0 ; fi
    AC_EGREP_CPP(yes, [#define HAVE_GCC_VERSION(MAJOR, MINOR, MICRO, DATE) \
    (__GNUC__ > (MAJOR) \
     || (__GNUC__ == (MAJOR) && __GNUC_MINOR__ > (MINOR)) \
     || (__GNUC__ == (MAJOR) && __GNUC_MINOR__ == (MINOR) \
         && __GNUC_PATCHLEVEL__ > (MICRO)) \
     || (__GNUC__ == (MAJOR) && __GNUC_MINOR__ == (MINOR) \
         && __GNUC_PATCHLEVEL__ == (MICRO) && ${ac_gcc_date}L >= (DATE)))
#if HAVE_GCC_VERSION($1,$2,$3,$4)
yes
#endif],
   AC_DEFINE_UNQUOTED(HAVE_GCC_VERSION_$1_$2_$3_$4, 1,
     [Define to 1 if we have gcc $1.$2.$3 ($4)])
   ac_cv_gcc_version_$1_$2_$3_$4=yes ; $5,
   ac_cv_gcc_version_$1_$2_$3_$4=no ; $6)
fi
])])dnl