File: fseeko.m4

package info (click to toggle)
shishi 1.0.0-1
  • links: PTS, VCS
  • area: main
  • in suites: squeeze
  • size: 22,144 kB
  • ctags: 7,865
  • sloc: ansic: 61,153; sh: 12,212; yacc: 1,219; makefile: 1,164; perl: 624; sed: 16
file content (50 lines) | stat: -rw-r--r-- 1,349 bytes parent folder | download | duplicates (7)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# fseeko.m4 serial 9
dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_FSEEKO],
[
  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  AC_REQUIRE([gl_HAVE_FSEEKO])
  AC_REQUIRE([gl_STDIN_LARGE_OFFSET])

  if test $gl_cv_func_fseeko = no; then
    HAVE_FSEEKO=0
    gl_REPLACE_FSEEKO
  else
    if test $gl_cv_var_stdin_large_offset = no; then
      gl_REPLACE_FSEEKO
    fi
  fi
])

dnl Tests whether fseeko is available.
dnl Result is gl_cv_func_fseeko.
AC_DEFUN([gl_HAVE_FSEEKO],
[
  AC_REQUIRE([AC_PROG_CC])

  dnl Persuade glibc <stdio.h> to declare fseeko().
  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])

  AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
    [
      AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
]], [fseeko (stdin, 0, 0);])],
        [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
    ])
])

AC_DEFUN([gl_REPLACE_FSEEKO],
[
  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  AC_REQUIRE([gl_HAVE_FSEEKO])
  if test $gl_cv_func_fseeko = yes; then
    REPLACE_FSEEKO=1
  fi
  AC_LIBOBJ([fseeko])
  dnl If we are also using the fseek module, then fseek needs replacing, too.
  m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
])