File: ax_check_page_aligned_malloc.m4

package info (click to toggle)
sigscheme 0.8.5-4.1
  • links: PTS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 11,752 kB
  • ctags: 7,396
  • sloc: lisp: 37,498; ansic: 30,976; sh: 10,329; makefile: 746; asm: 333; ruby: 288
file content (57 lines) | stat: -rw-r--r-- 1,955 bytes parent folder | download | duplicates (16)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
dnl @synopsis AX_CHECK_PAGE_ALIGNED_MALLOC
dnl
dnl Some operating systems (generally, BSD Unix variants) lack a
dnl posix_memalign function, a memalign function, and a working
dnl (meaning, the memory can be freed) valloc function. To make up for
dnl it, the malloc function promises to return page-aligned addresses
dnl if more than one page's worth of memory is allocated.
dnl AX_CHECK_PAGE_ALIGNED_MALLOC checks for this condition and defines
dnl HAVE_PAGE_ALIGNED_MALLOC if the condition holds.
dnl
dnl As an aside, note that valloc'd memory cannot safely be freed on
dnl all operating systems. (Again, some flavors of BSD are the
dnl troublemakers.) It's best to avoid using valloc in favor of
dnl posix_memalign, memalign, or an aligned malloc as detected by
dnl AX_CHECK_PAGE_ALIGNED_MALLOC.
dnl
dnl Caveat: AX_CHECK_PAGE_ALIGNED_MALLOC takes a probabalistic
dnl approach. If 100 calls to malloc all return page-aligned addresses,
dnl it assumes that all calls will behave likewise. It is therefore
dnl possible -- albeit extremely unlikely -- that
dnl AX_CHECK_PAGE_ALIGNED_MALLOC can return a false positive.
dnl
dnl @category C
dnl @author Scott Pakin <pakin@uiuc.edu>
dnl @version 2005-01-22
dnl @license AllPermissive

AC_DEFUN([AX_CHECK_PAGE_ALIGNED_MALLOC],
[AC_CACHE_CHECK([if large mallocs guarantee page-alignment],
  [ax_cv_func_malloc_aligned],
  [AC_TRY_RUN([
#include <stdio.h>
#include <stdlib.h>
#if HAVE_UNISTD_H
# include <unistd.h>
#endif

int main()
{
  int pagesize = getpagesize();
  int i;

  for (i=0; i<100; i++)
    if ((unsigned long)malloc(pagesize+1) & (pagesize-1))
      exit (1);
  exit (0);
}
              ],
     [ax_cv_func_malloc_aligned=yes],
     [ax_cv_func_malloc_aligned=no],
     [ax_cv_func_malloc_aligned=no])
  ])
if test "$ax_cv_func_malloc_aligned" = yes ; then
  AC_DEFINE([HAVE_PAGE_ALIGNED_MALLOC], [1],
    [Define if `malloc'ing more than one page always returns a page-aligned address.])
fi
])