File: sigviewer.pro

package info (click to toggle)
sigviewer 0.6.2-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 2,232 kB
  • sloc: cpp: 15,174; sh: 32; xml: 29; makefile: 6
file content (81 lines) | stat: -rw-r--r-- 1,949 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
TEMPLATE = app
DESTDIR = bin
TARGET = sigviewer

VERSION_MAJOR = 0
VERSION_MINOR = 6
VERSION_BUILD = 2

DEFINES += \
    "VERSION_MAJOR=$$VERSION_MAJOR" \
    "VERSION_MINOR=$$VERSION_MINOR" \
    "VERSION_BUILD=$$VERSION_BUILD"

QT += core gui widgets xml

BUILD_DIR = $$PWD/tmp
TARGET_DIR = $$PWD/bin

CONFIG(debug, debug|release) {
    DEFINES -= QT_NO_DEBUG_OUTPUT
    DESTDIR = $$TARGET_DIR/debug
    OBJECTS_DIR = $$BUILD_DIR/debug
    MOC_DIR = $$BUILD_DIR/debug
    RCC_DIR = $$BUILD_DIR/debug
    UI_DIR = $$BUILD_DIR/debug
}
CONFIG(release, debug|release) {
    DEFINES += QT_NO_DEBUG_OUTPUT
    DESTDIR = $$TARGET_DIR/release
    OBJECTS_DIR = $$BUILD_DIR/release
    MOC_DIR = $$BUILD_DIR/release
    RCC_DIR = $$BUILD_DIR/release
    UI_DIR = $$BUILD_DIR/release
}

CONFIG += warn_on link_prl qt thread c++11

macx {
    QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.9
    LIBS += -liconv
}

INCLUDEPATH += \
    $$PWD/external/include \
    $$PWD/src

LIBS += \
    -L$$PWD/external/lib \
    -lbiosig -lxdf

RESOURCES = $$PWD/src/src.qrc
win32:RC_FILE = $$PWD/src/src.rc
ICON = $$PWD/src/sigviewer.icns

TRANSLATIONS += \
    $$PWD/src/translations/sigviewer_de.ts \
    $$PWD/src/translations/sigviewer_en.ts

include($$PWD/src/base/base.pri)
include($$PWD/src/signal_processing/signal_processing.pri)
include($$PWD/src/file_handling_impl/file_handling_impl.pri)
include($$PWD/src/file_handling/file_handling.pri)
include($$PWD/src/gui/gui.pri)
include($$PWD/src/gui_impl/gui_impl.pri)
include($$PWD/src/editing_commands/editing_commands.pri)
include($$PWD/src/commands/commands.pri)
include($$PWD/src/tests/tests.pri)

HEADERS += \
    $$PWD/src/application_context_impl.h \
    $$PWD/src/command_executer.h \
    $$PWD/src/file_context.h \
    $$PWD/src/tab_context.h

SOURCES += \
    $$PWD/src/main.cpp \
    $$PWD/src/application_context_impl.cpp \
    $$PWD/src/file_context.cpp \
    $$PWD/src/tab_context.cpp

QMAKE_CFLAGS += -std=c99