File: soqt-config.cmake.in

package info (click to toggle)
soqt 1.6.0~ea5cd76+ds1-1
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 11,056 kB
  • sloc: sh: 11,393; cpp: 8,650; makefile: 8,649; perl: 863; ansic: 329
file content (72 lines) | stat: -rw-r--r-- 2,611 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
# CMake package configuration file for @PROJECT_NAME@
#
# Defines the target "@PROJECT_NAME@::@PROJECT_NAME@"
#
# Add the following lines to your CMakeLists.txt to depend on @PROJECT_NAME@
#
#    find_package(@PROJECT_NAME@ REQUIRED)
#    target_link_libraries(my_target_name @PROJECT_NAME@::@PROJECT_NAME@)
#
# Additionally you may one of the following variables (or their corresponding
# upper case version) that are also defined.
#
# @PROJECT_NAME@_COMPILE_DEFINITIONS
# @PROJECT_NAME@_DEFINITIONS
# @PROJECT_NAME@_INCLUDE_DIRS
# @PROJECT_NAME@_INCLUDE_DIR
# @PROJECT_NAME@_LIBRARY
# @PROJECT_NAME@_LIBRARIES
# @PROJECT_NAME@_LIBRARY_DIRS
# @PROJECT_NAME@_LIBRARY_DIR
#
# However, in most cases using the @PROJECT_NAME@::@PROJECT_NAME@ target is sufficient,
# and you won't need these variables.

@PACKAGE_INIT@

include(CMakeFindDependencyMacro)

find_dependency(Coin REQUIRED)

set(_have_qt5 "@Qt5_FOUND@")
set(_have_qt4 "@Qt4_FOUND@")
if(_have_qt5)
  find_dependency(Qt5Core REQUIRED)
  find_dependency(Qt5Gui REQUIRED)
  find_dependency(Qt5OpenGL REQUIRED)
  find_dependency(Qt5Widgets REQUIRED)
elseif(_have_qt4)
  find_dependency(Qt4 REQUIRED)
endif()

include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME_LOWER@-export.cmake")

get_property(@PROJECT_NAME@_COMPILE_DEFINITIONS TARGET @PROJECT_NAME@::@PROJECT_NAME@ PROPERTY INTERFACE_COMPILE_DEFINITIONS)
foreach(_def ${@PROJECT_NAME@_COMPILE_DEFINITIONS})
  list(APPEND @PROJECT_NAME@_DEFINITIONS -D${_def})
endforeach()

get_property(@PROJECT_NAME@_INCLUDE_DIRS TARGET @PROJECT_NAME@::@PROJECT_NAME@ PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
set(@PROJECT_NAME@_INCLUDE_DIR ${@PROJECT_NAME@_INCLUDE_DIRS})
set(@PROJECT_NAME@_LIBRARY @PROJECT_NAME@::@PROJECT_NAME@)
get_property(@PROJECT_NAME@_LIBRARIES TARGET @PROJECT_NAME@::@PROJECT_NAME@ PROPERTY INTERFACE_LINK_LIBRARIES)
set(@PROJECT_NAME@_LIBRARIES @PROJECT_NAME@::@PROJECT_NAME@ ${@PROJECT_NAME@_LIBRARIES})
set(@PROJECT_NAME@_LIBRARY_DIRS "@CMAKE_INSTALL_FULL_LIBDIR@")
set(@PROJECT_NAME@_LIBRARY_DIR ${@PROJECT_NAME@_LIBRARY_DIRS})
set(@PROJECT_NAME@_VERSION "@PROJECT_VERSION@")

# For backwards compatibility define upper case versions of output variables
foreach(_var
  @PROJECT_NAME@_COMPILE_DEFINITIONS
  @PROJECT_NAME@_DEFINITIONS
  @PROJECT_NAME@_INCLUDE_DIRS
  @PROJECT_NAME@_INCLUDE_DIR
  @PROJECT_NAME@_LIBRARY
  @PROJECT_NAME@_LIBRARIES
  @PROJECT_NAME@_LIBRARY_DIRS
  @PROJECT_NAME@_LIBRARY_DIR
  @PROJECT_NAME@_VERSION
  )
  string(TOUPPER ${_var} _uppercase_var)
  set(${_uppercase_var} ${${_var}})
endforeach()