File: PreferStaticLibs.cmake

package info (click to toggle)
spring 106.0%2Bdfsg-1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm
  • size: 55,260 kB
  • sloc: cpp: 543,946; ansic: 44,800; python: 12,575; java: 12,201; awk: 5,889; sh: 1,796; asm: 1,546; xml: 655; perl: 405; php: 211; objc: 194; makefile: 76; sed: 2
file content (66 lines) | stat: -rw-r--r-- 2,166 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
# This file is part of the Spring engine (GPL v2 or later), see LICENSE.html

if (NOT PREFER_STATIC_LIBS)
	set(PREFER_STATIC_LIBS FALSE)
	set(WARN_STATIC_LINK_SWITCH TRUE CACHE BOOL "")
	mark_as_advanced(WARN_STATIC_LINK_SWITCH)
endif ()

set(PREFER_STATIC_LIBS ${PREFER_STATIC_LIBS} CACHE BOOL "Try to link as much as possible libraries statically")
if (PREFER_STATIC_LIBS)
	if (WARN_STATIC_LINK_SWITCH)
		message (FATAL_ERROR "You cannot toggle `static linked` once you run cmake! You have to use a cmake `toolchain` file to enable this flag!")
	endif ()

	message (STATUS "Prefer static-linking!")

	set(Boost_USE_STATIC_LIBS TRUE)
	mark_as_advanced(Boost_USE_STATIC_LIBS)

	set(ORIG_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
	mark_as_advanced(ORIG_FIND_LIBRARY_SUFFIXES)

	include(TestCXXAcceptsFlag)

	check_cxx_accepts_flag("-static-libgcc" HAVE_STATIC_LIBGCC_FLAG)
	if (HAVE_STATIC_LIBGCC_FLAG)
		set(CMAKE_EXE_LINKER_FLAGS    "${CMAKE_EXE_LINKER_FLAGS}    -static-libgcc")
		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
		set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
	endif ()

	check_cxx_accepts_flag("-static-libstdc++" HAVE_STATIC_LIBSTDCXX_FLAG)
	if (HAVE_STATIC_LIBSTDCXX_FLAG)
		set(CMAKE_EXE_LINKER_FLAGS    "${CMAKE_EXE_LINKER_FLAGS}    -static-libstdc++")
		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
		set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
	endif ()

	macro (PREFER_STATIC_LIBS)
		if (WIN32 OR MINGW)
			set(CMAKE_FIND_LIBRARY_SUFFIXES .a .lib ${CMAKE_FIND_LIBRARY_SUFFIXES})
		else ()
			set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
		endif ()
	endmacro ()

	macro (UNPREFER_STATIC_LIBS)
		set(CMAKE_FIND_LIBRARY_SUFFIXES ${ORIG_FIND_LIBRARY_SUFFIXES})
	endmacro ()

	macro (FIND_PACKAGE_STATIC)
		prefer_static_libs()
		find_package(${ARGV0} ${ARGV1})
		unprefer_static_libs()
	endmacro ()
else ()
	macro (PREFER_STATIC_LIBS)
	endmacro ()

	macro (UNPREFER_STATIC_LIBS)
	endmacro ()

	macro (FIND_PACKAGE_STATIC)
		find_package(${ARGV0} ${ARGV1})
	endmacro ()
endif ()