1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
|
/* embll.l - EMBL sequence lexer */
%{
#ifdef HAVE_CONFIG_H
# include <config.h>
#endif
#ifdef STDC_HEADERS
# include <stdlib.h>
# include <string.h>
#endif
#include "sequence/embly.h"
%}
%option bison-bridge
%option never-interactive
%option noinput nounput noyywrap
%x IDTAG ACTAG SVTAG PRTAG DTTAG DETAG KWTAG OSTAG OCTAG OGTAG RNTAG RCTAG
%x RPTAG RXTAG RGTAG RATAG RTTAG RLTAG DRTAG AHTAG ASTAG FHTAG FTTAG CCTAG
%x COTAG SQTAG
%x SEQTAG ENDTAG
%x IDTA2 RXTA2 RTTA2
alp [[:alpha:]]
aln [[:alnum:]]
cbr "]"
col ":"
com ","
dig [[:digit:]]
dot "."
eol "\n"
min "-"
obr "["
quo "\""
sem ";"
sla "/"
spc " "
sta "*"
und "_"
txt .{1,80}
idnam [^ ;\n]{1,13}
idcla standard
idtyp ((genomic|other|unassigned){spc}|pre{min}|sno?|sc|[mrt])
idmol (circular{spc})?{idtyp}?([DR]NA|UKN)
iddiv (CON|EST|FUN|GSS|HT[CG]|HUM|INV|MAM|MUS|ORG|PHG|PLN|PRO|ROD|STS|SYN|UNC|VR[LT]|XXX)
acnum [^ ;\n]{1,75}
prdat Project:{aln}{1,10}
kwwrd [^; \n][^;\n]{0,80}
kword {kwwrd}({sem}{kwwrd})*
ocnod [^;\n]{1,80}
rxdb (AGRICOLA|DOI|MEDLINE|PUBMED)
rxid .{1,80}
raaut [^,;\n]{1,80}
gap {min}
bas ({alp}|{gap}){1,10}
%%
^{spc}*{eol} ; /* Empty lines ignored */
^XX{eol} ; /* Spacers ignored */
^ST{spc}{sta}{spc}.*{eol} ; /* Skip internal release status tag */
^AC{spc}{sta}{spc}.*{eol} ; /* Skip internal identifier tag */
^BQ{spc}{sta}{spc}.*{eol} ; /* Skip internal base quality tag */
^ID{spc}{3} { BEGIN IDTAG; return ID; }
<IDTAG>{idnam} { BEGIN IDTA2; yylval->str = strdup(yytext); return IDNAM; }
<IDTAG>{eol} { BEGIN INITIAL; return EOL; }
<IDTAG>. { return ERR; }
<IDTA2>{txt} { return TXT; }
<IDTA2>{eol} { BEGIN INITIAL; return EOL; }
^AC{spc}{3} { BEGIN ACTAG; return AC; }
<ACTAG>{acnum} { yylval->str = strdup(yytext); return ACNUM; }
<ACTAG>{sem}{spc} { return SEP; }
<ACTAG>{sem}{spc}?/{eol} { return TER; }
<ACTAG>{eol} { BEGIN INITIAL; return EOL; }
<ACTAG>. { return ERR; }
^SV{spc}{3} { BEGIN SVTAG; return SV; }
<SVTAG>{acnum}/{dot}{dig} { return ACNUM; }
<SVTAG>{dot} { return SEP; }
<SVTAG>{dig}+ { yylval->num = atoi(yytext); return SVNUM; }
<SVTAG>{eol} { BEGIN INITIAL; return EOL; }
<SVTAG>. { return ERR; }
^PR{spc}{3} { BEGIN PRTAG; return PR; }
<PRTAG>{prdat} { return PRDAT; }
<PRTAG>{sem}{spc} { return SEP; }
<PRTAG>{sem}/{eol} { return TER; }
<PRTAG>{eol} { BEGIN INITIAL; return EOL; }
<PRTAG>. { return ERR; }
^DT{spc}{3} { BEGIN DTTAG; return DT; }
<DTTAG>{txt} { return TXT; }
<DTTAG>{eol} { BEGIN INITIAL; return EOL; }
^DE{spc}{3} { BEGIN DETAG; return DE; }
<DETAG>{txt} { yylval->str = strdup(yytext); return DETXT; }
<DETAG>{eol} { BEGIN INITIAL; return EOL; }
^KW{spc}{3} { BEGIN KWTAG; return KW; }
<KWTAG>{sem}{spc} { return SEP; }
<KWTAG>{sem}{spc}?/{eol} { return TER2; }
<KWTAG>{dot}{spc}?/{eol} { return TER; }
<KWTAG>{kword}/{eol}KW { yylval->str = strdup(yytext); return KWOR2; }
<KWTAG>{kword}/{sem}{spc} { yylval->str = strdup(yytext); return KWORD; }
<KWTAG>{kword}/{sem}{eol} { yylval->str = strdup(yytext); return KWORD; }
<KWTAG>{kword}/{dot}{eol} { yylval->str = strdup(yytext); return KWORD; }
<KWTAG>{kword}/{dot}{spc}{eol} { yylval->str = strdup(yytext); return KWORD; }
<KWTAG>{eol} { BEGIN INITIAL; return EOL; }
<KWTAG>. { return ERR; }
^OS{spc}{3} { BEGIN OSTAG; return OS; }
<OSTAG>{txt} { return OSTXT; }
<OSTAG>{eol} { BEGIN INITIAL; return EOL; }
^OC{spc}{3} { BEGIN OCTAG; return OC; }
<OCTAG>{sem}{spc} { return SEP; }
<OCTAG>{sem}{spc}?/{eol} { return TER2; }
<OCTAG>{dot}{spc}?/{eol} { return TER; }
<OCTAG>{ocnod}/{sem}{spc} { return OCNOD; }
<OCTAG>{ocnod}/{sem}{eol} { return OCNOD; }
<OCTAG>{ocnod}{dot}/{eol}OC { return OCNO2; }
<OCTAG>{ocnod}/{dot}{eol} { return OCNOD; }
<OCTAG>{ocnod}/{dot}{spc}{eol} { return OCNOD; }
<OCTAG>{eol} { BEGIN INITIAL; return EOL; }
<OCTAG>. { return ERR; }
^OG{spc}{3} { BEGIN OGTAG; return OG; }
<OGTAG>{txt} { return TXT; }
<OGTAG>{eol} { BEGIN INITIAL; return EOL; }
^RN{spc}{3} { BEGIN RNTAG; return RN; }
<RNTAG>{obr} { return OBR; }
<RNTAG>{cbr} { return CBR; }
<RNTAG>{dig}+ { return INT; }
<RNTAG>{eol} { BEGIN INITIAL; return EOL; }
<RNTAG>. { return ERR; }
^RC{spc}{3} { BEGIN RCTAG; return RC; }
<RCTAG>{txt} { return TXT; }
<RCTAG>{eol} { BEGIN INITIAL; return EOL; }
^RP{spc}{3} { BEGIN RPTAG; return RP; }
<RPTAG>{min} { return MIN; }
<RPTAG>{com}{spc}? { return SEP; }
<RPTAG>{com}/{eol} { return TER; }
<RPTAG>{dig}+ { return INT; }
<RPTAG>{eol} { BEGIN INITIAL; return EOL; }
<RPTAG>. { return ERR; }
^RX{spc}{3} { BEGIN RXTAG; return RX; }
<RXTAG>{sem}{spc} { BEGIN RXTA2; return SEP; }
<RXTAG>{rxdb}/{sem}{spc} { return RXDB; }
<RXTAG>{eol} { return ERR; }
<RXTAG>. { return ERR; }
<RXTA2>{rxid}/{dot}{eol} { return RXID; }
<RXTA2>{dot}/{eol} { return TER; }
<RXTA2>{eol} { BEGIN INITIAL; return EOL; }
<RXTA2>. { return ERR; }
^RG{spc}{3} { BEGIN RGTAG; return RG; }
<RGTAG>{txt} { return TXT; }
<RGTAG>{eol} { BEGIN INITIAL; return EOL; }
^RA{spc}{3} { BEGIN RATAG; return RA; }
<RATAG>{com}{spc} { return SEP; }
<RATAG>{com}/{eol} { return TER2; }
<RATAG>{sem}/{eol} { return TER; }
<RATAG>{raaut} { return RAAUT; }
<RATAG>{eol} { BEGIN INITIAL; return EOL; }
<RATAG>. { return ERR; }
^RT{spc}{3} { BEGIN RTTAG; return RT; }
<RTTAG>{quo} { BEGIN RTTA2; return QUO; }
<RTTAG>{sem}/{eol} { return TER; }
<RTTAG>{eol} { BEGIN INITIAL; return EOL; }
<RTTA2>^RT{spc}{3}/{txt}{eol} { return RT; }
<RTTA2>{quo}/{sem}{eol} { BEGIN RTTAG; return QUO; }
<RTTA2>{txt}/{quo}{sem}{eol} { return TXT; }
<RTTA2>{txt} { return TXT; }
<RTTA2>{eol} { return EOL; }
^RL{spc}{3} { BEGIN RLTAG; return RL; }
<RLTAG>{txt} { return TXT; }
<RLTAG>{eol} { BEGIN INITIAL; return EOL; }
^DR{spc}{3} { BEGIN DRTAG; return DR; }
<DRTAG>{txt} { return TXT; }
<DRTAG>{eol} { BEGIN INITIAL; return EOL; }
^AH{spc}{3} { BEGIN AHTAG; return AH; }
<AHTAG>{txt} { return TXT; }
<AHTAG>{eol} { BEGIN INITIAL; return EOL; }
^AS{spc}{3} { BEGIN ASTAG; return AS; }
<ASTAG>{txt} { return TXT; }
<ASTAG>{eol} { BEGIN INITIAL; return EOL; }
^FH({spc}{3})? { BEGIN FHTAG; return FH; }
<FHTAG>{txt} { return TXT; }
<FHTAG>{eol} { BEGIN INITIAL; return EOL; }
^FT{spc}{3} { BEGIN FTTAG; return FT; }
<FTTAG>{txt} { return TXT; }
<FTTAG>{eol} { BEGIN INITIAL; return EOL; }
^CC{spc}{3} { BEGIN CCTAG; return CC; }
<CCTAG>{txt} { return TXT; }
<CCTAG>{eol} { BEGIN INITIAL; return EOL; }
^CO{spc}{3} { BEGIN COTAG; return CO; }
<COTAG>{txt} { return TXT; }
<COTAG>{eol} { BEGIN INITIAL; return EOL; }
^SQ{spc}{3} { BEGIN SQTAG; return SQ; }
<SQTAG>{txt} { return TXT; }
<SQTAG>{eol} { BEGIN INITIAL; return EOL; }
^{spc}{5} { BEGIN SEQTAG; return SEQ; }
<SEQTAG>{bas} { yylval->str = strdup(yytext); return SEQBAS; }
<SEQTAG>{dig}+ { return INT; }
<SEQTAG>{spc}+/{dig} { return SPC; }
<SEQTAG>{spc} { return SEP; }
<SEQTAG>{eol} { BEGIN INITIAL; return EOL; }
<SEQTAG>. { return ERR; }
^{sla}{2} { BEGIN ENDTAG; return END; }
<ENDTAG>{eol} { BEGIN INITIAL; return EOL; }
<ENDTAG><<EOF>> { BEGIN INITIAL; return EOL; }
<ENDTAG>. { return ERR; }
<<EOF>> { return NUL; }
{eol} { return ERR; }
. { return ERR; }
%%
|
