1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
#-------------------------------------------------------------------------------
# SuiteSparse/SuiteSparse_config/cmake_modules/SuiteSparse_configConfig.cmake
#-------------------------------------------------------------------------------
# The following copyright and license applies to just this file only, not to
# the library itself:
# SuiteSparse_configConfig.cmake, Copyright (c) 2023, Timothy A. Davis. All Rights Reserved.
# SPDX-License-Identifier: BSD-3-clause
#-------------------------------------------------------------------------------
# Finds the SuiteSparse_config include file and compiled library.
# The following targets are defined:
# SuiteSparseConfig - for the shared library (if available)
# SuiteSparseConfig_static - for the static library (if available)
# For backward compatibility the following variables are set:
# SUITESPARSE_CONFIG_INCLUDE_DIR - where to find SuiteSparse_config.h
# SUITESPARSE_CONFIG_LIBRARY - dynamic SuiteSparse_config library
# SUITESPARSE_CONFIG_STATIC - static SuiteSparse_config library
# SUITESPARSE_CONFIG_LIBRARIES - libraries when using SuiteSparse_config
# SUITESPARSE_CONFIG_FOUND - true if SuiteSparse_config found
# Set ``CMAKE_MODULE_PATH`` to the parent folder where this module file is
# installed.
#-------------------------------------------------------------------------------
@PACKAGE_INIT@
set ( SUITESPARSE_DATE "@SUITESPARSE_DATE@" )
set ( SUITESPARSE_CONFIG_VERSION_MAJOR @SUITESPARSE_VERSION_MAJOR@ )
set ( SUITESPARSE_CONFIG_VERSION_MINOR @SUITESPARSE_VERSION_MINOR@ )
set ( SUITESPARSE_CONFIG_VERSION_PATCH @SUITESPARSE_VERSION_SUB@ )
set ( SUITESPARSE_CONFIG_VERSION "@SUITESPARSE_VERSION_MAJOR@.@SUITESPARSE_VERSION_MINOR@.@SUITESPARSE_VERSION_SUB@" )
# Check for dependent targets
include ( CMakeFindDependencyMacro )
set ( _dependencies_found ON )
# Look for OpenMP
if ( @SUITESPARSE_CONFIG_HAS_OPENMP@ AND NOT OpenMP_C_FOUND )
find_dependency ( OpenMP COMPONENTS C )
if ( NOT OpenMP_C_FOUND )
set ( _dependencies_found OFF )
endif ( )
endif ( )
if ( NOT _dependencies_found )
set ( SuiteSparse_config_FOUND OFF )
return ( )
endif ( )
# Import target
include ( ${CMAKE_CURRENT_LIST_DIR}/SuiteSparse_configTargets.cmake )
if ( @SUITESPARSE_CONFIG_HAS_OPENMP@ )
if ( TARGET SuiteSparse::SuiteSparseConfig )
get_property ( _suitesparse_config_aliased TARGET SuiteSparse::SuiteSparseConfig
PROPERTY ALIASED_TARGET )
if ( "${_suitesparse_config_aliased}" STREQUAL "" )
target_include_directories ( SuiteSparse::SuiteSparseConfig SYSTEM AFTER INTERFACE
"$<TARGET_PROPERTY:OpenMP::OpenMP_C,INTERFACE_INCLUDE_DIRECTORIES>" )
else ( )
target_include_directories ( ${_suitesparse_config_aliased} SYSTEM AFTER INTERFACE
"$<TARGET_PROPERTY:OpenMP::OpenMP_C,INTERFACE_INCLUDE_DIRECTORIES>" )
endif ( )
endif ( )
if ( TARGET SuiteSparse::SuiteSparseConfig_static )
get_property ( _suitesparse_config_aliased TARGET SuiteSparse::SuiteSparseConfig_static
PROPERTY ALIASED_TARGET )
if ( "${_suitesparse_config_aliased}" STREQUAL "" )
target_include_directories ( SuiteSparse::SuiteSparseConfig_static SYSTEM AFTER INTERFACE
"$<TARGET_PROPERTY:OpenMP::OpenMP_C,INTERFACE_INCLUDE_DIRECTORIES>" )
else ( )
target_include_directories ( ${_suitesparse_config_aliased} SYSTEM AFTER INTERFACE
"$<TARGET_PROPERTY:OpenMP::OpenMP_C,INTERFACE_INCLUDE_DIRECTORIES>" )
endif ( )
endif ( )
endif ( )
# The following is only for backward compatibility with FindSuiteSparse_config.
set ( _target_shared SuiteSparse::SuiteSparseConfig )
set ( _target_static SuiteSparse::SuiteSparseConfig_static )
set ( _var_prefix "SUITESPARSE_CONFIG" )
if ( NOT @BUILD_SHARED_LIBS@ AND NOT TARGET ${_target_shared} )
# make sure there is always an import target without suffix )
add_library ( ${_target_shared} ALIAS ${_target_static} )
endif ( )
get_target_property ( ${_var_prefix}_INCLUDE_DIR ${_target_shared} INTERFACE_INCLUDE_DIRECTORIES )
if ( ${_var_prefix}_INCLUDE_DIR )
# First item in SuiteSparse targets contains the "main" header directory.
list ( GET ${_var_prefix}_INCLUDE_DIR 0 ${_var_prefix}_INCLUDE_DIR )
endif ( )
get_target_property ( ${_var_prefix}_LIBRARY ${_target_shared} IMPORTED_IMPLIB )
if ( NOT ${_var_prefix}_LIBRARY )
get_target_property ( _library_chk ${_target_shared} IMPORTED_LOCATION )
if ( EXISTS ${_library_chk} )
set ( ${_var_prefix}_LIBRARY ${_library_chk} )
endif ( )
endif ( )
if ( TARGET ${_target_static} )
get_target_property ( ${_var_prefix}_STATIC ${_target_static} IMPORTED_LOCATION )
endif ( )
# Check for most common build types
set ( _config_types "Debug" "Release" "RelWithDebInfo" "MinSizeRel" "None" )
get_property ( _isMultiConfig GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG )
if ( _isMultiConfig )
# For multi-configuration generators (e.g., Visual Studio), prefer those
# configurations.
list ( PREPEND _config_types ${CMAKE_CONFIGURATION_TYPES} )
else ( )
# For single-configuration generators, prefer the current configuration.
list ( PREPEND _config_types ${CMAKE_BUILD_TYPE} )
endif ( )
list ( REMOVE_DUPLICATES _config_types )
foreach ( _config ${_config_types} )
string ( TOUPPER ${_config} _uc_config )
if ( NOT ${_var_prefix}_LIBRARY )
get_target_property ( _library_chk ${_target_shared}
IMPORTED_IMPLIB_${_uc_config} )
if ( EXISTS ${_library_chk} )
set ( ${_var_prefix}_LIBRARY ${_library_chk} )
endif ( )
endif ( )
if ( NOT ${_var_prefix}_LIBRARY )
get_target_property ( _library_chk ${_target_shared}
IMPORTED_LOCATION_${_uc_config} )
if ( EXISTS ${_library_chk} )
set ( ${_var_prefix}_LIBRARY ${_library_chk} )
endif ( )
endif ( )
if ( TARGET ${_target_static} AND NOT ${_var_prefix}_STATIC )
get_target_property ( _library_chk ${_target_static}
IMPORTED_LOCATION_${_uc_config} )
if ( EXISTS ${_library_chk} )
set ( ${_var_prefix}_STATIC ${_library_chk} )
endif ( )
endif ( )
endforeach ( )
set ( SUITESPARSE_CONFIG_LIBRARIES ${SUITESPARSE_CONFIG_LIBRARY} )
macro ( suitesparse_check_exist _var _files )
# ignore generator expressions
string ( GENEX_STRIP "${_files}" _files2 )
foreach ( _file ${_files2} )
if ( NOT EXISTS "${_file}" )
message ( FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist!" )
endif ( )
endforeach ()
endmacro ( )
suitesparse_check_exist ( SUITESPARSE_CONFIG_INCLUDE_DIR ${SUITESPARSE_CONFIG_INCLUDE_DIR} )
suitesparse_check_exist ( SUITESPARSE_CONFIG_LIBRARY ${SUITESPARSE_CONFIG_LIBRARY} )
message ( STATUS "SuiteSparse_config version: ${SUITESPARSE_CONFIG_VERSION}" )
message ( STATUS "SuiteSparse_config include: ${SUITESPARSE_CONFIG_INCLUDE_DIR}" )
message ( STATUS "SuiteSparse_config library: ${SUITESPARSE_CONFIG_LIBRARY}" )
message ( STATUS "SuiteSparse_config static: ${SUITESPARSE_CONFIG_STATIC}" )
|
