1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
class:: LatoocarfianL
summary:: Latoocarfian chaotic generator
categories:: UGens>Generators>Chaotic
related:: Classes/LatoocarfianC, Classes/LatoocarfianN
description::
A linear-interpolating sound generator based on a function given in Clifford Pickover's book Chaos In Wonderland, pg 26. The function is:
teletype::
x(n+1) = sin(b * y(n)) + c * sin(b * x(n))
y(n+1) = sin(a * x(n)) + d * sin(a * y(n))
::
According to Pickover, parameters code::a:: and code::b:: should be in the range from -3 to +3, and parameters code::c:: and code::d:: should be in the range from 0.5 to 1.5. The function can, depending on the parameters given, give continuous chaotic output, converge to a single value (silence) or oscillate in a cycle (tone).
sclang code translation:
code::
(
var a = 1, b = 3, c = 0.5, d = 0.5, xi = 0.5, yi = 0.5, size = 64;
plot(size.collect { var x = xi;
xi = sin(b * yi) + (c * sin(b * xi));
yi = sin(a * x) + (d * sin(a * yi));
xi
});
)
::
note::This UGen is experimental and not optimized currently, so is rather hoggish of CPU.::
classmethods::
method:: ar
argument:: freq
Iteration frequency in Hertz
argument:: a
Equation variable
argument:: b
Equation variable
argument:: c
Equation variable
argument:: d
Equation variable
argument:: xi
Initial value of x
argument:: yi
Initial value of y
examples::
code::
// default initial params
{ LatoocarfianL.ar(MouseX.kr(20, SampleRate.ir)) * 0.2 }.play(s);
::
code::
// randomly modulate all params
(
{ LatoocarfianL.ar(
SampleRate.ir/4,
LFNoise2.kr(2,1.5,1.5),
LFNoise2.kr(2,1.5,1.5),
LFNoise2.kr(2,0.5,1.5),
LFNoise2.kr(2,0.5,1.5)
) * 0.2 }.play(s);
)
::
code::
(
{ LatoocarfianL.ar(
SampleRate.ir/4,
[LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
[LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
[LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
[LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2)
) * 0.2 !2}.play;
)
::
|
