1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
|
SynthDefOld : SynthDef {
*new { arg name, ugenGraphFunc, rates, prependArgs, variants, metadata;
^super.new.name_(name.asSymbol).variants_(variants).metadata_(metadata).children_(Array.new(64))
.build(ugenGraphFunc, rates, prependArgs)
}
writeDefFile { arg dir, overwrite(true);
if((metadata.tryPerform(\at, \shouldNotSend) ? false).not) {
super.writeDefFileOld(name, dir, overwrite);
} {
// actual error, not just warning as in .send and .load,
// because you might try to write the file somewhere other than
// the default location - could be fatal later, so crash now
MethodError("This SynthDef (%) was reconstructed from a .scsyndef file. It does not contain all the required structure to write back to disk. File was not written."
.format(name), this).throw
}
}
writeDef { arg file;
// This describes the file format for the synthdef files.
var allControlNamesTemp, allControlNamesMap;
try {
file.putPascalString(name.asString);
this.writeConstants(file);
//controls have been added by the Control UGens
file.putInt16(controls.size);
controls.do { | item |
file.putFloat(item);
};
allControlNamesTemp = allControlNames.reject { |cn| cn.rate == \noncontrol };
file.putInt16(allControlNamesTemp.size);
allControlNamesTemp.do { | item |
if (item.name.notNil) {
file.putPascalString(item.name.asString);
file.putInt16(item.index);
};
};
file.putInt16(children.size);
children.do { | item |
item.writeDefOld(file);
};
file.putInt16(variants.size);
if (variants.size > 0) {
allControlNamesMap = ();
allControlNamesTemp.do { |cn|
allControlNamesMap[cn.name] = cn;
};
variants.keysValuesDo {|varname, pairs|
var varcontrols;
varname = name ++ "." ++ varname;
if (varname.size > 32) {
Post << "variant '" << varname << "' name too long.\n";
^nil
};
varcontrols = controls.copy;
pairs.pairsDo { |cname, values|
var cn, index;
cn = allControlNamesMap[cname];
if (cn.notNil) {
values = values.asArray;
if (values.size > cn.defaultValue.asArray.size) {
postf("variant: '%' control: '%' size mismatch.\n",
varname, cname);
^nil
}{
index = cn.index;
values.do {|val, i|
varcontrols[index + i] = val;
}
}
}{
postf("variant: '%' control: '%' not found.\n",
varname, cname);
^nil
}
};
file.putPascalString(varname);
varcontrols.do { | item |
file.putFloat(item);
};
};
}
} { // catch
arg e;
if (file.respondsTo(\close)) {
file.close;
};
Error("SynthDefOld: could not write def: %".format(e.what())).throw;
}
}
writeConstants { arg file;
var array = FloatArray.newClear(constants.size);
constants.keysValuesDo { arg value, index;
array[index] = value;
};
file.putInt16(constants.size);
array.do { | item |
file.putFloat(item)
};
}
asBytes {
var stream = CollStream.on(Int8Array.new(256));
this.asArray.writeDefOld(stream);
^stream.collection;
}
}
+ Collection {
writeDefOld { | file |
file.putString("SCgf");
file.putInt32(1); // file version
file.putInt16(this.size); // number of defs in file.
this.do { | item | item.writeDef(file); }
}
writeInputSpecOld { | file, synthDef |
this.do { | item | item.writeInputSpecOld(file, synthDef) };
}
}
+ UGen {
writeDefOld { arg file;
//[\WR, this.class.name, rate, this.numInputs, this.numOutputs].postln;
try {
file.putPascalString(this.name);
file.putInt8(this.rateNumber);
file.putInt16(this.numInputs);
file.putInt16(this.numOutputs);
file.putInt16(this.specialIndex);
// write wire spec indices.
inputs.do({ arg input;
input.writeInputSpecOld(file, synthDef);
});
this.writeOutputSpecs(file);
//[this.class.name, file.length].postln;
} { // catch
arg e;
Error("UGen: could not write def: %".format(e.what())).throw;
}
}
writeInputSpecOld { arg file, synthDef;
file.putInt16(synthIndex);
file.putInt16(this.outputIndex);
}
}
+ SimpleNumber {
writeInputSpecOld { arg file, synth;
var constIndex = synth.constants.at(this.asFloat);
if (constIndex.isNil) {
Error("SimpleNumber-writeInputSpec constant not found: " ++ this.asFloat).throw; };
//[\inpspc, this.class.name, constIndex, this].postln;
file.putInt16(-1);
file.putInt16(constIndex);
}
}
+ Object {
writeDefFileOld { arg name, dir, overwrite = (true);
StartUp.defer { // make sure the synth defs are written to the right path
var file;
dir = dir ? SynthDef.synthDefDir;
if (name.isNil) { Error("missing SynthDef file name").throw } {
name = dir +/+ name ++ ".scsyndef";
if(overwrite or: { pathMatch(name).isEmpty })
{
file = File(name, "w");
protect {
AbstractMDPlugin.clearMetadata(name);
this.asArray.writeDefOld(file);
}{
file.close;
}
}
}
}
}
}
|
