1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
|
Spawner : Pattern {
var <>genStream;
var <>priorityQ;
var <>now;
var <>event;
*new { | func, stackSize=64 |
^super.new.init( func, stackSize)
}
suspend { | stream |
priorityQ.removeValue(stream);
}
suspendAll {
priorityQ.clear
}
init { | func, stackSize |
priorityQ = PriorityQueue.new;
genStream = Routine({func.value(this) }, stackSize);
now = 0;
priorityQ.put(now, genStream);
}
par { | pattern, delta = 0 |
var stream = pattern.asStream;
priorityQ.put(now + delta, stream);
^stream;
}
seq { | pat |
pat.embedInStream(event)
}
wait { | dur |
Event.silent(dur, event).yield
}
embedInStream { | inevent|
var outevent, stream, nexttime, cleanup;
event = inevent; // gives genStream access to the event
cleanup = EventStreamCleanup.new;
while({
priorityQ.notEmpty
},{
stream = priorityQ.pop;
outevent = stream.next(event).asEvent;
if (outevent.isNil, {
nexttime = priorityQ.topPriority;
if (nexttime.notNil, {
// that child stream ended, so rest until next one
outevent = Event.silent(nexttime - now, event);
cleanup.update(outevent);
event = outevent.yield;
now = nexttime;
},{
priorityQ.clear;
^cleanup.exit(event);
});
},{
cleanup.update(outevent);
// requeue stream
priorityQ.put(now + outevent.delta, stream);
nexttime = priorityQ.topPriority;
outevent.put(\delta, nexttime - now);
event = outevent.yield;
now = nexttime;
});
});
^event;
}
}
Pspawner : Prout {
asStream {
^Routine({ | inval |
this.embedInStream(inval)
})
}
embedInStream { | inevent |
^Spawner(routineFunc).embedInStream(inevent)
}
}
Pspawn : FilterPattern {
var <>spawnProtoEvent;
*new { |pattern, spawnProtoEvent|
^super.new(pattern)
.spawnProtoEvent_(spawnProtoEvent ?? { Event.default });
}
embedInStream { |inevent|
^Spawner({ |sp|
var event, stream = pattern.asStream, child, method;
while { (event = stream.next(spawnProtoEvent.copy.put(\spawner, sp))).notNil } {
method = event[\method];
case
{ method == \wait } {
event[\spawner].wait(event.delta)
}
{ #[seq, par].includes(method) } {
child = event[\pattern];
if(child.isKindOf(Symbol)) {
child = (event[\dict] ? Pdef).at(child);
};
event[\spawner].perform(event.method, child.value(event));
if(event.delta > 0) {
event[\spawner].wait(event.delta)
}
}
// suspend requires access to the specific stream
// don't know how to get it... maybe implement later
{ method == \suspendAll } {
event[\spawner].suspendAll
}
{ "Unrecognized method % in spawner event."
.format(method.asCompileString).warn;
}
};
}).embedInStream(inevent)
}
}
/*
(
Pseq([
Pspawner({ | sp |
sp.postln;
sp.par(Pbind(*[degree: Pwhite(0,12), dur: 0.1, db: -30]) );
sp.seq(Pbind(*[degree: Pseq((0..4).mirror.mirror, 1) + [-3, 0,2], ctranspose: -12, dur: 0.2 ]) );
"hi".postln;
sp.wait(1);
"bye".postln;
sp.suspendAll;
}),
Pspawner({ | sp |
sp.postln;
sp.par(Pbind(*[degree: Pwhite(0,12), dur: 0.2, ctranspose: -12]) );
"hi".postln;
sp.wait(4);
"bye".postln;
sp.suspendAll
}),
]).play;
)
a = Spawner({ |sp | 100.do{ sp.wait(1) } });
a.play;
b = a.par(Pbind(*[degree: Pwhite(0, 10), dur: 0.2]));
a.suspend(b)
a.par(b)
(
Pspawner({ | sp |
5.do {
sp.par(Pbind(*[
octave: (5.rand + 3).postln,
degree: Pwhite(0,12), dur: 0.1, db: -30
]) );
sp.wait(1);
sp.clear;
}
}).play
)
*/
|
