1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
// single sample feedback
// a simple sawtooth
(
{
var x, y, rate, a, c, m, b;
b = LocalBuf(1);
rate = MouseX.kr(100, SampleRate.ir);
a = 0.1;
c = 0.13;
m = 1.0;
x = Dbufrd(b); // read from buffer
x = x + a;
x = if(x > 1, 0, x);
y = Dbufwr(x, b); // write to buffer
Duty.ar(1 / rate, 0, y) * 0.1.dup;
}.scope;
)
// linear congruence
(
{
var x, y, rate, a, c, m, b;
b = LocalBuf(1);
rate = MouseX.kr(100, SampleRate.ir);
a = 1.1;
c = 0.13;
m = 1.0;
x = Dbufrd(b); // read from buffer
x = x * a + c % m;
y = Dbufwr(x, b); // write to buffer
Duty.ar(1 / rate, 0, y) * 0.1.dup;
}.scope;
)
// compare LinCongN and Duty
// plotting some..
(
{
var x, y, rate, a, c, m, u1, u2, b;
b = LocalBuf(1);
rate = SampleRate.ir / 32;
a = 1.1;
c = 0.13;
m = 1.0;
x = Dbufrd(b); // read from buffer
x = x * a + c % m;
y = Dbufwr(x, b); // write to buffer
u1 = LinCongN.ar(rate, a, c, m);
u2 = Duty.ar(1 / rate, 0, y);
// not exactly the same, but very similar. lincong uses doubles
[u1, u2];
}.plot(0.1);
)
// put in a delay line and some amplitude modulation and couple stereo pairs
(
{
var x, y, rate, a, c, m, z, b;
b = LocalBuf(1);
rate = MouseX.kr(100, SampleRate.ir) * [1, 1.2];
a = 1.1;
c = 0.13;
m = 1.0;
x = Dbufrd(b); // read from buffer
x = x * a + c % m;
z = Duty.ar(1 / rate, 0, Dbufwr(x, b));// write to buffer
// insert a delay and some amplitude modulation
z = LFSaw.ar(MouseY.kr(1, 10000, 1)) * z;
z = DelayL.ar(z, 1, 1);
z = Duty.ar(1 / rate, 0, Dbufwr(z, b));// write to buffer
z * 0.1;
}.scope;
)
|
