1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
class:: Phasor
summary:: A resettable linear ramp between two levels.
categories:: UGens>Triggers, UGens>Buffer
Description::
Phasor is a linear ramp between start and end values. When its trigger
input crosses from non-positive to positive, Phasor's output will jump to
its reset position. Upon reaching the end of its ramp Phasor will wrap
back to its start.
note::
N.B. Since end is defined as the wrap point, its value is never
actually output.
::
note::
If one wants Phasor to output a signal with frequency teletype::freq:: oscillating between teletype::start:: and teletype::end::, then the rate should be teletype::(end - start) * freq / sr:: where teletype::sr:: is the sampling rate.
::
Phasor is commonly used as an index control with link::Classes/BufRd::
and link::Classes/BufWr:: .
classmethods::
method::ar, kr
argument::trig
When triggered, jump to resetPos (default: 0, equivalent to
start).
argument::rate
The amount of change per sample, i.e at a rate of 1 the value of
each sample will be 1 greater than the preceding sample.
argument::start
Start point of the ramp.
argument::end
End point of the ramp.
argument::resetPos
The value to jump to upon receiving a trigger.
Examples::
code::
// phasor controls sine frequency: end frequency matches a second sine wave.
(
{ var trig, rate, x, sr;
rate = MouseX.kr(0.2, 2, 1);
trig = Impulse.ar(rate);
sr = SampleRate.ir;
x = Phasor.ar(trig, rate / sr);
SinOsc.ar(
[
LinLin.kr(x, 0, 1, 600, 1000), // convert range from 0..1 to 600..1000
1000 // constant second frequency
], 0, 0.2)
}.play;
)
// two phasors control two sine frequencies: mouse y controls resetPos of the second
(
{ var trig, rate, x, sr;
rate = MouseX.kr(1, 200, 1);
trig = Impulse.ar(rate);
sr = SampleRate.ir;
x = Phasor.ar(trig, rate / sr, 0, 1, [0, MouseY.kr(0, 1)]);
SinOsc.ar(x * 500 + 500, 0, 0.2)
}.play;
)
// use phasor to index into a sound file
// allocate a buffer with a sound file
b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
// simple playback (more examples: see BufRd)
// Start and end here are defined as 0 and the number of frames in the buffer.
// This means that the Phasor will output values from 0 to numFrames - 1 before looping,
// which is perfect for driving BufRd. (See note above)
{ BufRd.ar(1, b.bufnum, Phasor.ar(0, BufRateScale.kr(b.bufnum), 0, BufFrames.kr(b.bufnum))) }.play;
// two phasors control two sound file positions: mouse y controls resetPos of the second
(
{ var trig, rate, framesInBuffer;
rate = MouseX.kr(0.1, 100, 1);
trig = Impulse.ar(rate);
framesInBuffer = BufFrames.kr(b.bufnum);
x = Phasor.ar(trig, BufRateScale.kr(b.bufnum), 0, framesInBuffer,
[0, MouseY.kr(0, framesInBuffer)]);
BufRd.ar(1, b.bufnum, x);
}.play;
)
::
|
