1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
// See CallOnce help for details on argument handling
CallOnce : Thunk {
value { |... args| ^this.prEvaluate(\valueArray, args) }
valueArray { |... args| ^this.prEvaluate(\valueArray, *args) }
valueEnvir { |... args| ^this.prEvaluate(\valueArrayEnvir, args) }
valueArrayEnvir { |... args| ^this.prEvaluate(\valueArrayEnvir, *args) }
prEvaluate { |selector, args|
^value ?? {
value = function.performList(selector, args);
function = nil;
value
}
}
}
// Cleanup functions are passed a flag.
// The flag is set false if nodes have already been freed by CmdPeriod
EventStreamCleanup {
var <>functions; // cleanup functions from child streams and parent stream
*new { ^super.new.clear }
copy {
^this.class.new.functions_(this.functions.copy)
}
clear {
functions = IdentitySet.new;
}
addFunction { |event, function |
if(event.isKindOf(Dictionary)) {
function = CallOnce(function);
functions.add(function);
event[\addToCleanup] = event[\addToCleanup].add(function);
};
^function
}
addNodeCleanup { |event, function |
if(event.isKindOf(Dictionary)) {
function = CallOnce(function);
functions.add(function);
event[\addToNodeCleanup] = event[\addToNodeCleanup].add(function);
};
^function
}
update { | event |
if(event.isKindOf(Dictionary)) {
functions.addAll(event[\addToNodeCleanup]);
functions.addAll(event[\addToCleanup]);
functions.removeAll(event[\removeFromCleanup]); // backwards compat.
functions = functions.reject(_.didEvaluate);
};
^event
}
exit { | event, freeNodes = true |
if(event.isKindOf(Dictionary)) {
this.update(event);
functions.do(_.value(freeNodes));
this.clear;
};
^event
}
terminate { | freeNodes = true |
functions.do(_.value(freeNodes));
this.clear
}
}
|
