1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
UnitTestGUI {
*new { |allTestClasses|
// UnitTest GUI written by Dan Stowell 2009.
var w, classlist, methodlist, lookUp;
w = Window.new("[UnitTest GUI]", Rect(100, 100, 415, 615), resizable: false);
w.addFlowLayout;
StaticText(w, Rect(0,0, 400, 50))
.string_("Select a category, then a test method, and press Enter\nHit 'i' to jump to the code file.\nHit 'p' to post a shortcut.")
.align_(\center);
classlist = ListView(w, Rect(0,0, 200, 600-40))
.items_(allTestClasses.asSortedArray.collect(_[0]))
.action_{|widg|
methodlist.items_(
allTestClasses.asSortedArray[widg.value][1].asSortedArray.collect(_[0])
)
};
methodlist = ListView(w, Rect(200,40, 200, 600-40));
methodlist.enterKeyAction_ {|widg|
allTestClasses.asSortedArray[classlist.value][1].asSortedArray[widg.value][1].value
};
lookUp = {|widg, char, mod|
var class, selector, method;
class = ("Test" ++ classlist.items[classlist.value]).asSymbol.asClass;
class !? {
selector = methodlist.items[methodlist.value].asSymbol;
method = class.findMethod(selector);
if(char == $i) {
if(method.notNil) { method.openCodeFile } { class.openCodeFile };
};
if(char == $p) {
"UnitTest.runTest(\"%:%\")".format(class, selector).postln;
}
};
};
methodlist.keyDownAction = lookUp;
classlist.keyDownAction = lookUp;
classlist.enterKeyAction_{|widg|
// mimic behaviour of pressing enter in methodlist
methodlist.enterKey;
};
classlist.value_(0);
classlist.doAction; // fills in the right-hand column
^w.front;
}
}
|
