1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
File : UnixFILE {
classvar <openDialogs;
*new { arg pathName, mode;
^super.new.open(pathName, mode);
}
*open { arg pathName, mode;
^super.new.open(pathName, mode);
}
*use { arg pathName, mode, function;
var file;
file = this.new(pathName, mode);
^{ function.value(file) }.protect({ file.close });
}
*delete { arg pathName;
_FileDelete
^this.primitiveFailed
}
*exists { arg pathName;
var file;
file = File(pathName,"r");
if (file.isOpen, { file.close; ^true });
^false
}
*getcwd {
var string;
this.prGetcwd(string = String.new(256));
^string
}
open { arg pathName, mode;
/* open the file. mode is a string passed
to fopen, so should be one of:
"r","w","a","rb","wb","ab","r+","w+","a+",
"rb+","wb+","ab+"
*/
if (this.prOpen(pathName, mode), {
this.addOpenFile;
});
}
close { // close the file
// the GC will not call this for you
this.prClose;
fileptr = nil;
openFiles.remove(this);
}
length { // returns the length of the file
_FileLength;
^this.primitiveFailed;
}
pos { // current file position
_FilePos
^this.primitiveFailed;
}
pos_ { arg toPos;
toPos = toPos.clip(0, this.length - 1);
this.seek(toPos, 0);
}
seek { arg offset = 0, origin = 0;
// origin is an integer, one of:
// 0 - from beginning of file
// 1 - from current position
// 2 - from end of file
_FileSeek
^this.primitiveFailed;
}
readAllString {
var string;
string = String.newClear(this.length);
this.read(string);
^string
}
readAllStringRTF {
^this.readAllString.stripRTF;
}
readAllStringHTML {
^this.readAllString.stripHTML;
}
readAllSignal {
var signal;
signal = Signal.newClear(this.length);
this.read(signal);
^signal
}
// PRIVATE
prOpen { arg pathName, mode;
/* open the file. mode is a string passed
to fopen, so should be one of:
"r","w","a","rb","wb","ab","r+","w+","a+",
"rb+","wb+","ab+"
*/
_FileOpen
^this.primitiveFailed;
}
prClose {
_FileClose
^this.primitiveFailed;
}
*prGetcwd { arg string;
_File_getcwd
^this.primitiveFailed;
}
}
Pipe : UnixFILE {
// pipe stdin to, or stdout from, a unix shell command.
*new { arg commandLine, mode;
^super.new.open(commandLine, mode);
}
open { arg commandLine, mode;
/* open the file. mode is a string passed
to popen, so should be one of:
"r","w"
*/
if (this.prOpen(commandLine, mode), {
this.addOpenFile;
});
}
close {
this.prClose;
fileptr = nil;
openFiles.remove(this);
}
prClose { // close the file
// the GC will not call this for you
_PipeClose
^this.primitiveFailed;
}
// PRIVATE
prOpen { arg pathName, mode;
/* open the file. mode is a string passed
to popen, so should be one of:
"r","w"
*/
_PipeOpen
^this.primitiveFailed;
}
}
|
