1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
class:: Fdef
summary:: lazy function proxy
categories:: Libraries>JITLib>Patterns
related:: Classes/Pdef, Classes/Tdef, Classes/Pdefn, Classes/Ndef
description::
Placeholder for functions to calculate with.
See also: link::Classes/Maybe:: and the link::Overviews/JITLib:: overview.
ClassMethods::
private::initClass
method::new
argument::key
if no instance exists with this name, create a new one, otherwise return the existing one.
argument::val
If a link::Classes/Function:: is given, replace the old function with the new one.
Examples::
code::
Fdef(\x, { 8 + 9 });
Fdef(\y, Fdef(\x) - 3);
Fdef(\y).value;
Fdef(\x, 3);
Fdef(\y).value;
Fdef(\x, { |x=0| x });
Fdef(\x).value(8);
Fdef(\y).value(8);
z = Fdef(\x) * Fdef(\y) + { 1.0.rand };
z.value;
z.value(400);
::
code::
// sound example
(
s.boot;
SynthDef("gpdef",
{ arg out=0, freq=440, sustain=0.05, amp=0.1;
var env;
env = EnvGen.kr(Env.perc(0.01, sustain), doneAction:2) * amp;
Out.ar(out, SinOsc.ar(freq, 0, env))
}).add;
)
// fork a thread that plays some sounds
(
Fdef(\freq, 440);
Fdef(\dur, 0.2);
fork {
loop {
s.sendMsg("/s_new", "gpdef", -1, 1,1, \freq, Fdef(\freq).value);
Fdef(\dur).value.wait;
}
};
)
// some modifications
Fdef(\freq, Fdef(\midinote, 60).midicps);
Fdef(\midinote, { [67, 64, 65].choose });
Fdef(\midinote, { [67, 64, 65].choose } + Fdef(\offset));
Fdef(\offset, { 4.rand });
Fdef(\dur, 0.23);
::
|
