1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
|
//watches a server address for node-related messages
AbstractNodeWatcher {
var <server, <responders;
var <isWatching=false;
*new { arg server;
^super.new.ninit(server)
}
ninit { arg argServer;
var cmds;
server = argServer;
this.clear;
responders = [];
server.addr.asArray.do({ arg addrItem; //support for multiple addresses
this.cmds.do({ arg cmd;
var method;
method = cmd.copyToEnd(1).asSymbol;
responders = responders.add(
OSCFunc({ arg msg; this.respond(method, msg) }, cmd, addrItem)
.permanent_(true)
.disable
)
});
});
}
clear {}
cmds { ^nil }
respond { arg method, msg;
this.performList(method, msg.drop(1))
}
start {
if(isWatching.not, {
responders.do({ arg item; item.enable });
isWatching = true;
})
}
stop {
if(isWatching, {
responders.do({ arg item; item.free });
isWatching = false;
this.free;
})
}
}
BasicNodeWatcher : AbstractNodeWatcher {
var <nodes;
nodeIsPlaying { arg nodeID;
^nodes.includes(nodeID);
}
nodeIsPlaying_ { arg nodeID;
//sometimes it is needed to set this before the server reply
^nodes.add(nodeID);
}
clear {
nodes = IdentitySet.new;
}
cmds { ^#["/n_go", "/n_end"] }
n_end { arg nodeID;
nodes.remove(nodeID);
}
n_go { arg nodeID;
nodes.add(nodeID);
}
}
///////////////////////////////////
//watches registered nodes and sets their isPlaying/isRunning flag.
//a node needs to be registered to be addressed, other nodes are ignored.
NodeWatcher : BasicNodeWatcher {
classvar <>all;
*initClass {
all = IdentityDictionary.new;
CmdPeriod.add(this);
}
*cmdPeriod { all.do { arg item; item.clear } }
*newFrom { arg server;
var res;
res = all.at(server.name);
if(res.isNil, {
res = this.new(server);
res.start;
all.put(server.name, res)
});
^res
}
*register { arg node, assumePlaying=false;
var watcher;
watcher = this.newFrom(node.server);
watcher.register(node, assumePlaying);
}
*unregister { arg node;
var watcher;
watcher = this.newFrom(node.server);
watcher.unregister(node);
}
cmds { ^#["/n_go", "/n_end", "/n_off", "/n_on"] }
respond { arg method, msg;
var node, group;
node = nodes.at(msg.at(1));
if(node.notNil, {
group = nodes.at(msg.at(2));
this.performList(method, node, group)
})
}
clear {
// we must copy 'nodes'
// b/c a /n_end dependant might add or remove nodes
// from the collection
// NEVER iterate over a collection that might change
nodes.copy.do({ arg node;
node.isPlaying = false;
node.isRunning = false;
node.changed(\n_end);
});
nodes = IdentityDictionary.new
}
register { arg node, assumePlaying=false;
if(server.serverRunning.not) { nodes.removeAll; ^this };
if(isWatching) {
if(assumePlaying and: { nodes.at(node.nodeID).isNil }) { node.isPlaying = true };
nodes.put(node.nodeID, node);
};
}
unregister { arg node;
nodes.removeAt(node.nodeID);
}
//////////////private implementation//////////////
n_go { arg node;
node.isPlaying = true;
node.isRunning = true;
node.changed(\n_go); // notify all the node's dependents of the change
}
n_end { arg node;
this.unregister(node);
node.isPlaying = false;
node.isRunning = false;
node.changed(\n_end);
}
n_off { arg node;
node.isRunning = false;
node.changed(\n_off);
}
n_on { arg node;
node.isRunning = true;
node.changed(\n_on);
}
}
DebugNodeWatcher : BasicNodeWatcher {
cmds { ^#["/n_go", "/n_end", "/n_off", "/n_on"] }
//////////////private implementation//////////////
doPost { arg action, nodeID, groupID, prevID, nextID;
Post << ("[ server: " + server.name + "]" +
action + nodeID + "in group" + groupID + "between nodes" + prevID + "and" + nextID
) << Char.nl
}
n_go { arg nodeID, groupID, prevID, nextID;
this.doPost("started", nodeID, groupID, prevID, nextID);
nodes.add(nodeID);
}
n_end { arg nodeID, groupID, prevID, nextID;
nodes.remove(nodeID);
this.doPost("ended", nodeID, groupID, prevID, nextID);
}
n_off { arg nodeID, groupID, prevID, nextID;
this.doPost("turned off", nodeID, groupID, prevID, nextID);
}
n_on { arg nodeID, groupID, prevID, nextID;
this.doPost("turned on", nodeID, prevID, nextID);
}
}
|
