1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
OSCresponder {
classvar <>all;
var <>addr, <cmdName, <>action;
var <cmdNameWithoutSlash;
*new { arg addr, cmdName, action;
^super.new.init(addr, cmdName, action);
}
*initClass {
all = Set.new;
}
init { arg argAddr, argCmdName, argAction;
addr = argAddr;
action = argAction;
this.cmdName = argCmdName;
}
cmdName_ { arg string;
string = string.asString;
if(string[0] == $/) { string = string.drop(1) };
cmdNameWithoutSlash = string.asSymbol;
cmdName = ("/" ++ string).asSymbol;
}
*respond { arg time, addr, msg;
var cmdName, hit = false;
#cmdName = msg;
all.do { |resp|
if(
(resp.cmdName === cmdName)
or:
{ resp.cmdNameWithoutSlash === cmdName }
and: { addr.matches(resp.addr) }
) {
resp.value(time, msg, addr);
hit = true;
};
};
^hit
}
*add { arg responder;
var old;
old = all.findMatch(responder);
if(old.notNil,{ all.remove(old) });
all.add(responder);
}
*remove { arg responder;
all.remove(responder);
}
*removeAddr { arg addr;
all = all.reject({ arg item;
item.addr == addr
});
}
value { arg time, msg, addr;
action.value(time, this, msg, addr);
}
== { arg that;
^that respondsTo: #[\cmdName, \addr]
and: { cmdName == that.cmdName and: { addr == that.addr }}
}
hash {
^addr.hash bitXor: cmdName.hash
}
add { this.class.add(this); }
remove { all.remove(this) }
removeWhenDone {
var func;
func = action;
action = { arg time, responder, msg, addr;
func.value(time, responder, msg, addr);
this.remove;
}
}
}
//used to manage OSCresponderNodes. do not use directly.
OSCMultiResponder : OSCresponder {
var <>nodes;
value { arg time, msg, addr;
var iterlist;
iterlist = nodes.copy;
iterlist.do({ arg node; node.value(time, msg, addr) });
}
isEmpty { ^nodes.size == 0 }
}
OSCresponderNode : OSCresponder {
var <added = false;
add {
var made, found;
if(added.not, {
made = OSCMultiResponder(addr, cmdName);
found = all.findMatch(made);
if(found.isNil, { made.nodes = [this]; made.add; added = true; ^this });
if (found.class === OSCresponder, {
found.remove;
made.nodes = [found, this];
made.add;
},{
found.nodes = found.nodes.add(this)
});
added = true;
})
}
removeWhenDone {
var func;
func = action;
action = { arg time, responder, msg, addr;
func.value(time, responder, msg, addr);
this.remove;
}
}
remove {
var resp, alreadyThere;
resp = OSCMultiResponder(addr, cmdName);
alreadyThere = all.findMatch(resp);
if(alreadyThere.notNil)
{
alreadyThere.nodes.remove(this);
if(alreadyThere.isEmpty, { alreadyThere.remove });
added = false;
};
}
value { arg time, msg, addr;
action.value(time, this, msg, addr);
}
}
|
