1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
class:: Prout
summary:: routine pattern
related:: Classes/Routine
categories:: Streams-Patterns-Events>Patterns>Function
description::
note that there is a shortcut to create a Prout:
code::p(func)::
ClassMethods::
method::new
Returns a routine from the function.
argument::routineFunc
routine function.
Examples::
code::
(
var a;
a = Prout({ loop { 1.yield; 2.yield; 7.yield; 10.do { 1.0.rand.yield } }});
a.asStream.nextN(100).plot;
)
// sound example
(
SynthDef(\help_sinegrain,
{ arg out=0, freq=440, sustain=0.05;
var env;
env = EnvGen.kr(Env.perc(0.01, sustain, 0.1), doneAction:2);
Out.ar(out, SinOsc.ar(freq, 0, env))
}).add;
)
(
var a;
a = Prout({ loop { 1.yield; 2.yield; 7.yield; 10.do { 1.0.rand.yield } }}).asStream;
{
a.do { |val|
Synth(\help_sinegrain, [\freq, val * 100 + 300]);
0.02.wait;
}
}.fork;
)
// shortcut:
(
Pbind(
\instrument, \help_sinegrain,
\freq, p { loop { ([1000, 2000].choose + [100, 200].choose + [10, 20].choose).postln.yield } },
\dur, 0.1
).play;
)
::
|
