1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
|
/* $Id: dragdrop.pl,v 1.9 2002/02/01 15:04:49 jan Exp $
Part of XPCE --- The SWI-Prolog GUI toolkit
Author: Jan Wielemaker and Anjo Anjewierden
E-mail: jan@swi.psy.uva.nl
WWW: http://www.swi.psy.uva.nl/projects/xpce/
Copyright (C): 1985-2002, University of Amsterdam
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module(drag_and_drop, []).
:- use_module(library(pce)).
:- require([ default/3
, ignore/1
]).
/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Define a gesture that allows to `drag-and-drop' objects. The target on
which to drop should understand the method ->drop, which will be called
with the dropped graphical as an argument. If may also implement
->preview_drop, which will be called to provide visual feedback of the
drop that will take place when the button is released here.
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */
:- pce_begin_class(drag_and_drop_gesture, gesture,
"Drag and drop command-gesture").
variable(target, graphical*, get, "Drop target").
variable(warp, bool, both, "Pointer in center?").
variable(offset, point, get, "Offset X-y <->caret pointer").
variable(get_source, function*, both, "Function to map the source").
variable(source, any, get, "Current source").
variable(active_cursor, cursor*, get, "@nil: activated").
class_variable(warp, bool, '@on',
"Pointer in center?").
class_variable(button, button_name, left,
"Button on which gesture operates").
class_variable(cursor, cursor*, cross_reverse,
"Cursor to display. @nil: use graphical").
active_distance(_G, D) :-
D > 5.
initialise(G, But:button=[button_name],
M:modifier=[modifier], W:warp=[bool],
S:get_source=[function]*) :->
"Create from button, modifiers and warp"::
send(G, send_super, initialise, But, M),
default(W, class_variable(G, warp), Warp),
default(S, @nil, GS),
send(G, warp, Warp),
send(G, get_source, GS),
send(G, slot, offset, new(point)).
verify(_G, Ev:event) :->
"Only accept as single-click"::
get(Ev, multiclick, single).
initiate(G, Ev:event) :->
"Change the cursor"::
get(Ev, receiver, Gr),
get(Ev, position, Gr, Offset),
send(G?offset, copy, Offset),
send(G, set_source, Ev),
get(G, cursor, Gr, Cursor),
send(G, slot, active_cursor, Cursor).
set_source(G, Ev:event) :->
"Find source from event"::
get(Ev, receiver, Gr),
get(G, get_source, Function),
( Function == @nil
-> send(G, slot, source, Gr)
; get(Function, '_forward', Gr, Source),
send(G, slot, source, Source)
).
cursor(G, Gr, Cursor:cursor) :<-
"Create cursor from the graphical"::
( get(G, slot, cursor, Cursor),
send(Cursor, instance_of, cursor)
-> true
; get(G, class_variable_value, cursor, Cursor),
Cursor \== @nil
-> true
; get(Gr?area, size, size(W, H)),
( get(G, warp, @on)
-> new(HotSpot, point(W/2, H/2)),
send(Gr, pointer, HotSpot),
send(G?offset, copy, HotSpot)
; get(G, offset, HotSpot)
),
new(BM, image(@nil, W, H)),
send(BM, draw_in, Gr, point(0,0)),
send(BM, or, image('cross.bm'), point(HotSpot?x-8, HotSpot?y-8)),
new(Cursor, cursor(@nil, BM, @default, HotSpot))
).
drag(G, Ev:event) :->
"Find possible ->drop target"::
( get(G, active_cursor, Cursor),
Cursor \== @nil
-> ( get(Ev, click_displacement, D),
active_distance(G, D)
-> send(Ev?window, focus_cursor, Cursor),
send(G, slot, active_cursor, @nil),
send(G, drag, Ev)
; true
)
; get(G, source, Source),
( get(Ev, inside_sub_window, Frame),
get(Ev, inside_sub_window, Frame, Window),
get(Window, find, Ev,
and(@arg1 \== Source,
or(and(G?target == @arg1,
message(G, move_target, Ev)),
message(G, target, Source, Ev, @arg1))),
_Gr)
-> true
; send(G, target, Source, @nil, @nil)
)
).
:- pce_global(@dd_dummy_point, new(point)).
move_target(G, Ev:event) :->
"The user is dragging the object over a drop-zone"::
get(G, target, Target),
get(G, source, Source),
( get(Target, send_method, preview_drop, tuple(_, Method)),
get(Method, argument_type, 1, Type),
get(Type, check, Source, Src),
get(Method, argument_type, 2, PosType),
send(PosType, validate, @dd_dummy_point)
-> get(Ev, position, Target, Pos),
get(Pos, copy, P2),
send(P2, minus, G?offset),
send(Target, preview_drop, Src, P2)
; true
).
target(G, Source:any, Ev:event*, Gr:graphical*) :->
"Make the given object the target"::
( Gr == @nil
; get(Gr, is_displayed, @on),
send(Gr, has_send_method, drop)
),
ignore((get(G, target, Old),
send(Old, has_send_method, preview_drop),
send(Old, preview_drop, @nil))),
( get(Gr, send_method, preview_drop, tuple(_, Method)),
get(Method, argument_type, 1, Type),
get(Type, check, Source, Src)
-> ( get(Method, argument_type, 2, PosType),
send(PosType, validate, @dd_dummy_point)
-> get(Ev, position, Gr, Pos),
get(Pos, copy, P2),
send(P2, minus, G?offset),
send(Gr, preview_drop, Src, P2)
; send(Gr, preview_drop, Src)
)
; true
),
send(G, slot, target, Gr).
terminate(G, Ev:event) :->
"->drop to <-target"::
( get(G, active_cursor, Cursor),
Cursor \== @nil
-> send(G, slot, active_cursor, @nil),
send(G, cancel)
; get(G, slot, target, Target),
send(Ev?window, focus_cursor, @nil),
% send(G, cursor, @default),
get(G, source, Source),
( Target == @nil
-> true
; send(G, target, Source, @nil, @nil),
get(Target, send_method, drop, tuple(_, Method)),
get(Method, argument_type, 1, T1),
get(T1, check, Source, Src),
get(Target, display, Display),
( get(Method, argument_type, 2, Type),
send(Type, validate, @dd_dummy_point)
-> get(Ev, position, Target, Pos),
get(Pos, copy, P2),
send(P2, minus, G?offset),
send(Display, busy_cursor),
ignore(send(Target, drop, Src, P2)),
send(Display, busy_cursor, @nil)
; send(Display, busy_cursor, @default),
ignore(send(Target, drop, Src)),
send(Display, busy_cursor, @nil)
)
),
send(G, slot, source, @nil)
).
:- pce_end_class.
|
