1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
/* $Id: apply.pl,v 1.5 2002/02/01 16:49:10 jan Exp $
Part of SWI-Prolog
Author: Jan Wielemaker
E-mail: jan@swi.psy.uva.nl
WWW: http://www.swi-prolog.org
Copyright (C): 1985-2002, University of Amsterdam
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module($apply, [
checklist/2,
maplist/3,
sublist/3,
forall/2]).
:- module_transparent
checklist/2,
checklist2/2,
maplist/3,
maplist2/3,
sublist/3,
forall/2.
% checklist(+Goal, +List)
%
% True if Goal can succesfully be applied on all elements of List.
% Arguments are reordered to gain performance as well as to make
% the predicate deterministic under normal circumstances.
checklist(Goal, List) :-
checklist2(List, Goal).
checklist2([], _).
checklist2([Elem|Tail], Goal) :-
call(Goal, Elem),
checklist2(Tail, Goal).
% maplist(+Goal, +List1, ?List2)
% True if Goal can succesfully be applied to all succesive pairs
% of elements of List1 and List2.
maplist(Goal, List1, List2) :-
maplist2(List1, List2, Goal).
maplist2([], [], _).
maplist2([Elem1|Tail1], [Elem2|Tail2], Goal) :-
call(Goal, Elem1, Elem2),
maplist2(Tail1, Tail2, Goal).
% sublist(+Goal, +List1, ?List2)
% Succeeds if List2 unifies with a list holding those terms for wich
% apply(Goal, Elem) succeeds.
sublist(_, [], []) :- !.
sublist(Goal, [H|T], Sub) :-
call(Goal, H), !,
Sub = [H|R],
sublist(Goal, T, R).
sublist(Goal, [_|T], R) :-
sublist(Goal, T, R).
% forall(+Condition, +Action)
% True if Action if true for all variable bindings for which Condition
% if true.
forall(Cond, Action) :-
\+ (Cond, \+ Action).
% call_cleanup(:Goal, :Cleanup)
%
% Calls Goal as call/1 and executes Cleanup whenever Goal finishes
% due to deterministic success, failure, exception or cut.
|
