1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
|
/* $Id: readutil.pl,v 1.3 2002/02/01 16:49:11 jan Exp $
Part of SWI-Prolog
Author: Jan Wielemaker
E-mail: jan@swi.psy.uva.nl
WWW: http://www.swi-prolog.org
Copyright (C): 1985-2002, University of Amsterdam
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module(read_util,
[ read_line_to_codes/2, % +Fd, -Codes (without trailing \n)
read_line_to_codes/3, % +Fd, -Codes, ?Tail
read_stream_to_codes/2, % +Fd, -Codes
read_stream_to_codes/3, % +Fd, -Codes, ?Tail
read_file_to_codes/3, % +File, -Codes, +Options
read_file_to_terms/3 % +File, -Terms, +Options
]).
/*******************************
* LINES *
*******************************/
% read_line_to_codes(+Fd, -Line)
%
% Read a line of input from stream into a list of character codes.
% Trailing newline and or ret are deleted.
read_line_to_codes(Fd, Codes) :-
get_code(Fd, C0),
read_1line_to_codes(C0, Fd, Codes0),
Codes = Codes0.
read_1line_to_codes(-1, _, []) :- !.
read_1line_to_codes(10, _, []) :- !.
read_1line_to_codes(13, Fd, L) :- !,
get_code(Fd, C2),
read_1line_to_codes(C2, Fd, L).
read_1line_to_codes(C, Fd, [C|T]) :-
get_code(Fd, C2),
read_1line_to_codes(C2, Fd, T).
% read_line_to_codes(+Fd, -Line, ?Tail)
%
% Read a line of input as a difference list. This should be used
% to read multiple lines efficiently.
read_line_to_codes(Fd, Codes, Tail) :-
get_code(Fd, C0),
read_line_to_codes(C0, Fd, Codes0, Tail),
Codes = Codes0.
read_line_to_codes(-1, _, Tail, Tail) :- !.
read_line_to_codes(10, _, [10|Tail], Tail) :- !.
read_line_to_codes(C, Fd, [C|T], Tail) :-
get_code(Fd, C2),
read_line_to_codes(C2, Fd, T, Tail).
/*******************************
* STREAM (ENTIRE INPUT) *
*******************************/
% read_stream_to_codes(+Stream, -Codes, [?Tail]).
read_stream_to_codes(Fd, Codes) :-
read_stream_to_codes(Fd, Codes, []).
read_stream_to_codes(Fd, Codes, Tail) :-
get_code(Fd, C0),
read_stream_to_codes(C0, Fd, Codes0, Tail),
Codes = Codes0.
read_stream_to_codes(-1, _, Tail, Tail) :- !.
read_stream_to_codes(C, Fd, [C|T], Tail) :-
get_code(Fd, C2),
read_stream_to_codes(C2, Fd, T, Tail).
% read_stream_to_terms(+Stream, -Terms, [?Tail]).
read_stream_to_terms(Fd, Terms) :-
read_stream_to_terms(Fd, Terms, []).
read_stream_to_terms(Fd, Terms, Tail) :-
read(Fd, C0),
read_stream_to_terms(C0, Fd, Terms0, Tail),
Terms = Terms0.
read_stream_to_terms(end_of_file, _, Tail, Tail) :- !.
read_stream_to_terms(C, Fd, [C|T], Tail) :-
read(Fd, C2),
read_stream_to_terms(C2, Fd, T, Tail).
/*******************************
* FILE (ENTIRE INPUT) *
*******************************/
% read_file_to_codes(+Spec, -Codes, +Options)
read_file_to_codes(Spec, Codes, Options) :-
( select(tail(Tail), Options, Options1)
-> true
; Tail = []
),
split_options(Options1, FileOptions, OpenOptions),
absolute_file_name(Spec,
[ access(read)
| FileOptions
],
Path),
open(Path, read, Fd, OpenOptions),
read_stream_to_codes(Fd, Codes0, Tail),
close(Fd),
Codes = Codes0.
file_option(extensions(_)).
file_option(file_type(_)).
file_option(file_errors(_)).
split_options([], [], []).
split_options([H|T], File, Open) :-
( file_option(H)
-> File = [H|FT],
OT = Open
; Open = [H|OT],
FT = File
),
split_options(T, FT, OT).
% read_file_to_terms(+Spec, -Terms, +Options)
read_file_to_terms(Spec, Terms, Options) :-
( select(tail(Tail), Options, Options1)
-> true
; Tail = [],
Options1 = Options
),
split_options(Options1, FileOptions, OpenOptions),
absolute_file_name(Spec,
[ access(read)
| FileOptions
],
Path),
open(Path, read, Fd, OpenOptions),
read_stream_to_terms(Fd, Terms0, Tail),
close(Fd),
Terms = Terms0.
|
