File: nb_set.pl

package info (click to toggle)
swi-prolog 8.0.2+dfsg-3+deb10u1
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 72,036 kB
  • sloc: ansic: 349,612; perl: 306,654; java: 5,208; cpp: 4,436; sh: 3,042; ruby: 1,594; yacc: 845; makefile: 136; xml: 82; sed: 12; sql: 6
file content (164 lines) | stat: -rw-r--r-- 5,625 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
/*  Part of SWI-Prolog

    Author:        Jan Wielemaker
    E-mail:        J.Wielemaker@vu.nl
    WWW:           http://www.swi-prolog.org
    Copyright (c)  2005-2015, VU University Amsterdam
    All rights reserved.

    Redistribution and use in source and binary forms, with or without
    modification, are permitted provided that the following conditions
    are met:

    1. Redistributions of source code must retain the above copyright
       notice, this list of conditions and the following disclaimer.

    2. Redistributions in binary form must reproduce the above copyright
       notice, this list of conditions and the following disclaimer in
       the documentation and/or other materials provided with the
       distribution.

    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
    POSSIBILITY OF SUCH DAMAGE.
*/

:- module(nb_set,
          [ empty_nb_set/1,             % -EmptySet
            add_nb_set/2,               % +Key, !Set
            add_nb_set/3,               % +Key, !Set, ?New
            gen_nb_set/2,               % +Set, -Key
            size_nb_set/2,              % +Set, -Size
            nb_set_to_list/2            % +Set, -List
          ]).
:- use_module(library(lists)).
:- use_module(library(terms)).
:- use_module(library(apply_macros), []).

/** <module> Non-backtrackable sets

This library provides  a  non-backtrackabe  _set_   of  terms  that  are
variants of each other. It is primarily intended to implement distinct/1
from library(solution_sequences). The set is implemented as a hash table
that is built using non-backtrackable primitives, notably nb_setarg/3.

The original version of this library   used  binary trees which provides
immediate ordering. As the trees were   not  balanced, performance could
get   really   poor.   The   complexity   of   balancing   trees   using
non-backtrackable primitives is too high.

@author Jan Wielemaker
*/

initial_size(32).                       % initial hash-table size

%!  empty_nb_set(-Set)
%
%   Create an empty non-backtrackable set.

empty_nb_set(nb_set(Buckets, 0)) :-
    initial_size(Size),
    '$filled_array'(Buckets, buckets, Size, []).

%!  add_nb_set(+Key, !Set) is det.
%!  add_nb_set(+Key, !Set, ?New) is semidet.
%!  add_nb_set(+Key, !Set, ?New) is semidet.
%
%   Insert Key into the set. If  a   variant  (see  =@=/2) of Key is
%   already in the set, the set is unchanged and New is unified with
%   `false`. Otherwise, New is unified with   `true` and a _copy of_
%   Key is added to the set.
%
%   @tbd    Computing the hash for cyclic terms is performed with
%           the help of term_factorized/3, which performs rather
%           poorly.

add_nb_set(Key, Set) :-
    add_nb_set(Key, Set, _).
add_nb_set(Key, Set, New) :-
    arg(1, Set, Buckets),
    compound_name_arity(Buckets, _, BCount),
    hash_key(Key, BCount, Hash),
    arg(Hash, Buckets, Bucket),
    (   member(X, Bucket),
        Key =@= X
    ->  New = false
    ;   New = true,
        duplicate_term(Key, Copy),
        nb_linkarg(Hash, Buckets, [Copy|Bucket]),
        arg(2, Set, Size0),
        Size is Size0+1,
        nb_setarg(2, Set, Size),
        (   Size > BCount
        ->  rehash(Set)
        ;   true
        )
    ).

%!  hash_key(+Term, +BucketCount, -Key) is det.
%
%   Compute a hash for Term. Note that variant_hash/2 currently does
%   not handle cyclic terms, so use  term_factorized/3 to get rid of
%   the cycles. This means that  this   library  is rather slow when
%   cyclic terms are involved.

:- if(catch((A = f(A), variant_hash(A,_)), _, fail)).
hash_key(Term, BCount, Key) :-
    variant_hash(Term, IntHash),
    Key is (IntHash mod BCount)+1.
:- else.
hash_key(Term, BCount, Key) :-
    acyclic_term(Key),
    !,
    variant_hash(Term, IntHash),
    Key is (IntHash mod BCount)+1.
hash_key(Term, BCount, Key) :-
    term_factorized(Term, Skeleton, Substiution),
    variant_hash(Skeleton+Substiution, IntHash),
    Key is (IntHash mod BCount)+1.
:- endif.

rehash(Set) :-
    arg(1, Set, Buckets0),
    compound_name_arity(Buckets0, Name, Arity0),
    Arity is Arity0*2,
    '$filled_array'(Buckets, Name, Arity, []),
    nb_setarg(1, Set, Buckets),
    nb_setarg(2, Set, 0),
    forall(( arg(_, Buckets0, Chain),
             member(Key, Chain)
           ),
           add_nb_set(Key, Set, _)).

%!  nb_set_to_list(+Set, -List)
%
%   Get the elements of a an nb_set. List is sorted to the standard
%   order of terms.

nb_set_to_list(nb_set(Buckets, _Size), OrdSet) :-
    compound_name_arguments(Buckets, _, Args),
    append(Args, List),
    sort(List, OrdSet).

%!  gen_nb_set(+Set, -Key)
%
%   Enumerate the members of a set in the standard order of terms.

gen_nb_set(Set, Key) :-
    nb_set_to_list(Set, OrdSet),
    member(Key, OrdSet).

%!  size_nb_set(+Set, -Size)
%
%   Unify Size with the number of elements in the set

size_nb_set(nb_set(_, Size), Size).