File: shell.pl

package info (click to toggle)
swi-prolog 8.0.2+dfsg-3+deb10u1
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 72,036 kB
  • sloc: ansic: 349,612; perl: 306,654; java: 5,208; cpp: 4,436; sh: 3,042; ruby: 1,594; yacc: 845; makefile: 136; xml: 82; sed: 12; sql: 6
file content (412 lines) | stat: -rw-r--r-- 10,630 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
/*  Part of SWI-Prolog

    Author:        Jan Wielemaker
    E-mail:        J.Wielemaker@vu.nl
    WWW:           http://www.swi-prolog.org
    Copyright (c)  1985-2018, University of Amsterdam
                              VU University Amsterdam
                              CWI, Amsterdam
    All rights reserved.

    Redistribution and use in source and binary forms, with or without
    modification, are permitted provided that the following conditions
    are met:

    1. Redistributions of source code must retain the above copyright
       notice, this list of conditions and the following disclaimer.

    2. Redistributions in binary form must reproduce the above copyright
       notice, this list of conditions and the following disclaimer in
       the documentation and/or other materials provided with the
       distribution.

    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
    POSSIBILITY OF SUCH DAMAGE.
*/

:- module(shell,
          [ shell/0,
            ls/0,
            ls/1,                               % +Pattern
            cd/0,
            cd/1,                               % +Dir
            pushd/0,
            pushd/1,                            % +Dir
            dirs/0,
            pwd/0,
            popd/0,
            mv/2,                               % +File1, +File2
            rm/1                                % +File1
          ]).
:- use_module(library(lists), [nth1/3]).
:- use_module(library(error)).
:- use_module(library(apply)).
:- set_prolog_flag(generate_debug_info, false).

/** <module>  Elementary shell commands

This library provides some  basic  (POSIX)   shell  commands  defined in
Prolog, such as `pwd` and `ls` for   situations  where there is no shell
available or the shell output cannot be captured.
*/

%!  shell
%
%   Execute an interactive shell. The  following   options  are tried to
%   find a suitable shell command:
%
%     1. The Prolog flag `shell`
%     2. The environment variable ``$SHELL``
%     3. The Prolog flag `posix_shell`
%     4. The environment variable ``%comspec%`` (Windows only)
%
%   @error existence_error(config, shell) if no suitable shell can be
%   found.

shell :-
    interective_shell(Shell),
    access_file(Shell, execute),
    !,
    shell(Shell).
shell :-
    existence_error(config, shell).

interective_shell(Shell) :-
    current_prolog_flag(shell, Shell).
interective_shell(Shell) :-
    getenv('SHELL', Shell).
interective_shell(Shell) :-
    current_prolog_flag(posix_shell, Shell).
interective_shell(Shell) :-
    current_prolog_flag(windows, true),
    getenv(comspec, Shell).             % Windows


%!  cd.
%!  cd(Dir).
%
%   Change working directory

cd :-
    cd(~).

cd(Dir) :-
    name_to_file(Dir, Name),
    working_directory(_, Name).

%!  pushd.
%!  pushd(+Dir).
%!  popd.
%!  dirs.
%
%   Manage the _directory stack_:
%
%     - pushd/1 is as cd/1, pushing th old directory on a stack
%     - pushd/0 swaps the current directory with the top of the
%       stack
%     - popd/0 pops to the top of the stack
%     - dirs/0 lists the current directory and the stack.

:- dynamic
    stack/1.

pushd :-
    pushd(+1).

pushd(N) :-
    integer(N),
    !,
    findall(D, stack(D), Ds),
    (   nth1(N, Ds, Go),
        retract(stack(Go))
    ->  pushd(Go),
        print_message(information, shell(directory(Go)))
    ;   warning('Directory stack not that deep', []),
        fail
    ).
pushd(Dir) :-
    name_to_file(Dir, Name),
    working_directory(Old, Name),
    asserta(stack(Old)).

popd :-
    retract(stack(Dir)),
    !,
    working_directory(_, Dir),
    print_message(information, shell(directory(Dir))).
popd :-
    warning('Directory stack empty', []),
    fail.

dirs :-
    working_directory(WD, WD),
    findall(D, stack(D), Dirs),
    maplist(dir_name, [WD|Dirs], Results),
    print_message(information, shell(file_set(Results))).

%!  pwd
%
%   Print current working directory

pwd :-
    working_directory(WD, WD),
    print_message(information, format('~w', [WD])).

dir_name('/', '/') :- !.
dir_name(Path, Name) :-
    atom_concat(P, /, Path),
    !,
    dir_name(P, Name).
dir_name(Path, Name) :-
    current_prolog_flag(unix, true),
    expand_file_name('~', [Home0]),
    (   atom_concat(Home, /, Home0)
    ->  true
    ;   Home = Home0
    ),
    atom_concat(Home, FromHome, Path),
    !,
    atom_concat('~', FromHome, Name).
dir_name(Path, Path).

%!  ls.
%!  ls(+Pattern).
%
%   Listing similar to Unix =ls -F=, flagging directories with =/=.

ls :-
    ls('.').

ls(Spec) :-
    name_to_files(Spec, Matches),
    ls_(Matches).

ls_([]) :-
    !,
    warning('No Match', []).
ls_([Dir]) :-
    exists_directory(Dir),
    !,
    atom_concat(Dir, '/*', Pattern),
    expand_file_name(Pattern, Files),
    maplist(tagged_file_in_dir, Files, Results),
    print_message(information, shell(file_set(Results))).
ls_(Files) :-
    maplist(tag_file, Files, Results),
    print_message(information, shell(file_set(Results))).

tagged_file_in_dir(File, Result) :-
    file_base_name(File, Base),
    (   exists_directory(File)
    ->  atom_concat(Base, /, Result)
    ;   Result = Base
    ).

tag_file(File, Dir) :-
    exists_directory(File),
    !,
    atom_concat(File, /, Dir).
tag_file(File, File).

%!  mv(+From, +To) is det.
%
%   Move (Rename) a file. If To is   a directory, From is moved into
%   the directory.  Uses expand_file_name/2 on the From argument.

mv(From, To) :-
    name_to_files(From, Src),
    name_to_new_file(To, Dest),
    mv_(Src, Dest).

mv_([One], Dest) :-
    \+ exists_directory(Dest),
    !,
    rename_file(One, Dest).
mv_(Multi, Dest) :-
    (   exists_directory(Dest)
    ->  maplist(mv_to_dir(Dest), Multi)
    ;   print_message(warning, format('Not a directory: ~w', [Dest])),
        fail
    ).

mv_to_dir(Dest, Src) :-
    file_base_name(Src, Name),
    atomic_list_concat([Dest, Name], /, Target),
    rename_file(Src, Target).

%!  rm(+File) is det.
%
%   Remove (unlink) a file

rm(File) :-
    name_to_file(File, A),
    delete_file(A).


%!  name_to_file(+Name, -File)
%
%   Convert Name into a single file.

name_to_file(Spec, File) :-
    name_to_files(Spec, Files),
    (   Files = [File]
    ->  true
    ;   print_message(warning, format('Ambiguous: ~w', [Spec])),
        fail
    ).

name_to_new_file(Spec, File) :-
    name_to_files(Spec, Files, false),
    (   Files = [File]
    ->  true
    ;   print_message(warning, format('Ambiguous: ~w', [Spec])),
        fail
    ).

name_to_files(Spec, Files) :-
    name_to_files(Spec, Files, true).
name_to_files(Spec, Files, Exists) :-
    name_to_files_(Spec, Files, Exists),
    (   Files == []
    ->  print_message(warning, format('No match: ~w', [Spec])),
        fail
    ;   true
    ).

name_to_files_(Spec, Files, _) :-
    compound(Spec),
    compound_name_arity(Spec, _Alias, 1),
    !,
    findall(File,
            (   absolute_file_name(Spec, File,
                                   [ access(exist),
                                     file_type(directory),
                                     file_errors(fail),
                                     solutions(all)
                                   ])
            ;   absolute_file_name(Spec, File,
                                   [ access(exist),
                                     file_errors(fail),
                                     solutions(all)
                                   ])
            ),
            Files).
name_to_files_(Spec, Files, Exists) :-
    file_name_to_atom(Spec, S1),
    expand_file_name(S1, Files0),
    (   Exists == true,
        Files0 == [S1],
        \+ access_file(S1, exist)
    ->  warning('"~w" does not exist', [S1]),
        fail
    ;   Files = Files0
    ).

file_name_to_atom(Spec, File) :-
    atomic(Spec),
    !,
    atom_string(File, Spec).
file_name_to_atom(Spec, File) :-
    phrase(segments(Spec), L),
    atomic_list_concat(L, /, File).

segments(Var) -->
    { var(Var),
      !,
      instantiation_error(Var)
    }.
segments(A/B) -->
    !,
    segments(A),
    segments(B).
segments(A) -->
    { must_be(atomic, A) },
    [ A ].

%!  warning(+Fmt, +Args:list) is det.

warning(Fmt, Args) :-
    print_message(warning, format(Fmt, Args)).

:- multifile prolog:message//1.

prolog:message(shell(file_set(Files))) -->
    { catch(tty_size(_, Width), _, Width = 80)
    },
    table(Files, Width).
prolog:message(shell(directory(Path))) -->
    { dir_name(Path, Name) },
    [ '~w'-[Name] ].

%!  table(+List, +Width)//
%
%   Produce a tabular layout to list all   elements of List on lines
%   with a maximum width of Width. Elements are placed as =ls= does:
%
%      ==
%      1  4  7
%      2  5  8
%      3  6
%      ==

table(List, Width) -->
    { table_layout(List, Width, Layout),
      compound_name_arguments(Array, a, List)
    },
    table(0, Array, Layout).

table(I, Array, Layout) -->
    { Cols = Layout.cols,
      Index is I // Cols + (I mod Cols) * Layout.rows + 1,
      (   (I+1) mod Cols =:= 0
      ->  NL = true
      ;   NL = false
      )
    },
    (   { arg(Index, Array, Atom) }
    ->  (   { NL == false }
        ->  [ '~|~w~t~*+'-[Atom, Layout.col_width] ]
        ;   [ '~w'-[Atom] ]
        )
    ;   []
    ),
    (   { I2 is I+1,
          I2 < Cols*Layout.rows
        }
    ->  (   { NL == true }
        ->  [ nl ]
        ;   []
        ),
        table(I2, Array, Layout)
    ;   []
    ).

table_layout(Atoms, Width, _{cols:Cols, rows:Rows, col_width:ColWidth}) :-
    length(Atoms, L),
    longest(Atoms, Longest),
    Cols is max(1, Width // (Longest + 3)),
    Rows is integer(L / Cols + 0.49999),    % should be ceil/1
    ColWidth is Width // Cols.

longest(List, Longest) :-
    longest(List, 0, Longest).

longest([], M, M) :- !.
longest([H|T], Sofar, M) :-
    atom_length(H, L),
    L >= Sofar,
    !,
    longest(T, L, M).
longest([_|T], S, M) :-
    longest(T, S, M).