File: BUILD.gn

package info (click to toggle)
swiftlang 6.0.3-2
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid, trixie
  • size: 2,519,992 kB
  • sloc: cpp: 9,107,863; ansic: 2,040,022; asm: 1,135,751; python: 296,500; objc: 82,456; f90: 60,502; lisp: 34,951; pascal: 19,946; sh: 18,133; perl: 7,482; ml: 4,937; javascript: 4,117; makefile: 3,840; awk: 3,535; xml: 914; fortran: 619; cs: 573; ruby: 573
file content (39 lines) | stat: -rw-r--r-- 812 bytes parent folder | download | duplicates (8) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
import("//llvm/utils/gn/build/compiled_action.gni")

template("gen") {
  compiled_action(target_name) {
    tool = "//clang-tools-extra/pseudo/gen:clang-pseudo-gen"
    inputs = [ "../lib/cxx/cxx.bnf" ]
    outputs = [ "$target_gen_dir/$target_name" ]
    args = [
      "--grammar",
      rebase_path(inputs[0], root_build_dir),
      "-o",
      rebase_path(outputs[0], root_build_dir),
      invoker.flag,
    ]
  }
}

gen("CXXSymbols.inc") {
  flag = "--emit-symbol-list"
}

gen("CXXBNF.inc") {
  flag = "--emit-grammar-content"
}

config("cxx_gen_config") {
  visibility = [ ":cxx_gen" ]
  include_dirs = [ target_gen_dir ]
}

group("cxx_gen") {
  deps = [
    ":CXXBNF.inc",
    ":CXXSymbols.inc",
  ]

  # Let targets depending on this find the generated files.
  public_configs = [ ":cxx_gen_config" ]
}