File: gen_version_script.gni

package info (click to toggle)
swiftlang 6.0.3-2
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid, trixie
  • size: 2,519,992 kB
  • sloc: cpp: 9,107,863; ansic: 2,040,022; asm: 1,135,751; python: 296,500; objc: 82,456; f90: 60,502; lisp: 34,951; pascal: 19,946; sh: 18,133; perl: 7,482; ml: 4,937; javascript: 4,117; makefile: 3,840; awk: 3,535; xml: 914; fortran: 619; cs: 573; ruby: 573
file content (38 lines) | stat: -rw-r--r-- 1,008 bytes parent folder | download | duplicates (14) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
import("//compiler-rt/target.gni")

template("gen_version_script") {
  if (current_os != "mac" && current_os != "win") {
    action(target_name) {
      script = "//compiler-rt/lib/sanitizer_common/scripts/gen_dynamic_list.py"
      sources = [ invoker.extra ]
      deps = invoker.libs
      outputs = [ invoker.output ]
      args = [
        "--version-list",
        "--extra",
        rebase_path(invoker.extra, root_build_dir),
      ]
      foreach(lib_name, invoker.lib_names) {
        args += [ rebase_path(
                "$crt_current_out_dir/libclang_rt.$lib_name$crt_current_target_suffix.a",
                root_build_dir) ]
      }
      args += [
        "--nm-executable",
        "nm",
        "-o",
        rebase_path(invoker.output, root_build_dir),
      ]
    }
  } else {
    source_set(target_name) {
    }
    not_needed(invoker,
               [
                 "extra",
                 "lib_names",
                 "libs",
                 "output",
               ])
  }
}