1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
|
// RUN: mlir-opt %s --test-next-access --split-input-file | FileCheck %s
// CHECK-LABEL: @trivial
func.func @trivial(%arg0: memref<f32>, %arg1: f32) -> f32 {
// CHECK: name = "store"
// CHECK-SAME: next_access = ["unknown", ["load"]]
memref.store %arg1, %arg0[] {name = "store"} : memref<f32>
// CHECK: name = "load"
// CHECK-SAME: next_access = ["unknown"]
%0 = memref.load %arg0[] {name = "load"} : memref<f32>
return %0 : f32
}
// CHECK-LABEL: @chain
func.func @chain(%arg0: memref<f32>, %arg1: f32) -> f32 {
// CHECK: name = "store"
// CHECK-SAME: next_access = ["unknown", ["load 1"]]
memref.store %arg1, %arg0[] {name = "store"} : memref<f32>
// CHECK: name = "load 1"
// CHECK-SAME: next_access = {{\[}}["load 2"]]
%0 = memref.load %arg0[] {name = "load 1"} : memref<f32>
// CHECK: name = "load 2"
// CHECK-SAME: next_access = ["unknown"]
%1 = memref.load %arg0[] {name = "load 2"} : memref<f32>
%2 = arith.addf %0, %1 : f32
return %2 : f32
}
// CHECK-LABEL: @branch
func.func @branch(%arg0: memref<f32>, %arg1: f32, %arg2: i1) -> f32 {
// CHECK: name = "store"
// CHECK-SAME: next_access = ["unknown", ["load 1", "load 2"]]
memref.store %arg1, %arg0[] {name = "store"} : memref<f32>
cf.cond_br %arg2, ^bb0, ^bb1
^bb0:
%0 = memref.load %arg0[] {name = "load 1"} : memref<f32>
cf.br ^bb2(%0 : f32)
^bb1:
%1 = memref.load %arg0[] {name = "load 2"} : memref<f32>
cf.br ^bb2(%1 : f32)
^bb2(%phi: f32):
return %phi : f32
}
// CHECK-LABEL @dead_branch
func.func @dead_branch(%arg0: memref<f32>, %arg1: f32) -> f32 {
// CHECK: name = "store"
// CHECK-SAME: next_access = ["unknown", ["load 2"]]
memref.store %arg1, %arg0[] {name = "store"} : memref<f32>
cf.br ^bb1
^bb0:
// CHECK: name = "load 1"
// CHECK-SAME: next_access = "not computed"
%0 = memref.load %arg0[] {name = "load 1"} : memref<f32>
cf.br ^bb2(%0 : f32)
^bb1:
%1 = memref.load %arg0[] {name = "load 2"} : memref<f32>
cf.br ^bb2(%1 : f32)
^bb2(%phi: f32):
return %phi : f32
}
// CHECK-LABEL: @loop
func.func @loop(%arg0: memref<?xf32>, %arg1: f32, %arg2: index, %arg3: index, %arg4: index) -> f32 {
%c0 = arith.constant 0.0 : f32
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["outside", "loop"], "unknown"]
memref.load %arg0[%arg4] {name = "pre"} : memref<?xf32>
%l = scf.for %i = %arg2 to %arg3 step %arg4 iter_args(%ia = %c0) -> (f32) {
// CHECK: name = "loop"
// CHECK-SAME: next_access = {{\[}}["outside", "loop"], "unknown"]
%0 = memref.load %arg0[%i] {name = "loop"} : memref<?xf32>
%1 = arith.addf %ia, %0 : f32
scf.yield %1 : f32
}
%v = memref.load %arg0[%arg3] {name = "outside"} : memref<?xf32>
%2 = arith.addf %v, %l : f32
return %2 : f32
}
// CHECK-LABEL: @conditional
func.func @conditional(%cond: i1, %arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["post", "then"]]
memref.load %arg0[] {name = "pre"}: memref<f32>
scf.if %cond {
// CHECK: name = "then"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "then"} : memref<f32>
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @two_sided_conditional
func.func @two_sided_conditional(%cond: i1, %arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["then", "else"]]
memref.load %arg0[] {name = "pre"}: memref<f32>
scf.if %cond {
// CHECK: name = "then"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "then"} : memref<f32>
} else {
// CHECK: name = "else"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "else"} : memref<f32>
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @dead_conditional
func.func @dead_conditional(%arg0: memref<f32>) {
%false = arith.constant 0 : i1
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "pre"}: memref<f32>
scf.if %false {
// CHECK: name = "then"
// CHECK-SAME: next_access = "not computed"
memref.load %arg0[] {name = "then"} : memref<f32>
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @known_conditional
func.func @known_conditional(%arg0: memref<f32>) {
%false = arith.constant 0 : i1
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["else"]]
memref.load %arg0[] {name = "pre"}: memref<f32>
scf.if %false {
// CHECK: name = "then"
// CHECK-SAME: next_access = "not computed"
memref.load %arg0[] {name = "then"} : memref<f32>
} else {
// CHECK: name = "else"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "else"} : memref<f32>
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @loop_cf
func.func @loop_cf(%arg0: memref<?xf32>, %arg1: f32, %arg2: index, %arg3: index, %arg4: index) -> f32 {
%cst = arith.constant 0.000000e+00 : f32
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["loop", "outside"], "unknown"]
%0 = memref.load %arg0[%arg4] {name = "pre"} : memref<?xf32>
cf.br ^bb1(%arg2, %cst : index, f32)
^bb1(%1: index, %2: f32):
%3 = arith.cmpi slt, %1, %arg3 : index
cf.cond_br %3, ^bb2, ^bb3
^bb2:
// CHECK: name = "loop"
// CHECK-SAME: next_access = {{\[}}["loop", "outside"], "unknown"]
%4 = memref.load %arg0[%1] {name = "loop"} : memref<?xf32>
%5 = arith.addf %2, %4 : f32
%6 = arith.addi %1, %arg4 : index
cf.br ^bb1(%6, %5 : index, f32)
^bb3:
%7 = memref.load %arg0[%arg3] {name = "outside"} : memref<?xf32>
%8 = arith.addf %7, %2 : f32
return %8 : f32
}
// CHECK-LABEL @conditional_cf
func.func @conditional_cf(%arg0: i1, %arg1: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["then", "post"]]
%0 = memref.load %arg1[] {name = "pre"} : memref<f32>
cf.cond_br %arg0, ^bb1, ^bb2
^bb1:
// CHECK: name = "then"
// CHECK-SAME: next_access = {{\[}}["post"]]
%1 = memref.load %arg1[] {name = "then"} : memref<f32>
cf.br ^bb2
^bb2:
%2 = memref.load %arg1[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @two_sided_conditional_cf
func.func @two_sided_conditional_cf(%arg0: i1, %arg1: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["then", "else"]]
%0 = memref.load %arg1[] {name = "pre"} : memref<f32>
cf.cond_br %arg0, ^bb1, ^bb2
^bb1:
// CHECK: name = "then"
// CHECK-SAME: next_access = {{\[}}["post"]]
%1 = memref.load %arg1[] {name = "then"} : memref<f32>
cf.br ^bb3
^bb2:
// CHECK: name = "else"
// CHECK-SAME: next_access = {{\[}}["post"]]
%2 = memref.load %arg1[] {name = "else"} : memref<f32>
cf.br ^bb3
^bb3:
%3 = memref.load %arg1[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @dead_conditional_cf
func.func @dead_conditional_cf(%arg0: memref<f32>) {
%false = arith.constant false
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["post"]]
%0 = memref.load %arg0[] {name = "pre"} : memref<f32>
cf.cond_br %false, ^bb1, ^bb2
^bb1:
// CHECK: name = "then"
// CHECK-SAME: next_access = "not computed"
%1 = memref.load %arg0[] {name = "then"} : memref<f32>
cf.br ^bb2
^bb2:
%2 = memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// CHECK-LABEL: @known_conditional_cf
func.func @known_conditional_cf(%arg0: memref<f32>) {
%false = arith.constant false
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["else"]]
%0 = memref.load %arg0[] {name = "pre"} : memref<f32>
cf.cond_br %false, ^bb1, ^bb2
^bb1:
// CHECK: name = "then"
// CHECK-SAME: next_access = "not computed"
%1 = memref.load %arg0[] {name = "then"} : memref<f32>
cf.br ^bb3
^bb2:
// CHECK: name = "else"
// CHECK-SAME: next_access = {{\[}}["post"]]
%2 = memref.load %arg0[] {name = "else"} : memref<f32>
cf.br ^bb3
^bb3:
%3 = memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
func.func private @callee1(%arg0: memref<f32>) {
// CHECK: name = "callee1"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "callee1"} : memref<f32>
return
}
func.func private @callee2(%arg0: memref<f32>) {
// CHECK: name = "callee2"
// CHECK-SAME: next_access = "not computed"
memref.load %arg0[] {name = "callee2"} : memref<f32>
return
}
// CHECK-LABEL: @simple_call
func.func @simple_call(%arg0: memref<f32>) {
// CHECK: name = "caller"
// CHECK-SAME: next_access = {{\[}}["callee1"]]
memref.load %arg0[] {name = "caller"} : memref<f32>
func.call @callee1(%arg0) : (memref<f32>) -> ()
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// CHECK-LABEL: @infinite_recursive_call
func.func @infinite_recursive_call(%arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["pre"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
func.call @infinite_recursive_call(%arg0) : (memref<f32>) -> ()
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// CHECK-LABEL: @recursive_call
func.func @recursive_call(%arg0: memref<f32>, %cond: i1) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["post", "pre"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
scf.if %cond {
func.call @recursive_call(%arg0, %cond) : (memref<f32>, i1) -> ()
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// CHECK-LABEL: @recursive_call_cf
func.func @recursive_call_cf(%arg0: memref<f32>, %cond: i1) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["pre", "post"]]
%0 = memref.load %arg0[] {name = "pre"} : memref<f32>
cf.cond_br %cond, ^bb1, ^bb2
^bb1:
call @recursive_call_cf(%arg0, %cond) : (memref<f32>, i1) -> ()
cf.br ^bb2
^bb2:
%2 = memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
func.func private @callee1(%arg0: memref<f32>) {
// CHECK: name = "callee1"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "callee1"} : memref<f32>
return
}
func.func private @callee2(%arg0: memref<f32>) {
// CHECK: name = "callee2"
// CHECK-SAME: next_access = {{\[}}["post"]]
memref.load %arg0[] {name = "callee2"} : memref<f32>
return
}
func.func @conditonal_call(%arg0: memref<f32>, %cond: i1) {
// CHECK: name = "pre"
// CHECK-SAME: next_access = {{\[}}["callee1", "callee2"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
scf.if %cond {
func.call @callee1(%arg0) : (memref<f32>) -> ()
} else {
func.call @callee2(%arg0) : (memref<f32>) -> ()
}
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// In this test, the "call" operation also accesses %arg0 itself before
// transferring control flow to the callee. Therefore, the order of accesses is
// "caller" -> "call" -> "callee" -> "post"
func.func private @callee(%arg0: memref<f32>) {
// CHECK: name = "callee"
// CHECK-SAME-LITERAL: next_access = [["post"]]
memref.load %arg0[] {name = "callee"} : memref<f32>
return
}
// CHECK-LABEL: @call_and_store_before
func.func @call_and_store_before(%arg0: memref<f32>) {
// CHECK: name = "caller"
// CHECK-SAME-LITERAL: next_access = [["call"]]
memref.load %arg0[] {name = "caller"} : memref<f32>
// Note that the access after the entire call is "post".
// CHECK: name = "call"
// CHECK-SAME-LITERAL: next_access = [["post"], ["post"]]
test.call_and_store @callee(%arg0), %arg0 {name = "call", store_before_call = true} : (memref<f32>, memref<f32>) -> ()
// CHECK: name = "post"
// CHECK-SAME-LITERAL: next_access = ["unknown"]
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// In this test, the "call" operation also accesses %arg0 itself after getting
// control flow back from the callee. Therefore, the order of accesses is
// "caller" -> "callee" -> "call" -> "post"
func.func private @callee(%arg0: memref<f32>) {
// CHECK: name = "callee"
// CHECK-SAME-LITERAL: next_access = [["call"]]
memref.load %arg0[] {name = "callee"} : memref<f32>
return
}
// CHECK-LABEL: @call_and_store_after
func.func @call_and_store_after(%arg0: memref<f32>) {
// CHECK: name = "caller"
// CHECK-SAME-LITERAL: next_access = [["callee"]]
memref.load %arg0[] {name = "caller"} : memref<f32>
// CHECK: name = "call"
// CHECK-SAME-LITERAL: next_access = [["post"], ["post"]]
test.call_and_store @callee(%arg0), %arg0 {name = "call", store_before_call = true} : (memref<f32>, memref<f32>) -> ()
// CHECK: name = "post"
// CHECK-SAME-LITERAL: next_access = ["unknown"]
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// -----
// In this test, the "region" operation also accesses %arg0 itself before
// entering the region. Therefore:
// - the next access of "pre" is the "region" operation itself;
// - at the entry of the block, the next access is "post".
// CHECK-LABEL: @store_with_a_region
func.func @store_with_a_region_before(%arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME-LITERAL: next_access = [["region"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
// CHECK: name = "region"
// CHECK-SAME-LITERAL: next_access = [["post"]]
// CHECK-SAME-LITERAL: next_at_entry_point = [[["post"]]]
test.store_with_a_region %arg0 attributes { name = "region", store_before_region = true } {
test.store_with_a_region_terminator
} : memref<f32>
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// In this test, the "region" operation also accesses %arg0 itself after
// exiting from the region. Therefore:
// - the next access of "pre" is the "region" operation itself;
// - at the entry of the block, the next access is "region".
// CHECK-LABEL: @store_with_a_region
func.func @store_with_a_region_after(%arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME-LITERAL: next_access = [["region"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
// CHECK: name = "region"
// CHECK-SAME-LITERAL: next_access = [["post"]]
// CHECK-SAME-LITERAL: next_at_entry_point = [[["region"]]]
test.store_with_a_region %arg0 attributes { name = "region", store_before_region = false } {
test.store_with_a_region_terminator
} : memref<f32>
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// In this test, the operation with a region stores to %arg0 before going to the
// region. Therefore:
// - the next access of "pre" is the "region" operation itself;
// - the next access of the "region" operation (computed as the next access
// *after* said operation) is the "post" operation;
// - the next access of the "inner" operation is also "post";
// - the next access at the entry point of the region of the "region" operation
// is the "inner" operation.
// That is, the order of access is: "pre" -> "region" -> "inner" -> "post".
// CHECK-LABEL: @store_with_a_region_before_containing_a_load
func.func @store_with_a_region_before_containing_a_load(%arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME-LITERAL: next_access = [["region"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
// CHECK: name = "region"
// CHECK-SAME-LITERAL: next_access = [["post"]]
// CHECK-SAME-LITERAL: next_at_entry_point = [[["inner"]]]
test.store_with_a_region %arg0 attributes { name = "region", store_before_region = true } {
// CHECK: name = "inner"
// CHECK-SAME-LITERAL: next_access = [["post"]]
memref.load %arg0[] {name = "inner"} : memref<f32>
test.store_with_a_region_terminator
} : memref<f32>
// CHECK: name = "post"
// CHECK-SAME-LITERAL: next_access = ["unknown"]
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
// In this test, the operation with a region stores to %arg0 after exiting from
// the region. Therefore:
// - the next access of "pre" is "inner";
// - the next access of the "region" operation (computed as the next access
// *after* said operation) is the "post" operation);
// - the next access at the entry point of the region of the "region" operation
// is the "inner" operation;
// - the next access of the "inner" operation is the "region" operation itself.
// That is, the order of access is "pre" -> "inner" -> "region" -> "post".
// CHECK-LABEL: @store_with_a_region_after_containing_a_load
func.func @store_with_a_region_after_containing_a_load(%arg0: memref<f32>) {
// CHECK: name = "pre"
// CHECK-SAME-LITERAL: next_access = [["inner"]]
memref.load %arg0[] {name = "pre"} : memref<f32>
// CHECK: name = "region"
// CHECK-SAME-LITERAL: next_access = [["post"]]
// CHECK-SAME-LITERAL: next_at_entry_point = [[["inner"]]]
test.store_with_a_region %arg0 attributes { name = "region", store_before_region = false } {
// CHECK: name = "inner"
// CHECK-SAME-LITERAL: next_access = [["region"]]
memref.load %arg0[] {name = "inner"} : memref<f32>
test.store_with_a_region_terminator
} : memref<f32>
// CHECK: name = "post"
// CHECK-SAME-LITERAL: next_access = ["unknown"]
memref.load %arg0[] {name = "post"} : memref<f32>
return
}
|
