1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
|
#===--- CMakeLists.txt - Build the core standard library -----------------===#
#
# This source file is part of the Swift.org open source project
#
# Copyright (c) 2014 - 2022 Apple Inc. and the Swift project authors
# Licensed under Apache License v2.0 with Runtime Library Exception
#
# See https://swift.org/LICENSE.txt for license information
# See https://swift.org/CONTRIBUTORS.txt for the list of Swift project authors
#
#===----------------------------------------------------------------------===#
function(split_embedded_sources)
cmake_parse_arguments(SPLIT1 "" "OUT_LIST_EMBEDDED;OUT_LIST_NORMAL" "EMBEDDED;NORMAL" ${ARGN})
string(REPLACE "EMBEDDED" "NORMAL" ARGN2 "${ARGN}")
cmake_parse_arguments(SPLIT2 "" "OUT_LIST_EMBEDDED;OUT_LIST_NORMAL" "EMBEDDED;NORMAL" ${ARGN2})
set(${SPLIT1_OUT_LIST_EMBEDDED} "${SPLIT1_EMBEDDED}" PARENT_SCOPE)
set(${SPLIT1_OUT_LIST_NORMAL} "${SPLIT2_NORMAL}" PARENT_SCOPE)
endfunction()
# The complete list of sources in the core standard library. Each file is
# annotated with either "EMBEDDED" which means it contributes to both the
# embedded Swift stdlib and the regular stdlib, or "NORMAL" which means it only
# contributes to the regular stdlib. The split_embedded_sources splits this list
# into SWIFTLIB_EMBEDDED_SOURCES and SWIFTLIB_SOURCES accordingly.
split_embedded_sources(
OUT_LIST_EMBEDDED SWIFTLIB_EMBEDDED_SOURCES
OUT_LIST_NORMAL SWIFTLIB_SOURCES
### "ESSENTIAL" SOURCES
### -- PLEASE KEEP THIS LIST IN ALPHABETICAL ORDER ###
# Some files can't be sorted alphabetically, see notes in the list below.
EMBEDDED Algorithm.swift
EMBEDDED ArrayBody.swift
EMBEDDED ArrayBuffer.swift
EMBEDDED ArrayBufferProtocol.swift
NORMAL ArrayCast.swift
EMBEDDED Array.swift
EMBEDDED ArrayShared.swift
EMBEDDED ArraySlice.swift
EMBEDDED ArrayType.swift
NORMAL ASCII.swift
EMBEDDED Assert.swift
EMBEDDED AssertCommon.swift
EMBEDDED BidirectionalCollection.swift
EMBEDDED Bitset.swift
EMBEDDED Bool.swift
NORMAL BridgeObjectiveC.swift
EMBEDDED BridgeStorage.swift
NORMAL BridgingBuffer.swift
EMBEDDED Builtin.swift
EMBEDDED BuiltinMath.swift
NORMAL Character.swift
NORMAL CocoaArray.swift
NORMAL Codable.swift
EMBEDDED Collection.swift
EMBEDDED CollectionAlgorithms.swift
EMBEDDED Comparable.swift
EMBEDDED CompilerProtocols.swift
EMBEDDED Sendable.swift
EMBEDDED ContiguousArray.swift
NORMAL ContiguouslyStored.swift
EMBEDDED ClosedRange.swift
EMBEDDED ContiguousArrayBuffer.swift
NORMAL CString.swift
EMBEDDED CTypes.swift
NORMAL DebuggerSupport.swift
EMBEDDED Dictionary.swift
EMBEDDED DictionaryBridging.swift
EMBEDDED DictionaryBuilder.swift
EMBEDDED DictionaryCasting.swift
EMBEDDED DictionaryStorage.swift
EMBEDDED DictionaryVariant.swift
NORMAL DiscontiguousSlice.swift
NORMAL DropWhile.swift
NORMAL Dump.swift
EMBEDDED EmptyCollection.swift
EMBEDDED Equatable.swift
EMBEDDED ErrorType.swift
EMBEDDED ExistentialCollection.swift
NORMAL Filter.swift
NORMAL FixedArray.swift
NORMAL FlatMap.swift
NORMAL Flatten.swift
EMBEDDED FloatingPoint.swift
EMBEDDED Hashable.swift
# WORKAROUND: This file name is not sorted alphabetically in the list because
# if we do so, the compiler crashes.
EMBEDDED AnyHashable.swift
# END WORKAROUND
EMBEDDED Hasher.swift
NORMAL Hashing.swift
EMBEDDED HashTable.swift
EMBEDDED Identifiable.swift
EMBEDDED Indices.swift
NORMAL InputStream.swift
NORMAL IntegerParsing.swift
EMBEDDED Integers.swift
NORMAL Join.swift
EMBEDDED KeyPath.swift
NORMAL KeyValuePairs.swift
EMBEDDED LazyCollection.swift
EMBEDDED LazySequence.swift
NORMAL LegacyABI.swift
EMBEDDED LifetimeManager.swift
NORMAL Macros.swift
EMBEDDED ManagedBuffer.swift
NORMAL Map.swift
EMBEDDED MemoryLayout.swift
EMBEDDED UnicodeScalar.swift # ORDER DEPENDENCY: Must precede Mirrors.swift
NORMAL Mirrors.swift
EMBEDDED Misc.swift
EMBEDDED MutableCollection.swift
EMBEDDED NativeDictionary.swift
EMBEDDED NativeSet.swift
NORMAL NewtypeWrapper.swift
NORMAL NFC.swift
NORMAL NFD.swift
EMBEDDED ObjectIdentifier.swift
EMBEDDED Optional.swift
EMBEDDED OptionSet.swift
NORMAL OutputStream.swift
EMBEDDED Pointer.swift
EMBEDDED Policy.swift
NORMAL PrefixWhile.swift
NORMAL Prespecialize.swift
NORMAL Print.swift
EMBEDDED PtrAuth.swift
EMBEDDED Random.swift
EMBEDDED RandomAccessCollection.swift
EMBEDDED Range.swift
EMBEDDED RangeReplaceableCollection.swift
NORMAL RangeSet.swift
NORMAL RangeSetRanges.swift
NORMAL ReflectionMirror.swift
EMBEDDED Repeat.swift
NORMAL REPL.swift
EMBEDDED Result.swift
EMBEDDED Reverse.swift
EMBEDDED Runtime.swift
NORMAL RuntimeFunctionCounters.swift
EMBEDDED SipHash.swift
EMBEDDED Sequence.swift
EMBEDDED SequenceAlgorithms.swift
EMBEDDED Set.swift
EMBEDDED SetAlgebra.swift
NORMAL SetAnyHashableExtensions.swift
NORMAL SetBridging.swift
EMBEDDED SetBuilder.swift
EMBEDDED SetCasting.swift
EMBEDDED SetStorage.swift
EMBEDDED SetVariant.swift
EMBEDDED ShadowProtocols.swift
NORMAL Shims.swift
EMBEDDED Slice.swift
NORMAL SmallString.swift
EMBEDDED Sort.swift
EMBEDDED StaticString.swift
NORMAL StaticPrint.swift
EMBEDDED Stride.swift
NORMAL StringHashable.swift # ORDER DEPENDENCY: Must precede String.swift
NORMAL String.swift
NORMAL StringBreadcrumbs.swift
NORMAL StringBridge.swift
NORMAL StringCharacterView.swift
NORMAL StringComparable.swift
NORMAL StringComparison.swift
NORMAL StringCreate.swift
NORMAL StringGuts.swift
NORMAL StringGutsSlice.swift
NORMAL StringGutsRangeReplaceable.swift
NORMAL StringObject.swift
NORMAL StringProtocol.swift
NORMAL StringIndex.swift
NORMAL StringIndexConversions.swift
NORMAL StringIndexValidation.swift
NORMAL StringInterpolation.swift
NORMAL StringLegacy.swift
NORMAL StringNormalization.swift
NORMAL StringRangeReplaceableCollection.swift
NORMAL StringStorage.swift
NORMAL StringStorageBridge.swift
NORMAL StringSwitch.swift
NORMAL StringTesting.swift
NORMAL StringUnicodeScalarView.swift
NORMAL StringUTF16View.swift
NORMAL StringUTF8View.swift
NORMAL StringUTF8Validation.swift
NORMAL StringWordBreaking.swift
NORMAL Substring.swift
EMBEDDED SwiftNativeNSArray.swift
EMBEDDED TemporaryAllocation.swift
NORMAL ThreadLocalStorage.swift
NORMAL UIntBuffer.swift
NORMAL UnavailableStringAPIs.swift
NORMAL UnicodeData.swift
NORMAL UnicodeEncoding.swift
NORMAL UnicodeBreakProperty.swift
NORMAL UnicodeHelpers.swift
NORMAL UnicodeParser.swift
NORMAL UnicodeScalarProperties.swift
NORMAL CharacterProperties.swift # ORDER DEPENDENCY: UnicodeScalarProperties.swift
NORMAL UnicodeSPI.swift
EMBEDDED Unmanaged.swift
NORMAL UnmanagedOpaqueString.swift
NORMAL UnmanagedString.swift
EMBEDDED UnsafePointer.swift
EMBEDDED UnsafeRawPointer.swift
NORMAL UTFEncoding.swift
NORMAL UTF8.swift
NORMAL UTF16.swift
NORMAL UTF32.swift
NORMAL Unicode.swift # ORDER DEPENDENCY: must follow new unicode support
NORMAL StringGraphemeBreaking.swift # ORDER DEPENDENCY: Must follow UTF16.swift
NORMAL ValidUTF8Buffer.swift
EMBEDDED WriteBackMutableSlice.swift
NORMAL MigrationSupport.swift
### "NON-ESSENTIAL" SOURCES, LAYERED ON TOP OF THE "ESSENTIAL" ONES
### -- PLEASE KEEP THIS LIST IN ALPHABETICAL ORDER ###
EMBEDDED Availability.swift
NORMAL CollectionDifference.swift
EMBEDDED CollectionOfOne.swift
NORMAL Diffing.swift
EMBEDDED Duration.swift
EMBEDDED DurationProtocol.swift
EMBEDDED FloatingPointRandom.swift
EMBEDDED Instant.swift
EMBEDDED Int128.swift
NORMAL Mirror.swift
NORMAL PlaygroundDisplay.swift
NORMAL CommandLine.swift
EMBEDDED SliceBuffer.swift
NORMAL StaticBigInt.swift
EMBEDDED UInt128.swift
NORMAL UnfoldSequence.swift
NORMAL UnsafeBufferPointerSlice.swift
NORMAL VarArgs.swift
EMBEDDED Zip.swift
NORMAL "${SWIFT_SOURCE_DIR}/stdlib/linker-support/magic-symbols-for-install-name.c"
)
split_embedded_sources(
OUT_LIST_EMBEDDED SWIFTLIB_EMBEDDED_GYB_SOURCES
OUT_LIST_NORMAL SWIFTLIB_GYB_SOURCES
NORMAL AtomicInt.swift.gyb
NORMAL FloatingPointParsing.swift.gyb
EMBEDDED FloatingPointTypes.swift.gyb
EMBEDDED IntegerTypes.swift.gyb
EMBEDDED LegacyInt128.swift.gyb
EMBEDDED UnsafeBufferPointer.swift.gyb
EMBEDDED UnsafeRawBufferPointer.swift.gyb
EMBEDDED Tuple.swift.gyb
)
if(SWIFT_STDLIB_ENABLE_VECTOR_TYPES)
list(APPEND SWIFTLIB_SOURCES SIMDVector.swift)
list(APPEND SWIFTLIB_GYB_SOURCES SIMDConcreteOperations.swift.gyb SIMDVectorTypes.swift.gyb)
list(APPEND SWIFTLIB_EMBEDDED_SOURCES SIMDVector.swift)
list(APPEND SWIFTLIB_EMBEDDED_GYB_SOURCES SIMDConcreteOperations.swift.gyb SIMDVectorTypes.swift.gyb)
endif()
# Freestanding and Linux builds both have failures to resolve.
if(NOT BOOTSTRAPPING_MODE STREQUAL "OFF" AND NOT SWIFT_FREESTANDING_FLAVOR AND NOT SWIFT_HOST_VARIANT_SDK STREQUAL "LINUX")
list(APPEND SWIFTLIB_SOURCES ObjectIdentifier+DebugDescription.swift)
endif()
list(APPEND SWIFTLIB_EMBEDDED_SOURCES
EmbeddedRuntime.swift
EmbeddedStubs.swift
EmbeddedPrint.swift
)
set(GROUP_INFO_JSON_FILE ${CMAKE_CURRENT_SOURCE_DIR}/GroupInfo.json)
set(swift_core_link_flags "${SWIFT_RUNTIME_SWIFT_LINK_FLAGS}")
set(swift_core_framework_depends)
set(swift_core_private_link_libraries)
set(swift_stdlib_compile_flags "${SWIFT_RUNTIME_SWIFT_COMPILE_FLAGS}")
if(SWIFT_PRIMARY_VARIANT_SDK STREQUAL "CYGWIN")
# TODO(compnerd) cache this variable to permit re-configuration
execute_process(COMMAND "cygpath" "-u" "$ENV{SYSTEMROOT}" OUTPUT_VARIABLE ENV_SYSTEMROOT)
list(APPEND swift_core_private_link_libraries "${ENV_SYSTEMROOT}/system32/psapi.dll")
elseif(SWIFT_PRIMARY_VARIANT_SDK STREQUAL "FREEBSD")
find_library(EXECINFO_LIBRARY execinfo)
list(APPEND swift_core_private_link_libraries ${EXECINFO_LIBRARY})
elseif(SWIFT_PRIMARY_VARIANT_SDK STREQUAL "LINUX")
if(SWIFT_BUILD_STATIC_STDLIB)
list(APPEND swift_core_private_link_libraries)
endif()
elseif(SWIFT_PRIMARY_VARIANT_SDK STREQUAL "WINDOWS")
list(APPEND swift_core_private_link_libraries shell32;DbgHelp;Synchronization)
endif()
# There is a race condition with building the 'tools' CMake build of the compiler,
# which produces libSwiftScan that the compiler building the standard library may attempt to use.
# Since the current build system makes establishing this dependency relationship exceedingly difficult,
# we attempt to work around it by disabling use of 'libSwiftScan' here.
list(APPEND swift_stdlib_compile_flags "-nonlib-dependency-scanner")
if(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "MinSizeRel")
list(APPEND swift_stdlib_compile_flags "-Xllvm" "-sil-inline-generics")
list(APPEND swift_stdlib_compile_flags "-Xllvm" "-sil-partial-specialization")
endif()
if(SWIFT_STDLIB_ENABLE_STDLIBCORE_EXCLUSIVITY_CHECKING)
list(APPEND swift_stdlib_compile_flags "-enforce-exclusivity=checked")
endif()
if(SWIFT_STDLIB_ENABLE_DEBUG_PRECONDITIONS_IN_RELEASE)
list(APPEND swift_stdlib_compile_flags "-DSWIFT_STDLIB_ENABLE_DEBUG_PRECONDITIONS_IN_RELEASE")
endif()
set(compile_flags_for_final_build)
if(SWIFT_ENABLE_ARRAY_COW_CHECKS)
list(APPEND compile_flags_for_final_build "-DCOW_CHECKS_ENABLED")
endif()
# STAGING: Temporarily avoids having to write #fileID in Swift.swiftinterface.
list(APPEND swift_stdlib_compile_flags "-Xfrontend" "-enable-experimental-concise-pound-file")
list(APPEND swift_stdlib_compile_flags "-enable-experimental-feature" "Macros")
list(APPEND swift_stdlib_compile_flags "-enable-experimental-feature" "FreestandingMacros")
list(APPEND swift_stdlib_compile_flags "-enable-experimental-feature" "Extern")
list(APPEND swift_stdlib_compile_flags "-enable-experimental-feature" "BitwiseCopyable")
if("${SWIFT_NATIVE_SWIFT_TOOLS_PATH}" STREQUAL "")
set(swift_bin_dir "${CMAKE_BINARY_DIR}/bin")
set(swift_lib_dir "${CMAKE_BINARY_DIR}/lib")
else()
set(swift_bin_dir "${SWIFT_NATIVE_SWIFT_TOOLS_PATH}")
set(swift_lib_dir "${SWIFT_NATIVE_SWIFT_TOOLS_PATH}/../lib")
endif()
list(APPEND swift_stdlib_compile_flags "-external-plugin-path"
"${swift_lib_dir}/swift/host/plugins#${swift_bin_dir}/swift-plugin-server")
list(APPEND swift_stdlib_compile_flags "-enable-experimental-feature" "DebugDescriptionMacro")
set(swift_core_incorporate_object_libraries)
list(APPEND swift_core_incorporate_object_libraries swiftRuntime)
list(APPEND swift_core_incorporate_object_libraries swiftLLVMSupport)
list(APPEND swift_core_incorporate_object_libraries swiftDemangling)
list(APPEND swift_core_incorporate_object_libraries swiftStdlibStubs)
list(APPEND swift_core_incorporate_object_libraries swiftThreading)
if(SWIFT_STDLIB_HAS_COMMANDLINE)
list(APPEND swift_core_incorporate_object_libraries swiftCommandLineSupport)
endif()
set(swiftCore_common_options
IS_STDLIB IS_STDLIB_CORE
${SWIFTLIB_SOURCES}
GYB_SOURCES
${SWIFTLIB_GYB_SOURCES}
LINK_FLAGS
${swift_core_link_flags}
PRIVATE_LINK_LIBRARIES
${swift_core_private_link_libraries}
INCORPORATE_OBJECT_LIBRARIES
${swift_core_incorporate_object_libraries}
FRAMEWORK_DEPENDS
${swift_core_framework_depends}
SWIFT_COMPILE_FLAGS
${swift_stdlib_compile_flags} -Xcc -DswiftCore_EXPORTS ${SWIFT_STANDARD_LIBRARY_SWIFT_FLAGS})
# The copy_shim_headers target dependency is required to let the
# build system know that there's a rule to produce the shims
# directory, but is not sufficient to cause the object file to be rebuilt
# when the shim header changes. Therefore, we pass both the target
# and the generated directory as dependencies.
set(swiftCore_common_dependencies
copy_shim_headers "${SWIFTLIB_DIR}/shims" ${GROUP_INFO_JSON_FILE})
if(BOOTSTRAPPING_MODE STREQUAL "BOOTSTRAPPING")
set(b0_deps symlink-headers-bootstrapping0)
set(b1_deps symlink-headers-bootstrapping1)
list(FIND SWIFT_STDLIB_LIBRARY_BUILD_TYPES "SHARED" index_of_shared)
if(index_of_shared EQUAL -1)
message(FATAL_ERROR "bootstrapping requires SHARED stdlib build type")
endif()
set(swiftCore_common_bootstrapping_options
SHARED
${swiftCore_common_options}
SDK ${SWIFT_HOST_VARIANT_SDK}
ARCHITECTURE ${SWIFT_HOST_VARIANT_ARCH}
INSTALL_IN_COMPONENT
"never_install")
# Bootstrapping - stage 0
add_swift_target_library_single(swiftCore-bootstrapping0 swiftCore
${swiftCore_common_bootstrapping_options}
FILE_DEPENDS
${b0_deps} ${swiftCore_common_dependencies}
BOOTSTRAPPING 0)
# Bootstrapping - stage 1
add_swift_target_library_single(swiftCore-bootstrapping1 swiftCore
${swiftCore_common_bootstrapping_options}
FILE_DEPENDS
${b1_deps} ${swiftCore_common_dependencies}
BOOTSTRAPPING 1)
endif()
add_swift_target_library(swiftCore
${SWIFT_STDLIB_LIBRARY_BUILD_TYPES}
${swiftCore_common_options}
${compile_flags_for_final_build}
FILE_DEPENDS
${swiftCore_common_dependencies}
INSTALL_IN_COMPONENT
stdlib
MACCATALYST_BUILD_FLAVOR
zippered
)
# Embedded standard library - embedded libraries are built as .swiftmodule only,
# i.e. there is no .o or .a file produced (no binary code is actually produced)
# and only users of a library are going to actually compile any needed code.
if(SWIFT_SHOULD_BUILD_EMBEDDED_STDLIB)
add_custom_target(embedded-stdlib ALL)
set(SWIFT_ENABLE_REFLECTION OFF)
set(SWIFT_STDLIB_SUPPORT_BACK_DEPLOYMENT OFF)
set(SWIFT_STDLIB_STABLE_ABI OFF)
set(SWIFT_STDLIB_ENABLE_OBJC_INTEROP OFF)
foreach(entry ${EMBEDDED_STDLIB_TARGET_TRIPLES})
string(REGEX REPLACE "[ \t]+" ";" list "${entry}")
list(GET list 0 arch)
list(GET list 1 mod)
list(GET list 2 triple)
set(SWIFT_SDK_embedded_ARCH_${arch}_MODULE "${mod}")
set(SWIFT_SDK_embedded_LIB_SUBDIR "embedded")
set(SWIFT_SDK_embedded_ARCH_${arch}_TRIPLE "${triple}")
add_swift_target_library_single(
embedded-stdlib-${mod}
swiftCore
ONLY_SWIFTMODULE
IS_STDLIB IS_STDLIB_CORE IS_FRAGILE
${SWIFTLIB_EMBEDDED_SOURCES}
GYB_SOURCES ${SWIFTLIB_EMBEDDED_GYB_SOURCES}
SWIFT_COMPILE_FLAGS
${swift_stdlib_compile_flags} -Xcc -D__MACH__ -Xcc -D__APPLE__ -Xcc -ffreestanding -enable-experimental-feature Embedded
-Xfrontend -enable-ossa-modules -nonlib-dependency-scanner
MODULE_DIR "${CMAKE_BINARY_DIR}/lib/swift/embedded"
SDK "embedded"
ARCHITECTURE "${arch}"
FILE_DEPENDS ${swiftCore_common_dependencies}
INSTALL_IN_COMPONENT stdlib
)
add_dependencies(embedded-stdlib embedded-stdlib-${mod})
endforeach()
endif()
|
